*20
	PMODE
	*40
EX1,	0
AC1H,	0
AC1L,	0
OVER1,	0
EXP,	0
HORD,	0
LORD,	0
OVER2,	0
EXP1,	0
QUOL,	0
FPAC1,	0
	0
	0
	*61
FLAG,	0
	5
	5
	0
	0
	*5
	FLINTP	/PTR FOR JMS I 5
	FLOUTP	/OUTPT PTR JMS I 6
	FPNT	/INPT=JMS I 7
	*44
EXPONT,	0
HORDER,	0
LORDER,	0
	*52
FPAC1,	0
	0
	0
SWIT1,	7777
SWIT2,	7777
CHAR,	0
DSWIT,	0
	*1767
PRCHAR,	0
	TAD SWIT2
	SNA CLA
	JMP I PRCHAR
	TAD LFED
	JMS I OPUT
	JMP I PRCHAR
OPUT,	OUT
LFED,	0212
	PMODE
	*600
FPNT,	0
	CLA CLL
	DCA OVER1
	DCA OVER2
	TAD I FPNT
	DCA JUMP
	TAD JUMP
	AND PAGENO
	SNA CLA
	JMP .+3
	TAD MASK5
	AND FPNT
	DCA ADDR
	TAD MASK7
	AND JUMP
	TAD ADDR
	DCA ADDR
	TAD INDRCT
	AND JUMP
	SNA CLA
	JMP LOOPO1
	TAD I ADDR
	DCA ADDR
LOOPO1,	ISZ FPNT
	TAD I ADDR
	DCA EX1
	TAD ADDR
	DCA SAVE
	ISZ SAVE
	TAD I SAVE
	DCA AC1H
	ISZ SAVE
	TAD I SAVE
	DCA AC1L
	TAD JUMP
	CLL RTL
	RTL
	AND MASK3
	TAD TABLE
	DCA JUMP2
	TAD I JUMP2
	DCA JUMP2
	JMP I JUMP2
JUMP,	0
JUMP2,	0
GO2,	0
ADDR,	0
SAVE,	0
MASK3,	0017
MASK5,	7600
MASK7,	0177
PAGENO,	0200
INDRCT,	0400
TABLE,	.+1
	EXIT
	FLAD
	FLSU
	FLMY
	FLDV
	FLGT
	FLPT
	NORF
FLGT,	TAD EX1
	DCA EXP
	TAD AC1H
	DCA HORD
	TAD AC1L
	DCA LORD
	JMP FPNT+1
FLPT,	TAD EXP
	DCA I ADDR
	ISZ ADDR
	TAD HORD
	DCA I ADDR
	ISZ ADDR
	TAD LORD
	DCA I ADDR
	JMP FPNT+1
FLAD,	JMS I ALGN
	JMP FPNT+1
	JMS I UNORM
	CLL
	TAD OVER1
	TAD OVER2
	DCA OVER2
	RAL
	TAD AC1L
	TAD LORD
	DCA LORD
	RAL
	TAD AC1H
	TAD HORD
	DCA HORD
	JMS I NORM
	JMP FPNT+1
FLSU,	JMS I OPMINS
	JMP FLAD
OPMINS,	MINUS2
EXIT,	TAD JUMP
	AND MASK3
	SNA
	JMP I FPNT
	TAD ACON6
	DCA JUMP2
	TAD I JUMP2
	DCA JUMP2
	TAD FPNT
	DCA GO2
	JMS I JUMP2
	CLA CLL
	TAD GO2
	DCA FPNT
	JMP FPNT+1
ACON6,	TABLE6-1
FLMY,	CLA IAC
	TAD EX1
	TAD EXP
	DCA EXP
	JMS I MULT
	JMP FPNT+1
MULT,	DMULT
NORM,	DNORM
ALGN,	ALIGN
UNORM,	DUNORM
NORF,	JMS I NORM
	JMP FPNT+1
	*1000
ACMINS,	0
	CLL CLA
	TAD OVER2
	CMA IAC
	DCA OVER2
	TAD LORD
	CMA
	SZL
	CLL IAC
	DCA LORD
	TAD HORD
	CMA
	SZL
	CLL IAC
	DCA HORD
	JMP I ACMINS
