[LOGPLOT
SETi2
3777
SETi1
0
#1A XSKi1
JMP p+2
JMP 1B
LDA
1
JMP 7E
STAi2
JMP 1A
#1B SETi1
3777
CLR
STC 1C
STC 1C-1
JMP 3W
JMP 3L
JMP 4P
2000
0
JMP 4P
2000
1200
JMP 4P
0
1200
JMP 4P
0
0
#1D LDAi1
STC 1C
ADD 1C-1
ADAi
1
STC 1C-1
JMP 4P
0
#1C 0
XSK 1
JMP 1D
JMP 3R
HLT
[LOGBASE2
[SUBROUTINE AJH
[26 MARCH 71 VERSION
[ON ENTRY, VALUE IN ACCUM.
[ENTRY - JMP 7E
[EXITS WITH LOG BASE 2 IN ACCUM.
[   6 BITS +  6 BITS
[ MANTISSA + CHARACTERISTIC
[VALUE DIVIDED BY 8
[ALL NEG. VALUES SET TO ZERO
[ 
#7E APO
CLR       [NEG. VALUES SET TO ZERO
STC p+25  [SAVE VALUE
ADD 0
STC p+30  [SAVE RETURN JMP
ADD 17
STC p+23  [SAVE REG 17 CONTENT
SETi17
-11
CLR       [CLEAR LINK
ADD p+15  [LOAD VALUE
XSKi17
JMP p+2
JMP p+4
ROLi1
LZEi
JMP p-5
ROL 6
STC p+5   [SAVE CHARACTERISTIC
LDA
17
COM       [MANTISSA
STHi
0000      [ORIGINAL VALUE, LATER LOG BASE 2
LDAi
0000      [CONTENTS REG 17
STC 17    [RESTORED
ADD p-4
JMP 0000  [RETURN JMP
[ 
[END SUBROUTINE LOGBASE2
[ 
[ R
[  E
[   M
[    O
[O    V
[ R    E
[  I
[   G
[    I
[     N
$400
[  ------
[   ----
[SIMPLOT
[CALL AS FOLLOWS-
[JMP 4P
[   X
[   Y
[NEXT INSTRUCTION
[AJH, JUNE 1967
#4P LDA
0
BCLi
6000
STC 14
LDA 14
STC 4X
LDAi14
STC 4Y
LDAi14
LDA
14
ADD 4P+3
STC p+2
JMP 4Z
JMP 000
[CLOSEOUT PLOT
#4Q SET 17
0
CLR
STC 3X
STC 3Y
JMP 3R+2
[SET PLOTTER WIDE
#3W LDA
0
STC 3U+20
LDAi
OPR 10
STC 4J+6
LDAi
OPR 7
STC 4J+12
LDAi
OPR 12
STA
3U+12
STC 4K+6
LDAi
OPR 11
STA
3U+3
STC 4K+12
JMP 3U
[SET PLOTTER TALL
#3T LDA
0
STC 3U+20
ADD 3W+17
STA
3U+12
STC 4J+6
ADD 3W+12
STA
3U+3
STC 4J+12
ADD 3W+4
STC 4K+6
ADD 3W+7
STC 4K+12
[RESET PEN POSITION BEFORE STARTING.
#3U JMP 4Q
LDAi
-3000
OPR 11
JMP 4L
ADD 4E
APO
JMP p-4
LDAi
-62
OPR 12
JMP 4L
ADD 4E
APO
JMP p-4
JMP 4Q
JMP 0000
[INTERPOL
JMP 000
#4Z LDA
0
STC 4Z-1
STC 15
ADD 3X
COM
ADD 4X
STAi
#4A 0
APO
COM
STC 4B
ADD 3Y
COM
ADD 4Y
STAi
#4C 0
APO
COM
STC 4D
ADD 4D
COM
ADD 4B
APO
CLR
ADD 4D
AZEi
JMP 4Z-1
ROL 1
XSKi15
APOi
JMP p-3
LDAi
240
ADD 15
STC 4H
ADD 15
COM
ADAi
254
STC 4G
ADD 4E
#4G ROL 10
ADD 4E
COM
STC 15
ADD 4B
JMP 4H
STC 4B
ADD 4D
JMP 4H
STC 4D
STC 4M+3
STC 4M+11
#4M CLR
ADD 4B
LAMi
0
LZE
JMP 4J
CLR
ADD 4D
LAMi
0
LZE
JMP 4K
LDAi
#4I 0
APOi
JMP 4L
COM
STC 4I
ADD 4E
ADM
15
AZE
JMP 4M
JMP 4Z-1
#4X 0
#4Y 0
#4B 0
#4D 0
#4H ROL 4
JMP 0
#4J SET 17
0
LDA
4A
APO
JMP p+5
OPR 10
LDAi
#4E 1
JMP p+4
OPR 7
LDAi
#4F -1
ADMi
#3X 0
CLR
STC 4I
JMP 17
#4K SET 17
0
LDA
4C
APO
JMP p+5
OPR 12
LDA
4E
JMP p+4
OPR 11
LDA
4F
ADMi
#3Y 0
CLR
STC 4I
JMP 17
#4L SET 17
0
SETi16
1640
XSKi16
JMP p-1
JMP 17
[LOWER PEN
#3L SET 17
0
LDAi
#4R 7777
APO
JMP 17
OPR 14
CLR
COM
STC 4R
SETi16
0
XSKi16
JMP p-1
SROi
3333
JMP 3L+12
JMP 17
[RAISE PEN
#3R SET 17
0
LDA
4R
APOi
JMP 17
OPR 13
CLR
STC 4R
JMP 3L+12
[END OF INTERPOL
[END SHORTENED SIMPLOT
[LOGPLOT