+$/
[IODIS
[I\0 ROUTINES USING
[SCOPE DISPLAY
[ROUTINES AND ENTRY:
[#8D DECODE OCTAL
[#8E DECODE DECIMAL
[#8F DISPLAY NUMBER
[#8G DISDNO
[#8H DISPLAY POINTS
[#8J CURS
[#8K DHOR2
[#8L DHOR4
[#8M VERT
[DISPLAY [8F] USES
[8D OR 8E FOR INPUT
[
[DECODE OCTAL IN ACC
[ENTER AT 8D
#8D STA I
NUMBER
SCR 11
BCL I
7770
STC 8I
ADD .-5
SCR 6
BCL I
7770
STC 8I+1
ADD .-12
SCR 3
BCL I
7770
STC 8I+2
ADD .-17
BCL I
7770
STC 8I+3
JMP 0
[
[CONVERT OCTAL TO
[SEPARATED DECIMAL 
[N IN ACC
[USES I10,11,12
[ENTER AT 8E
NUMBER
#8E STC .-1
ADD 0
STC .+33
SET I10
8I-4
SET I11
8I-1
SET I12
-4
CLR
STA I11
LDA 10
COM
ADM 
8E-1
AZE I
JMP .+3
APO
JMP .+5
LDA I
1
ADM 11
JMP .-13
LDA 10
ADM
8E-1
XSK I10
XSK I12
JMP .-23
JMP 0
1750
144
12
1
#8I N1
N2
N3
N4
[
[DISPLAY 4 DIGITS
[STORED IN 8I
[X TO I1, Y TO ACC
[USES I1,10,11,12
[ENTER AT 8F
#8F STC .+20
ADD 0
STC .+23
SET I10
-4
SET I11
8I-1
LDA I11
ROL 1
ADA I
.+23
STC 12
ADD 8G+22
APO
JMP 8Y
LDA I
Y
DSC 12
DSC I12
XSK I10
JMP .+2
JMP 0
ADA I
4
STC .-10
ADD .-2
ADM
1
JMP 8F+7
[CHARACTER TABLE
4136
3641
2100
0177
4523
2151
4122
2651
2414
0477
5172
0651
1506
4225
4443
6050
5126
2651
5131
3452
0
0
[HALF SIZE CHAR
#8Y LDA
8F+20
SRO 12
DIS 1
ADD .+5
SRO I
3737
JMP .-5
LDA I
2
ADM 
1
SRO I
2525
JMP 8Y
XSK I12
SRO I
2525
JMP 8Y
LDA 
1
ADD 8Y+11
STC 1
XSK I10
JMP 8F+7
JMP 8F+25
[
[DISDNO
[DISPLAY DECIMAL
[NUMBER [DECODED]
[USES I1,10,11,12
[ENTER AT 8G
[CALLING SEQUENCE:
[   JMP 8G
[   [NUM]
[   X COORD
[   Y COORD
#8G LDA
0
BCL I 
6000
STA 
.+5
ADA I
JMP 0+3
STC .+21
SET I10
0
LDA 10
STC .+6
LDA I10
STC 1
LDA I10
STC .+5
LDA
NUM
JMP 8E
LDA I
Y
JMP 8F
CLR
STC .-6
JMP 0
[
[DISPLAY 2 QUARTERS
[FROM UMB
[ACC = FWA - 1
[USES I10,11
[ENTER AT 8H
#8H STC .+4
ADD 0
STC .+15
SET I10
0
SET I11
2777
LDA I10
NOP
ADA I
-377
DIS I11
NOP
XSK 11
JMP .-7
JMP 0
[
[CURS
[
[DISPLAY A CURSOR
[ACC[O-8]=FWA LIST
[ACC[9-11]=SAM POT
[ON RETURN, Y OF
[CURSOR TO ACC
[USES I10,11
[ENTER AT 8J
#8J STA I
ACC
BCL I
7770
ADA I
100
STC .+1
SAM 0
ADA I
400
STA
10
NOP [X SHIFT
STC 12
ADD 0
STC .+24
ADD 8J+1
BCL I
0007
ADD 10
STC .+2
LDA
0
NOP [Y SHIFT
ADA I
-340
SET I11
-10
DIS 12
ADA I
-4
XSK I11
JMP .-4
ADA I
400
JMP 0
[
[DHOR4
[HORIZ
[
[DISPLAY HORIZONTAL
[LINE AT ACC VALUE
[EVERY 4-TH POINT
[USES I10,11
[ENTER AT 8L
#8L ADA I
-377
STC .+6
ADD 0
STC .+16
SET I11
2777
LDA I
Y-VALUE
SET I10
-200
DIS I11
XSK I11
XSK I11
XSK I11
NOP
XSK I10
JMP .-6
JMP 0
[
[VERT
[
[DISPLAYS VERTICAL
[LINE AT ACC=X
[USES I10,11
[ENTER AT 8M
#8M STC 11
ADD 0
STC .+12
LDA I
-377
SET I10
-200
DIS 11
ADA I
4
XSK I10
JMP .-4
JMP 0
[END OF IODIS