ALIGN,	0
	TAD HORD
	SZA CLA
	JMP .+4
	TAD LORD
	SNA CLA
	JMP NOHERE
	TAD AC1H
	SZA CLA
	JMP .+4
	TAD AC1L
	SNA CLA
	JMP I ALIGN
	TAD EX1
	CMA IAC
	TAD EXP
	SNA
	JMP DONE
	SMA
	CMA IAC
	DCA AMOUNT
	TAD AMOUNT
	TAD TEST2
	SMA CLA
	JMP .+6
	JMS OUTGO
	SZL
	TAD TAG2
	TAD TAG1
	JMP NOGO
	JMS OUTGO
	SNL
	TAD TAG2
	TAD TAG1
	DCA TEST3
	TAD AMOUNT
	CMA IAC
	TAD I TEST3
	DCA I TEST3
	ISZ TEST3
	TAD TEST3
	DCA TEST4
	ISZ TEST4
	TAD TEST4
	DCA TEST5
	ISZ TEST5
SHIFT,	CLL
	TAD I TEST3
	SPA
	CML
	RAR
	DCA I TEST3
	TAD I TEST4
	RAR
	DCA I TEST4
	TAD I TEST5
	RAR
	DCA I TEST5
	ISZ AMOUNT
	JMP SHIFT
DONE,	ISZ ALIGN
	JMP I ALIGN
OUTGO,	0
	TAD EX1
	CMA IAC
	TAD EXP
	RAL
	CLA
	JMP I OUTGO
NOGO,	DCA TEST3
	TAD I TEST3
	DCA EXP
	ISZ TEST3
	TAD I TEST3
	DCA HORD
	ISZ TEST3
	TAD I TEST3
	DCA LORD
	JMP I ALIGN
NOHERE,	TAD EX1
	DCA EXP
	JMP DONE
AMOUNT,	0
TEST2,	0030
TEST3,	0
TEST4,	0
TEST5,	0
TAG1,	EXP
TAG2,	EX1-EXP
RETN2,	FPNT+1
ERROR1,	TAD GOOF
	DCA EXP
	TAD GOOF
	DCA HORD
	CMA
	DCA LORD
	ISZ FLAG
	JMP I RETN2
GOOF,	3777
SQUARE,	0
	JMS I 0007
	FPUT FPAC1
	FMPY FPAC1
	FEXT
	JMP I SQUARE
EXIT6,	0
	JMP I EXIT6
	*1200
DIVI,	0
	CLA CLL
	TAD HORD
	SPA
	CLL CML
	RAR
	DCA HORD
	TAD LORD
	RAR
	DCA LORD
	TAD OVER2
	RAR
	DCA OVER2
	CLL
	ISZ EXP
	NOP
	JMP I DIVI
DMULT,	0
	CLA CLL
	TAD SMACLA
	DCA SNSWIT
	JMS SIGN
	TAD AC1L
	DCA I MP2PT
	TAD LORD
	JMS I MP4PT
	CLA
	TAD I MP5PT
	DCA OVER2
	TAD HORD
	DCA I MP2PT
	TAD AC1L
	JMS I MP4PT
	TAD OVER2
	DCA OVER2
	RAL
	TAD I MP5PT
	DCA D
	RAL
	DCA KEEP
	TAD AC1H
	DCA I MP2PT
	TAD LORD
	JMS I MP4PT
	TAD OVER2
	DCA OVER2
	RAL
	TAD I MP5PT
	TAD D
	DCA D
	RAL
	TAD KEEP
	DCA KEEP
	TAD HORD
	DCA I MP2PT
	TAD AC1H
	JMS I MP4PT
	TAD D
	DCA LORD
	RAL
	TAD I MP5PT
	TAD KEEP
	DCA HORD
	JMS I NORMF
	DCA OVER2
	ISZ SGN
	JMP I DMULT
	JMS I MINS
	JMP I DMULT
FLDV,	TAD AC1H
	SZA CLA
	JMP .+4
	TAD AC1H
	SNA CLA
	JMP I ERROR
	TAD EX1
	CMA IAC
	TAD EXP
	IAC
	DCA EXP
	TAD SPACLA
	DCA SNSWIT
	JMS SIGN
	JMS I DIVIDE
	TAD I MP5PT
	TAD AC1H
	SZL CLA
	IAC
	DCA AC1L
	DCA AC1H
	ISZ SGN
	JMS I MINS
	JMP I .+1
	FLAD+2
