*20
	PMODE
	FIELD 0
/CONSTANTS FOR USERS OPTIONS
	*55
	7777		/CR AFTER OUT
	7777		/LF AFTER IN
	*2207
	1055		/TAD SWIT1
	*62
	7		/CHAR OUT
	5		/5 TO RIGHT
	2		/ROUND
	0		/HI SK-FLT
	0		/LO SK-FLT
/
/INTERFACE FOR UPPER 4K FPT SYSTEM
/USER CAN INSERT AT ANY REASONBLE
/LOCATION
/
/
	*200
FIN2,	CDF 0
	JMS I 5
	CDF 10
	CIF 10
	JMP I .+1
	FLINP2+4
/
FOU2,	CDF 0
	JMS I 6
	CDF 10
	CIF 10
	JMP I .+1
	FLOUT2+4
/
FENT2,	CDF 0
	JMS I 7
	0
	0		/FEXIT
	CDF 10
	CIF 10
	JMP I .+1
	FPNT2+1
/
/UPPER 4K FPT SYSTEM
/
	PMODE
	FIELD 1
/
	*5
	FLINP2
	FLOUT2
	FPNT2
/
/THE FOLLOWING IS 200 WORDS THAT CAN BE
/PLACED ON ANY PAGE EXCEPT PAGE ZERO
	*600
FPNT2,	0
	CLA CLL
	TAD I FPNT2
	DCA FJUMP
	TAD FJUMP
	AND FPAGE
	SNA CLA
	JMP .+3
	TAD FMASK5
	AND FPNT2
	DCA FADDR
	TAD FMASK7
	AND FJUMP
	TAD FADDR
	DCA FADDR
	TAD FINDR
	AND FJUMP
	SNA CLA
	JMP .+3
	TAD I FADDR
	DCA FADDR
	ISZ FPNT2
	TAD FJUMP
	CLL RTL
	RTL
	AND FMASK3
	TAD FTABL
	DCA FJUMP2
	TAD I FJUMP2
	DCA FJUMP2
	JMP I FJUMP2
FJUMP,	0
FJUMP2,	0
FADDR,	0
FMASK3,	17
FMASK5,	7600
FMASK7,	177
FPAGE,	200
FINDR,	400
/
FTABL,	.+1
	FLX
	FLA
	FLS
	FLM
	FLD
	FLG
	FLP
	FLN
/
FLG,	STA CLL RTL	/-3
	DCA FM3
	TAD FP44A
	DCA FP44B
	CDF 10
	TAD I FADDR
	CDF 0
	DCA I FP44B
	ISZ FADDR
	ISZ FP44B
	ISZ FM3
	JMP .-7
	CDF 10
	JMP FPNT2+1
FP44A,	44
FP44B,	44
FM3,	-3
/
FLP,	STA CLL RTL
	DCA FM3
	TAD FP44A
	DCA FP44B
	CDF 0
	TAD I FP44B
	CDF 10
	DCA I FADDR
	ISZ FADDR
	ISZ FP44B
	ISZ FM3
	JMP .-7
	JMP FPNT2+1
/
FLX,	TAD FJUMP
	AND FMASK3
	SNA
	JMP I FPNT2
	SKP
FLA,	TAD FA40
	SKP
FLS,	TAD FA40+1
	SKP
FLM,	TAD FA40+2
	SKP
FLD,	TAD FA40+3
	SKP
FLN,	TAD FA40+4
	CDF 0
	DCA I FA40+5
	STA CLL RTL
	DCA FM3
	TAD FP40A
	DCA FP40B
	CDF 10
	TAD I FADDR
	CDF 0
	DCA I FP40B
	ISZ FADDR
	ISZ FP40B
	ISZ FM3
	JMP .-7
	CIF 0
	JMP I .+1
	FENT2
/
FP40A,	40
FP40B,	40
FA40,	1040		/FADD 40
	2040		/FSUB 40
	3040		/FMPY 40
	4040		/FDIV 40
	7000		/FNOR
	FENT2+2		/OPERATION
/
FLINP2,	0
	CIF 0
	JMP I .+1
	FIN2
	JMP I .-4
/
FLOUT2,	0
	CIF 0
	JMP I .+1
	FOU2
	JMP I .-4
/
/END OF UPPER 4K FPNT SYSTEM
/
/FPNT TESTING PROGRAM
/
	LMODE
	SEGMNT 2
	*20
	CLR
	LIF 6
	LDF 7
	JMP 20
/
	*400
	CLR
	LIF 6
	LDF 7
	JMP 400
/
/
	SEGMNT 6
	*20
	PDP
	PMODE
	TLS
START,	CLA CLL
	KSF
	JMP .-1
	KCC
	CRLF
	CDF 10
	OSR
	SPA
	JMP TW+1
	TAD M777
	SMA
	JMP TW
	TAD P777
	DCA FUN
	JMP ON
TW,	TAD P777
	TAD ADD
	DCA FUN
	INPF
	FENT
	FPUT AB
	FEXT
ON,	INPF
	FENT
FUN,	0
	FOUT
	FEXT
	JMP START
ADD,	A&177!200
AB,	0
	0
	0
P777,	777
M777,	-777
/
	CRLF=JMS .
	0
	CLA CLL
	TAD CR
	TYPE
	CLA CLL
	TAD LF
	TYPE
	JMP I .-7
CR,	215
LF,	212
/
	TYPE=JMS .
	0
	TSF
	JMP .-1
	TLS
	CLA CLL
	JMP I .-5
/
	LMODE
	SEGMNT 6
	*400
	CLR
	PDP
	PMODE
	KCC
	TLS
BEGIN,	FENT
	FINP
	FMPY TWO
	FPUT A
	FINP
	FPUT B
	FINP
	FMPY TWO
	FMPY A
	FPUT T
	FGET B
	SQRE
	FSUB T
	SQRT
	FPUT T
	FGET B
	FMPY M
	FPUT B
	FSUB T
	FDIV A
	FOUT
	FGET B
	FADD T
	FDIV A
	FOUT
	FEXT
	JMP BEGIN
TWO,	2
	2000
	0
M,	1
	6000
	0
T,	0
	0
	0
A,	0
	0
	0
B,	0
	0
	0
/
	FEXT=0000
	FADD=1000
	FSUB=2000
	FMPY=3000
	FDIV=4000
	FGET=5000
	FPUT=6000
	FNOR=7000
	SQRE=1
	SQRT=2
	FSIN=3
	FCOS=4
	FATN=5
	FEXP=6
	FLOG=7
	FSNK=10
	FLOT=11
	FABS=12
	FINP=13
	FOUT=14
	FITR=15
	FRND=16
	FNEG=17
	INPF=JMS I 5
	OUTF=JMS I 6
	FENT=JMS I 7
/
	LISTAP-1