*20
/QANDAN SUBROUTINE FOR THE
/PDP-12 WHICH RESPONDS TO TTY I/O
/REMOVE *1000 BELOW IF
/INSERTING SOURCE DIRECTLY
/INTO YOUR PROGRAM SOURCE
*1000		/REMOVE,IF DESIRED
/
/TO HERE TO INITIALIZE THE ROUTINE
/
QAINIT,	CLR
	LDA
	1
	STC QB+1
	LDA
	2
	STC QB+3
	LDA
	3
	STC QB+5
	LDA
	4
	STC QB+7
	LDA
	0
	BCL I
	6000
	STC 4
	LDA 4
	STC QTEXT
	LDA I 4
	STC QANS
	LDA I 4
	STC QRFSH
	LDA I 4
	LDA
	4
	BSE I
	6000
	STC QEX
	QHB
	QANS
QALF,	LDA I
QTEXT,	0
	STC 1
	LDA I
QANS,	0
	STC 2
	LDA I
	215
	QTYPE
	NOP
	SKP
QARFSH,	JMP QARF
	LDA I
	212
	QTYPE
	LDH 1
QF,	SAE I
	6		/F
	SKP
	JMP .+4
	SAE I
	10		/H
	SKP
QNF,	LDH I 1
	SAE I
	34		/\
	SKP
	JMP QOUT
	SAE I
	74		/<
	SKP
	JMP QINP
	SAE I
	43		/CR
	SKP
	JMP .+3
	QTYP
	JMP QNF
	LDA I
	215
	QTYPE
	LDA I
	212
	QTYPE
	LDH I 1
	JMP QF
/
/
	QTYP=JMP .
	BCL I
	7700
	ADA I
	-37
	DJR
	APO I
	JMP .+3
	ADA I
	100
	ADA I
	237
	QTYPE=JMP .
	DJR
	IOB
	TSF
	JMP .-3
	TSF=6041
	IOB
	TLS
	TLS=6046
	JMP
/
/
QOUT,	LDA I
	215
	QTYPE
	LDA I
	212
	QTYPE
QB,	SET I 1
	0
	SET I 2
	0
	SET I 3
	0
	SET I 4
	0
	CLR
QEX,	0
/
/
QINP,	LDH I 1
	ADA I
	-60
	APO
	JMP QOUT
	COM
	STC 3
	ADD 2
	STA I
QANO,	0
	LDA I
	272
	QTYPE
	LDA I
	240
	QTYPE
QARF,	KST
QRFSH,	0
	IOB
	KRB
	KRB=6036
	SAE I
	277		/CTRL RO
	SKP		/BACK ONE ANS
	JMP QACR
	SAE I
	375		/ALT MODE
	SKP		/RESETS ALL
	JMP QALF
	SAE I
	215		/CR
	SKP
	JMP QCR
	SAE I
	212		/LF
	SKP
	JMP QOUT
	SAE I
	377		/RO
	SKP
	JMP QRO
	QTYPE
	BCL I
	7700
	STH I 2
	XSK I 3
	JMP QARFSH
	JMP QNF
/
/
QACR,	LDA
	2
	SAE
	QANO
	SKP
	JMP QWB
	LDA
	QANO
	STC 2
	LDH 1
	JMP QINP+1
QWB,	LDA
	2
	SAE
	QANS
	SKP
	JMP QARFSH
	QHB
	1
	QHB
	1
	LDH 1
	SAE I
	74
	JMP .-5
	LDH I 1
	ADA I
	-60
	COM
	STC 3
	QHB
	2
	XSK I 3
	JMP .-3
	LDH 1
	JMP QINP+1
/
/
	QHB=JMP .
	SET 4
	0
	LDA I 4
	LDA
	0
	BCL I
	6000
	STC .+2
	LDA
	0
	STA
	QB2
	STC .+2
	LDA
	0
	APO I
	JMP .+6
	BCL I
	4000
	STA
QB2,	0
	JMP 4
	BSE I
	4000
	ADA I
	-1
	JMP .-7
/
/
QCR,	XSK 3
	SKP
	JMP QNF
	LDH I 2
	XSK I 3
	JMP .-2
	JMP QNF
/
/
QRO,	LDA
	2
	SAE
	QANO
	SKP
	JMP QARFSH
	LDA I
	-1
	ADM
	3
	QHB
	2
	LDA I
	334		/\
	QTYPE
	JMP QARFSH
/
/
TXTSTR,	TEXT "DATA AT BLOCK<3
FUNIT<1 IS DATA TAPE
HDATA BEGINS AT WORD<3 ON THAT BLOCK
BIN SIZE IS<4 MS PER BIN
SCALING FACTOR IS<2 TIMES ACTUAL VALUES\"
/
/
ANSWER,	3434
	3434
	3434
	3434
	3434
	3434
	3434
	3434
	3434
	3434
	3434
	3434
	3434
	3434
/
/
START,	CLR
	IOB
	TLS
	JMP QAINIT
	TXTSTR
	ANSWER
	JMP RFSH
	NOP
	NOP
	NOP
	JMP QAINIT
	ANSWER
	ANSWER
	QARFSH
	NOP
	NOP
	HLT
	JMP START
/
/
RFSH,	JMP QARFSH