SIGN,	0
	TAD REST
	DCA SGN
	TAD HORD
	SMA CLA
	JMP .+3
	JMS I MINS
	ISZ SGN
	TAD AC1H
SNSWIT,	SMA CLA
	JMP I SIGN
	JMS I MINS2
	ISZ SGN
	NOP
	JMP I SIGN
MP4PT,	MP4
MP2PT,	MP2
MP5PT,	MP5
NORMF,	DNORM
DIVIDE,	DUBDIV
SPACLA,	SPA CLA
SMACLA,	SMA CLA
RETURN,	FPNT+1
SGN,	0
REST,	7776
D,	0
KEEP,	0
MINS2,	MINUS2
RAR2,	DIV2
MINS,	ACMINS
ERROR,	ERROR1
	*1400
MINUS2,	0
	CLA CLL
	TAD OVER1
	CMA IAC
	DCA OVER1
	TAD AC1L
	CMA
	SZL
	CLL IAC
	DCA AC1L
	TAD AC1H
	CMA 
	SZL
	CLL IAC
	DCA AC1H
	JMP I MINUS2
DIV2,	0
	CLA CLL
	TAD AC1H
	SPA
	CLL CML
	RAR
	DCA AC1H
	TAD AC1L
	RAR
	DCA AC1L
	TAD OVER1
	RAR
	DCA OVER1
	CLL
	JMP I DIV2
MP4,	0
	DCA MP1
	DCA MP5
	TAD THIR
	DCA MP3
	CLL
	TAD MP1
	RAR
	DCA MP1
	TAD MP5
	SNL
	JMP .+3
	CLL
	TAD MP2
	RAR
	DCA MP5
	ISZ MP3
	JMP MP4+6
	TAD MP1
	RAR
	CLL
	JMP I MP4
MP5,	0
MP1,	0
MP3,	0
THIR,	7764
MP2,	0
DUBDIV,	0
	CLA CLL
	DCA QUOL
	TAD MIF
	DCA MP3
	JMP DVX
DV3,	TAD LORD
	RAL
	DCA LORD
	TAD HORD
	RAL
	DCA HORD
DVX,	TAD AC1L
	TAD LORD
	DCA MP2
	RAL
	TAD HORD
	TAD AC1H
	SNL
	JMP DV2-1
	DCA HORD
	TAD MP2
	DCA LORD
	CLA
DV2,	TAD QUOL
	RAL
	DCA QUOL
	TAD OVER2
	RAL
	DCA OVER2
	ISZ MP3
	JMP DV3
	TAD QUOL
	DCA LORD
	TAD HORD
	CLL RTL
	DCA MP5
	TAD OVER2
	DCA HORD
	DCA OVER2
	TAD MP5
	JMP I DUBDIV
MIF,	7751
TABLE6,	SQUARE
	SQROOT
	SINE
	COS
	ARTN
	EXPNT
	LOG
	INPT
	OUTP
	SINK
	FLOAT
	ABSOL
	INTR
	ROUND
	EXIT6
DUNORM,	0
	JMS DIV2
	JMS I RAR1
	ISZ EX1
	NOP
	JMP I DUNORM
RAR1,	DIVI
	*1600
DNORM,	0
	CLA CLL
	DCA AMT1
	DCA SIGN1
	TAD HORD
	SPA
	ISZ SIGN1
	SZA CLA
	JMP GO6
	TAD LORD
	SZA CLA
	JMP GO6
	TAD OVER2
	SNA CLA
	JMP EXIT2
GO6,	TAD SIGN1
	SZA CLA
	JMS I NEG
LOP,	TAD HORD
	RAL CLL
	SPA CLA
	JMP EXIT1
	TAD OVER2
	CLL RAL
	DCA OVER2
	TAD LORD
	RAL
	DCA LORD
	TAD HORD
	RAL
	DCA HORD
	ISZ AMT1
	JMP LOP
EXIT1,	TAD AMT1
	CMA IAC
	TAD EXP
	DCA EXP
	TAD SIGN1
	SZA CLA
	JMS I NEG
	JMP I DNORM
EXIT2,	DCA EXP
	JMP I DNORM
