+$/
[DBLFLT
[FLOPSY
[L2Q2,3
[DOUBLE
[PRECISION
[FLTG. PT.
[SUBROUTINES
$1000
[ADD
#5A CLR
ADD 0
JMP 7A
LDA 1
COM
ADA 2
SKP 14
JMP .+4
SCR 14
BCOI
7737
SCRI 1
ROLI 1
LZEI
COM
STC 7M+1
JMP 6I
LZE
JMP 6H
LDA 1
STA 3
LDAI 2
STAI 3
LDAI 2
STAI 3
JMP 7M
JMP 7H
JMP 7I-2
JMP 6G
LDAI 3
JMP 6C+2
SET 1
6G+1
SETI 2
0
JMP 6D
JMP 7Q
[SUBTRACT
#5B CLR
ADD 0
JMP 7A
JMP 6I
JMP 6D-2
JMP 6H
JMP 5A+3
[MULTIPLY
#5C CLR
ADD 0
JMP 7A
LDA 1
ADA 2
JMP 6E+1
STC 5E
JMP 6C
JMP 6I
JMP 6D
JMP 6H
JMP 6D
LDAI 2
LDAI 2
ROR 1
STA 2
JMP 6H
LDAI 1
MULI 2
STA 3
MSC 5
STAI 3
LDAI 1
ROR 1
MULI 2
ROL 1
STAI 3
JMP 6H+2
LDAI 1
MUL 2
JMP 5F
#5D JMP 6H
LDAI 1
LDAI 1
ROR 1
MULI 2
JMP 5F
JMP 6G
LDAI 3
LDAI 3
ROLI 1
ROL 1
BCLI
7776
STC 7P
JMP 6G
LDAI 3
ROLI 1
STAI 3
JMP 6G
LDA 3
STAI 3
JMP 6G
LDAI
#5E 0
STA 3
JMP 7Q
#5F STC 7X
JMP 6B
STC 7X+1
SETI 1
7X-1
JMP 6G
JMP 7H
SETI 2
-0
JMP 7I
SROI
2525
JMP 5D
JMP 5D+6
[DIVIDE
#5G CLR
ADD 0
JMP 7A
ADD 7K
STC 5J+1
LDAI 2
AZEI
HLT
JMP 6H
LDA 2
COM
ADA 1
JMP 6E+1
JMP 6C
JMP 6H
JMP 6D
JMP 6I
JMP 6D
JMP 6H
LDAI 1
STAI 3
LDAI 1
STAI 3
LDAI 2
COM
STC 7X+1
LDAI 2
COM
STC 7X+2
STC 7X
STC 7Y
SETI 2
7X-3
#5H JMP 6H+2
JMP .+2
#5I JMP 6I+2
JMP 7H
#5J SROI
0001
JMP 5M
SETI 5
-0
JMP 6G
LDAI 3
AZE
JMP 5K-3
LDAI 3
AZEI
JMP 5K+2
CLR
JMP 6G
LDAI 3
#5K APO
JMP 5L
LDA 2
BSE
5J+1
STA 2
XSKI 5
#5L SET 1
6G+1
JMP 6G
JMP 7H
XSK 5
JMP 5H
JMP 5I
#5M XSKI 2
XSKI 2
XSKI 2
SROI
3333
JMP 5J+3
JMP 6G
CLR
ADD 7X
STAI 3
CLR
ADD 7Y
STAI 3
JMP 7Q
[MOVE 1 TO 2
#6A LDA 1
STA 2
LDAI 1
STAI 2
LDAI 1
STAI 2
CLR
JMP 0
[Z TO A
#6B MSC 5
ROL 1
SKP 15
ADD 7K
JMP 0
[COM SETUP
#6C LDAI 1
BCOI 2
ROLI 1
LDAI
NOP
LZE
ADD .+3
STC 7S
JMP 0
JMP 6D-20
SETI 2
-0
[COM\ABS 1
#6D LDAI 1
SCRI 1
ROLI 1
XSK 2
LZE
COM
STA 1
LDAI 1
XSK 2
LZE
COM
STA 1
JMP 0
[OVF CHECK
#6E ADA 3
AZEI
CLR
STA 3
SKP 14
JMP 0
APO
HLT
[RESULT=0
#6F JMP 6G
LDAI
-3777
STA 3
CLR
STAI 3
STAI 3
JMP 7T
[SET 3
#6G SETI 3
0
JMP 0
[SET NORMAL
#6H SETI 2
7Y+4000
SETI 1
7X
JMP 0
[SET REVERSE
#6I SETI 2
7X
SETI 1
7Y
JMP 0
[SETUP
#7A BCLI
6000
STC 4
ADD 0
STC 7E
LDA 4
JMP 7G
JMP 7F
STC 7C
LDAI 4
JMP 7G
JMP 7E+1
STC 7D
LDAI 4
JMP 7G
NOP
STC 6G+1
#7B JMP 6I
SETI 1
#7C 0
JMP 6A
XSKI 2
SETI 1
#7D 0
JMP 6A
XSKI 4
ADD 4
ADD 7A+1
STC 7T
STC 7P
JMP 6G
JMP 6H
#7E RTN
STC 7D
ADD 7F+2
JMP 7B-1
#7F STC 7D
LDAI
7Z
STC 7C
JMP 7E+2
[IR+SIGN TEST
#7G APOI
XSKI 0
APO
COM
ADAI
-17
SCRI 1
ROLI 1
ADD 7G+3
LZEI
JMP 0
STC 1
LDA 1
ADD 7S-1
STA 1
ADAI
-3
JMP 0
[ADD 1 TO 3
#7H SET 4
0
CLR
JMP 6G
LDAI 1
STC 7J
LDAI 3
STC 7J+2
LDA 1
LAM 3
LDAI 1
LAMI 3
JMP 6G
STC 0
LAMI 3
STC 0
LAMI 3
JMP 4
SETI 2
0
[CHECK FOR
[ADD OVERFLOW
#7I SET 1
0
JMP 6G
LDAI
#7J 0
BCOI
0
APO
JMP 1
LDAI 3
BCO
7J
APOI
JMP 1
JMP 6G
LDAI
#7K 1
JMP 6E
LDAI
#7L -1
XSK 2
JMP 7M+2
ADD 7P
XSK 2
COM
STC 7P
JMP 6G
LDAI 3
BCOI
4000
STA 3
JMP 1
[SCR N  3
#7M LDAI
0
SET 2
0
AZEI
JMP 2
STC 5
SETI 4
-30
#7O CLR
JMP 6G
LDAI 3
SCRI 1
STA 3
LDAI 3
RORI 1
STA 3
XSKI 4
JMP .+2
JMP .+3
XSKI 5
JMP 7O
JMP 6G
LDAI 3
ROLI 1
LZE
COM
STC 7P
JMP 2
#7P 0
[NORMALIZE,
[ROUND,XIT
#7Q CLR
STC 1
ADD 7P
RORI 1
JMP 6G
LDAI 3
SAEI 3
JMP .+5
AZE
JMP .+3
LZEI
JMP 6F
JMP 6G
LDAI 3
APO
JMP 7U
ROL 1
APOI
JMP 7T+1
#7R JMP 6G
LDAI 3
LDAI 3
RORI 1
STC 0
LAM 3
JMP 6G
STC 0
LAMI 3
APO
JMP 7V
JMP 6G
CLR
ADD 1
COM
JMP 6E
SET 1
3
#7S NOP
CLR
#7T XIT
LDAI 3
ROLI 1
STA 3
JMP 6G
LDAI 3
ROLI 1
STA 3
XSKI 1
JMP 7R-3
#7U JMP 7V
JMP 7R
#7V CLR
ADD 0
STC 7W
ADD 7L
JMP 7M+2
ADD 7L
ADD 1
STC 1
LDA 3
BCLI
4000
STA 3
#7W RTN
[ARG 1
#7X 0
0
0
[ARG 2
#7Y 0
0
0
[FAC
#7Z 0
0
0
[TRANSFER
#5N CLR
ADD 0
JMP 7A
SET 2
7D
JMP 6A
JMP 7T-1
[FLOAT
#5O CLR
ADD 0
JMP 7A
ADD 7D
STC 6G+1
JMP 6G
LDAI
27
STA 3
JMP 5B-10
[FIX
#5P CLR
ADD 0
JMP 7A
ADD 7D
STC 6G+1
JMP 6G
LDAI
-27
JMP 6E
APOI
JMP 7T
JMP 7M+2
JMP 7T-1