[DISPIMP4
[DISPLAY OF DATA COLLECTED WITH SAM IMP4
  ----
$20
[PRINT OPTIONS MESSAGE
SETi1
2D+3777
JMP 2M
#1E SETi1
2A+3777
JMP 2M
JMP 2E
JMP 1E
COM
STC 1R
JMP 2M
JMP 2E
JMP 1E
COM
STC 1S
JMP 2M
JMP 2E
JMP 1E
COM
STC 1T
JMP 2M
#1F SETi1
2B+3777
JMP 2M
JMP 2E
JMP 1F
COM 
STC 1U
#2Z OPR 1
SETi3
-1002
LDA
1P
ADAi
-10
STC 1P
RDCui
#1P 4010
XSKi3
JMP p+2
JMP 2Y
SETi2
3777
LDAi
#1R 000
SAEi2
JMP 1G
LDAi
#1S 000
SAEi2
JMP 1G
LDAi
#1T 000
SAEi2
JMP 1G
LDAi
#1U 000
SAEi2
JMP 1G
LDAi
1001
ADD 1P
STA
1Q
ADD p-4
STA
1Q+2
ADD p-7
STC 1Q+4
RDCui
#1Q 5001
RDCui
6002
RDCu
7203
JMP 1H
#1G LDAi
1
ADM
1P
SAEi
5000
JMP 1P-1
LDAi
4010
STC 1P
JMP 1P-1
#2Y MTBu
0000
SETi1
2C+3777
JMP 2M
JMP 7R
JMP 7P
SAEi
31
JMP 1E
JMP 1F
[MESSAGE PRINT
#2M SET 10
0
LDHi1
SHDi
7200
JMP 10
JMP 7P
JMP p-5
[ENTER DIGITS
#2E SET 10
0
CLR
STC 2J
JMP 7R
SHDi
1300
JMP 2H
SHDi
1400
JMP 2J-1
SHDi
1200
JMP 2J-1
SHDi
2500  [B
JMP 1E
SHDi
4300  [P
JMP 2V
SHDi
6000  [?
JMP 2G
ADAi
-11
APOi
JMP 2E+4
ADAi
11
AZEi
CLR
JMP 7P
STC p+5
ADD 2J
MULi
12
ADAi
0000
STC 2J
JMP 2E+4
LDAi
#2J 0000
XSKi10
JMP 10
[DELETE
#2H LDAi
22
JMP 7P
SROi
3777
JMP p-5
JMP 10
[QUERY
#2G JMP 7P
JMP 1H+1
[SAME 
#2V SETi1
2V+4+3777
JMP 2M
JMP 2Z
"AND REMAINING PARAMETERS AS ABOVE.<'
[MESSAGES
#2A"
-
-
TIME  <'
":<:<:<'
#2B"
FREQ.  <'
#2C"
NO SUCH DATA. FOR NEW FREQUENCY ONLY, TYPE F. OTHERWISE ANY KEY.<'
[L6BUFTTY
[LAP 6 COMPATIBLE VERSION OF BUFFERED TELETYPE SUBROUTINES.
[READ AND PRINT
[ALPHANUMERICS
[SUBROUTINE.
[AJH REVISED
[JUNE 1967
[LAP 6 CHARACTER
[IN ACCUM.
[PRINT
#7P STC p+13
ADD 0
STC p+14
ADD p+10
ADAi
7L
STC p+2
LDA
0
OPRi2
LDAi
0
SAEi
12
JMP 000
SROi
5252
JMP p-3
LDAi
212
JMP p-13
[READ.LEAVES
[LAP 6 CHARACTER
[IN ACCUM.
#7R LDA
0
STC p+33
ADD 1
STC p+22
ADD 2
STC p+23
OPRi1
SETi1
-101
SETi2
7L-1
SAEi2
JMP p+21
LDAi
7L
COM
ADD 2
AZEi
COM
STC p+10
LDAi
0
STC 1
LDAi
0
STC 2
LDAi
0
JMP 000
XSKi1
JMP p-23
JMP p-14
[TABLE
#7L 260
261
262
263
264
265
266
267
270
271
215
377
240
246
247
255
253
257
243
215
301
302
303
304
305
306
307
310
311
312
313
314
315
316
317
320
321
322
323
324
325
326
327
330
331
332
251
000
277
275
245
254
256
244
333
300
336
273
274
276
335
252
272
207
[END SUBROUTINE L6BUFTTY.
[DISPLAY MESSAGE
#1H SETi1
2F+3777
JMP 2M
JMP 2E
JMP p-4
ADAi
JMP 1W+1
STC 1W
#1W JMP 000
JMP 1E  [NEW DATA
JMP 8A  [R X T
JMP 8B  [X X T
JMP 8C  [PA X T
JMP 8D  [R+X X T
JMP 8E  [R X X 
[RESISTANCE VS. TIME
#8A SETi2
2077
SETi4
1037
JMP 1A
STC p+2
LDAi2
SCR 0
DISi4
LDAi2
XSK 4
JMP p-5
SXL 1
JMP 8A
JMP 1H
[SET ATTENUATION
#1A SAM 0
ADAi
177
SCR 4
ADAi
0340
JMP 0
[REACTANCE VS. TIME
#8B SETi2
2100
SETi4
1037
JMP 1A
STC p+2
LDAi2
SCR 0
DISi4
LDAi2
XSK 4
JMP p-5
SXL 1
JMP 8B
JMP 1H
[PHASE ANGLE VS. TIME
#8C SETi1
2076
SETi2
6077
SETi4
1037
JMP 1A
STC 1B
LDAi1
LDAi2
LDAi
2631
MULi2
STC 7A
ZTA
LZE
COM
ROL 1
STC 7B
ADD 7A
SCRi1
STC 7A
ADD 7B
RORi1
STC 7B
LDAi1
STC 7C
JMP 7D
LDA
7B
#1B SCR 0
DISi4
XSK 4
JMP 8C+10
SXL 1
JMP 8C
JMP 1H
[RESISTANCE VS REACTANCE
#8D SETi1
2076
SETi2
2077
SETi4
1037
JMP 1A
STA
1C
STC 1C+3
LDAi1
LDAi2
LDAi1
#1C SCR 0
STC 5
LDAi2
SCR 0
DIS 5
XSKi4
JMP 8D+12
SXL 1
JMP 8D
JMP 1H
[OPTION MESSAGES
#2D"
-
-
OPTIONS -
FETCH NEW DATA . . . . . 00
RESISTANCE VS. TIME  . . 01
REACTANCE VS. TIME . . . 02
PHASE ANGLE VS. TIME . . 03
REACTANCE VS. RESISTANCE 04
-
<'
#2F "
DISPLAY  <'
[DPDIV2
[DOUBLE PREC.
[DIVISION SUB-
[ROUTINE.
[ON ENTRY -
[DIVIDEND MSB
[IN 7A, LSB IN
[7B, DIVISOR
[IN 7C.
[ON EXIT -
[QUOTIENT MSB
[IN 7A, LSB IN
[7B, DIVISOR
[UNCHANGED IN
[7C. REMAINDER
[IN ACCUMUL.
[AJH APR.67
#7D LDA
0
STC 7A+10
LDAi
#7C 0
AZEi
JMP 0
APOi
COM
STC 7B-11
STC 7B-13
ADD 7A
STAi
0
APOi
JMP p+6
COM
STC 7A
ADD 7B
COM
STC 7B
LDAi
3777
STC 7B+2
ADD 7B-2
STC 7B+5
CLR
ADD 7B
ROLi1
STC 7B
ADD 7A
ROLi1
STC 7A
ADD 7B-13
ROLi1
STAi
0
ADAi
0
AZEi
COM
APO
JMP p+6
STC 7B-13
LDAi
1
ADMi
#7B 0
SROi
3777
JMP 7B-25
SROi
0001
JMP 7B-25
LDA
7C+11
APOi
JMP p+5
LDA
7B-13
COM
STC 7B-13
LDA
7C
BCO
7C+11
APOi
JMP p+10
LDAi
#7A 0
COM
STC 7A
ADD 7B
COM
STC 7B
LDA
7B-13
JMP 000
[END DP-DIV-2
[  ------
[   ----
[END DISPIMP4