NEG,	ACMINS
SIGN1,	0
AMT1,	0
SQROOT,	0
	DCA FLAG1
	JMS I 007
	FPUT FPAC1
	FEXT
	TAD HORD
	SPA CLA
	JMP SQEND1
	TAD EXP
	CLL
	SPA
	CML
	RAR
	DCA ITER1
	SZL
	ISZ ITER1
	NOP
	TAD SQCON1
	DCA ITER1+1
	DCA ITER1+2
	TAD FPAC1+1
	SZA CLA
	JMP CLCU
	TAD FPAC1+2
	SNA CLA
	JMP SQEND
CLCU,	JMS I 0007
	FGET FPAC1
	FDIV ITER1
	FADD ITER1
	FEXT
	CLA CMA
	TAD EXP
	DCA EXP
	TAD EXP
	CMA IAC
	TAD ITER1
	SZA CLA
	JMP ROOTGO
	TAD HORD
	CMA IAC
	TAD ITER1+1
	SZA CLA
	JMP ROOTGO
	TAD LORD
	CMA IAC
	TAD ITER1+2
	SMA
	CMA IAC
	IAC
	SPA CLA
	JMP ROOTGO
	TAD FLAG1
	DCA FLAG
	JMP I SQROOT
ROOTGO,	JMS I 0007
	FPUT ITER1
	FEXT
	JMP CLCU
SQEND1,	JMS I NEG
	ISZ FLAG1
	JMP SQROOT+2
SQEND,	DCA EXP
	JMP I SQROOT
ITER1,	0
	0
	0
SQCON1,	3015
FLAG1,	0
	PMODE
	*2000
DECONV,	0
	CLA
	DCA HORDER
	DCA LORDER
	DCA SIGNNN
	DCA DNUMBR
	JMS INPUT
	TAD PLUS
	SNA
	JMP DECON
	TAD MINUS
	SZA
	JMP .+4
	CLA CMA
	DCA SIGNNN
DECON,	JMS INPUT
	CLA
	TAD CHAR
	TAD MIN9
	SMA
	JMP I DECONV
	TAD PLUS12
	SPA
	JMP I DECONV
	DCA DIGIT
	TAD HORDER
	AND MASK
	SZA
	JMP DECON
	ISZ DSWIT
	ISZ DNUMBR
	JMS MULT10
	JMP DECON
MULT10,	0
	TAD LORDER
	DCA LTEMP
	TAD HORDER
	DCA HTEMP
	DCA REMAIN
	JMS MULT2
	JMS MULT2
	JMS DUBLAD
	JMS MULT2
	TAD DIGIT
	DCA LTEMP
	DCA HTEMP
	JMS DUBLAD
	TAD REMAIN
	JMP I MULT10
LTEMP,	0
HTEMP,	0
DIGIT,	0
REMAIN,	0
SIGNNN,	0
DNUMBR,	0
MULT2,	0
	CLA CLL
	TAD LORDER
	RAL
	DCA LORDER
	TAD HORDER
	RAL
	DCA HORDER
	TAD REMAIN
	RAL
	DCA REMAIN
	JMP I MULT2
DUBLAD,	0
	CLA CLL
	TAD LORDER
	TAD LTEMP
	DCA LORDER
	RAL
	TAD HORDER
	TAD HTEMP
	DCA HORDER
	RAL
	TAD REMAIN
	DCA REMAIN
	JMP I DUBLAD
MSIGN,	0
	CLA CLL
	ISZ SIGNNN
	JMP I MSIGN
	TAD LORDER
	CMA IAC
	DCA LORDER
	TAD HORDER
	CMA
	SZL
	IAC
	DCA HORDER
	JMP I MSIGN
MINUS,	253-255
PLUS,	-253
MIN9,	-272
PLUS12,	272-260
MASK,	7600
INPUT,	0
	CLA
	KSF
	JMP .-1
	KRB
	DCA CHAR
	TAD CHAR
	JMS I OUTPUT
	TAD CHAR
	SNA
	JMP INPUT+1
	TAD MRBOUT
	SNA
	JMP I RESTRT
	TAD MINCR
	SNA CLA
	JMS I PRINT
	TAD CHAR
	JMP I INPUT
PRINT,	PRCHAR
OUTPUT,	OUT
RESTRT,	FLINTP+1
MRBOUT,	-377
MINCR,	377-215
	*2200
FLOUTP,	0
	JMS I IEDIT
	JMS FOUTCN
	TAD BEXP
	JMS I ITGO
	JMS OUT
	JMS I FEXPPT
	TAD SWIT1
	SNA CLA
	JMP I FLOUTP
	TAD CARRTN
	JMS OUT
	TAD LNFEED
	JMS OUT
	JMP I FLOUTP
FOUTCN,	0
	CLA CLL
	TAD HORDER
	SPA CLA
	CLA CML
	TAD SPLUS
	SZL
	TAD SMINUS
	DCA I 15
	NOP
	NOP
	NOP
	CLA CLL
	TAD HORDER
	SMA CLA
	JMP FGO1
	CMA
	DCA I SNPT
	JMS I MSNPT
FGO1,	CLA CMA
	TAD EXPONT
	DCA EXPONT
	DCA BEXP
FGO2,	TAD EXPONT
	SMA
	JMP FGO3
	TAD FOUR
	SMA CLA
	JMP FGO4
	JMS I 7
	FMPY I TENPT
	FEXT
	CLA CMA
	TAD BEXP
	DCA BEXP
	JMP FGO2
FGO3,	JMS I 7
	FMPY CCC10
	FEXT
	ISZ BEXP
	JMP FGO2
FGO4,	DCA I DPT
	JMS I M2PT
	JMS I M10PT
	SKP
FGO5A,	JMS DIVTWO
	ISZ EXPONT
	JMP FGO5A
	SNA
	JMP FGO7
FGO6,	DCA I 15
	TAD MINUS7
	DCA EXPONT
FGO6A,	JMS I M10PT
	DCA I 15
	ISZ EXPONT
	JMP FGO6A
	JMP I FOUTCN
FGO7,	CLA CMA
	TAD BEXP
	DCA BEXP
	TAD HORDER
	SZA CLA
	JMP .+4
	TAD LORDER
	SNA CLA
	DCA BEXP
	CLA CMA
	JMP FGO6+1
BEXP,	0
MINUS7,	7772
FOUR,	0004
SPLUS,	253
SMINUS,	255-253
PERIOD,	256
MSNPT,	MSIGN
SNPT,	SIGNNN
DPT,	DIGIT
M10PT,	MULT10
M2PT,	MULT2
FEXPPT,	FEXC
TENPT,	TEN
CARRTN,	0215
LNFEED,	0212
CHE,	305
OUT,	0
	TSF
	JMP .-1
	TLS
	CLA
	JMP I OUT
OUTDG,	0
	TAD C260
	JMS OUT
	JMP I OUTDG
C260,	0260
DIVTWO,	0
	CLL RAR
	DCA OUT
	TAD HORDER
	RAR
	DCA HORDER
	TAD LORDER
	RAR
	DCA LORDER
	TAD OUT
	JMP I DIVTWO
CCC10,	7775
	3146
	3150
	0
ITGO,	TGO
IEDIT,	EDIT
	*2400
FLINTP,	0
	CLA CMA
	DCA PRSW
	DCA DSWIT
	JMS I DPCVPT
	CLA
	TAD CHAR
	TAD PER
	SZA CLA
	JMP FIGO1
	TAD PRSW
	SNA CLA
	JMP FIGO2
	DCA I DPN
	DCA PRSW
	JMP I DPCSPT
FIGO1,	TAD PRSW
	SNA CLA
FIGO2,	TAD I DPN
	CMA IAC
	DCA SEXP
	JMS I MSGNPT
FIGO3,	TAD C27
	DCA EXPONT
	JMS I 7
	FNOR
	FPUT FPAC1
	FEXT
	TAD CHAR
	TAD MINUSE
	SZA CLA
	JMP ENDFI
	JMS I DPCVPT
	JMS I MSGNPT
	TAD HORDER
	SPA
	IAC
	SZA CLA
	JMP EXCESS
	TAD LORDER
	TAD SEXP
	DCA SEXP
ENDFI,	JMS I 7
	FGET FPAC1
	FEXT
	TAD SEXP
	SNA
	JMP I FLINTP
	SMA CLA
	JMP FIGO4
	JMS I 7
	FMPY I PCPC10
	FEXT
	ISZ SEXP
	JMP ENDFI+3
	JMP I FLINTP
FIGO4,	JMS I 7
	FMPY TEN
	FEXT
	CLA CMA
	TAD SEXP
	DCA SEXP
	JMP ENDFI+3
EXCESS,	TAD C3777
	DCA EXPONT
	TAD C3777
	DCA HORDER
	JMP I FLINTP
TEN,	0004
	2400
	0000
PCPC10,	CCC10
MINUSE,	-305
C27,	0027
PER,	-256
PRSW,	0
SEXP,	0
C3777,	3777
DPCVPT,	DECONV
DPCSPT,	DECON
MSGNPT,	MSIGN
DPN,	DNUMBR
FEXC,	0
	CLA CLL
	TAD EXPONT
	SPA
	CMA IAC CML
	DCA EXPONT
	TAD C253
	SZL
	TAD C255
	JMS I DGPT
	DCA HORDER
	TAD EXPONT
	ISZ HORDER
	TAD M144
	SMA
	JMP .-3
	TAD C144
	DCA EXPONT
	CMA
	TAD HORDER
	SZA
	JMS I DGPT
	DCA HORDER
	TAD EXPONT
	ISZ HORDER
	TAD M12
	SMA
	JMP .-3
	TAD C12
	DCA LORDER
	CLA CMA
	TAD HORDER
	JMS I DGPT
	TAD LORDER
	JMS I DGPT
	JMP I FEXC
C253,	0253-260
C255,	255-253
M144,	7634
C144,	0144
M12,	7766
C12,	0012
DGPT,	OUTDG
	FADD=1000
	FSUB=2000
	FMPY=3000
	FDIV=4000
	FGET=5000
	FPUT=6000
	FNOR=7000
	FEXT=0000
	SQRE=1
	SQRT=2
	FSIN=3
	FCOS=4
	FARC=5
	FEXP=6
	FLOG=7
	FINP=10
	FOUT=11
	FSNK=12
	FLOT=13
	FABS=14
	FINT=15
	FRND=16
	INPF=JMS I 5
	OUTF=JMS I 6
	FENT=JMS I 7
	*2600
EDIT,	0
	DCA SAC
	TAD 62
	CMA IAC
	DCA COUNT1
	TAD M8
	DCA COUNT2
	TAD SAD1
	DCA 15
	JMP I EDIT
TGO,	0
	DCA 44
	TAD SAD1
	DCA 15
	TAD I 15
	JMS I OUT1
	TAD 62
	SNA CLA
	JMP EFORM
	ISZ TGO
	ISZ TGO
TRYAGN,	TAD 44
	SPA
	JMP MINSS
	TAD SAC
	CMA IAC
	TAD 62
	SPA
	JMP ERR
	SNA
	JMP G01
	CMA IAC
	DCA CNTR
	TAD SPCE
	JMS OUTT
	ISZ CNTR
	JMP .-3
G01,	TAD 44
	CIA
	SNA
	JMP G02
	DCA CNTR
	JMS GET
	JMS OUTT
	ISZ CNTR
	JMP .-3
G02,	TAD SAC
	SNA CLA
	JMP .+3
	TAD PERID
	JMS I OUT1
	JMS GET
	JMS OUTT
	JMP .-2
ERR,	TAD SAC
	SMA CLA
	JMP ERGO
	TAD CHX
	JMS OUTT
	JMP .-2
ERGO,	CLA CMA
	TAD SAC
	DCA SAC
	JMP TRYAGN
MINSS,	CLA
	TAD 62
	CIA
	TAD SAC
	SNA
	JMP G03
	DCA CNTR
	TAD SPCE
	JMS OUTT
	ISZ CNTR
	JMP .-3
G03,	TAD PERID
	JMS I OUT1
	JMS OUTT
	ISZ 44
	JMP .-2
	JMP G02+5
OUTT,	0
	JMS I OUT2
	ISZ COUNT1
	JMP I OUTT
	TAD CHEE
	JMP I TGO
EFORM,	JMS I OUT2
	TAD PERID
	JMS I OUT1
	TAD M7
	DCA COUNT1
	JMS GET
	JMS OUTT
	JMP .-2
GET,	0
	ISZ COUNT2
	JMP .+4
	CLA CMA
	DCA COUNT2
	JMP I GET
	TAD I 15
	JMP I GET
COUNT1,	0
COUNT2,	0
CNTR,	0
SAC,	0
SPCE,	240-260
PERID,	256
CHEE,	305
CHX,	330-260
M8,	-10
M7,	-7
OUT1,	2344
OUT2,	2352
SAD1,	BUFFER-1
BUFFER,	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	*3000
FLOAT,	0
	TAD 64
	DCA 45
	DCA 46
	TAD FCM13
	CIA
	DCA 44
	JMS I 7
	FNOR
	FEXT
	JMP I FLOAT
SINK,	0
	TAD 44
	SZA SMA
	JMP .+3
	CLA
	JMP FCA+1
	TAD FCM13
	SNA
	JMP FCA
	SMA
	JMP FCA+3
	DCA 44
	CLL
	TAD 45
	SPA
	CML
	RAR
	DCA 45
	ISZ 44
	JMP .-7
FCA,	TAD 45
	DCA 64
	JMP I SINK
	DCA 61
	JMP .-3
FCM13,	-13
ROUND,	0
	TAD I IGO2
	DCA 15
	TAD 45
	RAL
	CLA RAR
	DCA FAF
	JMS I 7
	FABS
	FPUT FAB
	FEXT
	CLA
	TAD 65
	SMA
	CIA
	DCA FAG
	TAD 65
	RAL CLA
	TAD FAH
	SZL
	TAD FAI
	DCA FAJ
	JMS I 7
	FGET FA10
	FDIV FA10
	FEXT
	CLA
	TAD 65
	SNA
	JMP .+6
	JMS I 7
FAJ,	FMPY FA10
	FEXT
	ISZ FAG
	JMP .-4
	JMS I 7
	FPUT FAC
	FMPY FAB
	FPUT FAD
	FINT
	FPUT FAE
	FSUB FAD
	FADD FA5
	FEXT
	CLA
	TAD 45
	SMA
	JMP .+7
	JMS I 7
	FGET FA10
	FDIV FA10
	FADD FAE
	FPUT FAE
	FEXT
	JMS I 7
	FGET FAE
	FDIV FAC
	FEXT
	CLA
	TAD FAF
	SZA
	JMS I FACMNS
	TAD 15
	DCA I IGO2
	JMP I ROUND
IGO2,	GO2
FAB,	0
	0
	0
FAC,	0
	0
	0
FAD,	0
	0
	0
FAE,	0
	0
	0
FA10,	4
	2400
	0
FA5,	0
	2000
	0
FAF,	0
FAG,	0
FAH,	FMPY FA10
FAI,	1000
FACMNS,	ACMINS
	*3200
ABSOL,	0
	CLA CLL
	TAD 45
	SMA
	JMP I ABSOL
	JMS I .+2
	JMP .-2
	ACMINS
INPT,	0
	JMS I 5
	JMP I INPT
OUTP,	0
	CLA
	JMS I 7
	FPUT FOUTP
	FEXT
	CLA
	TAD 63
	JMS I 6
	JMS I 7
	FGET FOUTP
	FEXT
	JMP I OUTP
FOUTP,	0
	0
	0
INTR,	0
	CLA CLL
	JMS I ISINK
	JMS I IFLOAT
	JMP I INTR
ISINK,	SINK
IFLOAT,	FLOAT
SINE,	0
	JMP I SINE
COS,	0
	JMP I COS
ARTN,	0
	JMP I ARTN
EXPNT,	0
	JMP I EXPNT
LOG,	0
	JMP I LOG
	LMODE
	SEGMNT 2
	*20
	PDP
	PMODE
	TLS
START,	CLA CLL
	KSF
	JMP .-1
	KCC
	OSR
	SPA
	JMP TWO+1
	TAD M777
	SMA
	JMP TWO
	TAD P777
	DCA FUN
	JMP ONE
TWO,	TAD P777
	TAD ADD
	DCA FUN
	INPF
	FENT
	FPUT A
	FEXT
ONE,	INPF
	FENT
FUN,	0
	FEXT
	TAD P5
	OUTF
	JMP START
ADD,	A&177!200
A,	0
	0
	0
P777,	777
M777,	-777
P5,	5
	FENT=JMS I 7
	FEXT=0
	OUTF=JMS I 6
	INPF=JMS I 5
	FPUT=6000
	FGET=5000
	FNOR=7000
	CRLF=JMS .
	0
	CLA CLL
	TAD CR
	TYPE
	CLA CLL
	TAD LF
	TYPE
	JMP I .-7
CR,	215
LF,	212
	TYPE=JMS .
	0
	TSF
	JMP .-1
	TLS
	JMP I .-4