[PLOTIMP5
[SIMPLE PLOTTING PROGRAMS FOR IMPEDANCE DATA
  ----
$20
[PRINT OPTIONS MESSAGE
SETi1
2D+3777
JMP 2M
JMP 3W
#1E SETi1
2A+3777
JMP 2M
JMP 2E
JMP 1E
STC 1R
JMP 2M
JMP 2E
JMP 1E
STC 1S
JMP 2M
JMP 2E
JMP 1E
STC 1T
#1F SETi1
2B+3777
JMP 2M
JMP 2E
JMP 1F
STC 1U
#2Z OPR 1
SETi3
-1002
RDCui
#1P 4010
XSKi3
JMP p+2
JMP 2Y
LDA
2000
SCR 13
STAi
#5H 0000
SETi7
5H
SETi2
3777
LDAi
#1R 000
SRO 7
COM
SAEi2
JMP 1G
LDAi
#1S 000
SRO 7
COM
SAEi2
JMP 1G
LDAi
#1T 000
SRO 7
COM
SAEi2
JMP 1G
LDAi
#1U 000
SRO 7
COM
SAEi2
JMP 1G
LDAi
1001
ADD 1P
STA
1Q
ADD p-4
STA
1Q+2
ADD p-7
STC 1Q+4
RDCui
#1Q 5001
RDCui
6002
RDCu
7203
JMP 1H
#1G LDAi
1
ADM
1P
SAEi
5000
JMP 1P-1
LDAi
4010
STC 1P
JMP 1P-1
#2Y MTBu
0000
SETi1
2C+3777
JMP 2M
JMP 7R
JMP 7P
SAEi
31
JMP 1E
JMP 1F
[MESSAGE PRINT
#2M SET 10
0
LDHi1
SHDi
7200
JMP 10
JMP 7P
JMP p-5
[ENTER DIGITS
#2E SET 10
0
CLR
STC 2J
JMP 7R
SHDi
1300
JMP 2H
SHDi
1400
JMP 2J-1
SHDi
1200
JMP 2J-1
SHDi
4300  [P
JMP 2V
JMP 7P
SHDi
2500  [B
JMP 1E
SHDi
6000  [?
JMP 2G
ADAi
-11
APOi
JMP 2E+4
ADAi
11
AZEi
CLR
STC p+5
ADD 2J
MULi
12
ADAi
0000
STC 2J
JMP 2E+4
LDAi
#2J 0000
XSKi10
JMP 10
[DELETE
#2H LDAi
22
JMP 7P
SROi
3777
JMP p-5
JMP 10
[QUERY
#2G JMP 7P
JMP 1H+1
[SAME 
#2V SETi1
2V+4+3777
JMP 2M
JMP 2Z
"AND REMAINING PARAMETERS AS ABOVE.<'
[MESSAGES
#2A"
-
-
TIME  <'
":<:<:<'
#2B"
FREQ.  <'
#2C"
NO SUCH DATA. FOR NEW FREQUENCY ONLY, TYPE F. OTHERWISE ANY KEY.<'
[L6BUFTTY
[LAP 6 COMPATIBLE VERSION OF BUFFERED TELETYPE SUBROUTINES.
[READ AND PRINT
[ALPHANUMERICS
[SUBROUTINE.
[AJH REVISED
[JUNE 1967
[LAP 6 CHARACTER
[IN ACCUM.
[PRINT
#7P STC p+13
ADD 0
STC p+14
ADD p+10
ADAi
7L
STC p+2
LDA
0
OPRi2
LDAi
0
SAEi
12
JMP 000
SROi
5252
JMP p-3
LDAi
212
JMP p-13
[READ.LEAVES
[LAP 6 CHARACTER
[IN ACCUM.
#7R LDA
0
STC p+33
ADD 1
STC p+22
ADD 2
STC p+23
OPRi1
SETi1
-101
SETi2
7L-1
SAEi2
JMP p+21
LDAi
7L
COM
ADD 2
AZEi
COM
STC p+10
LDAi
0
STC 1
LDAi
0
STC 2
LDAi
0
JMP 000
XSKi1
JMP p-23
JMP p-14
[TABLE
#7L 260
261
262
263
264
265
266
267
270
271
215
377
240
246
247
255
253
257
243
215
301
302
303
304
305
306
307
310
311
312
313
314
315
316
317
320
321
322
323
324
325
326
327
330
331
332
251
000
277
275
245
254
256
244
333
300
336
273
274
276
335
252
272
207
[END SUBROUTINE L6BUFTTY.
[PLOT MESSAGE
#1H SETi1
2F+3777
JMP 2M
JMP 2E
JMP p-4
ADAi
JMP 1W+1
STC 1W
ADD 1V
STC 1X
STC 1Y
#1W JMP 000
JMP 1E  [NEW DATA
JMP 8A  [R X T
JMP 8B  [X X T
JMP 8C  [PA X T
JMP 8D  [ADV.FR.
JMP 8E  [BACKSP
JMP 8F  [X INCR
JMP 8G  [Y GAIN
JMP 8H  [ADV 1 INCH AND CLOSEOUT
[PLOTTING KERNEL
#1Z SET 10
0
ROL 2   [VARIABLE
APOi
JMP p+3
BSEi
7700
SCR 2
STC 1Y
NOP   [PEN LOWER
JMP 4P
#1X 0
#1Y 0
LDAi
JMP 3L
STC 1X-2
LDAi
#1V 2      [X INCREMENT
ADM
1X
XSKi3
JMP 10
LDAi
NOP
STC 1X-2
XSKi10
JMP 10
[RESISTANCE VS. TIME
#8A SETi2
2076
LDAi
6005
STC 1A+1
SETi3
-740
LDAi2
LDAi2
JMP 1A
JMP 1Z
JMP p-4
#8Z JMP 3R
JMP 4P
0
0
JMP 1H
[RCAL AND XCAL CORRECTION
#1A MUL
6000
LZE
COM
SCR 7
ZTA
LZE
COM
JMP 0
[REACTANCE VS. TIME
#8B SETi2
2077
LDAi
6006
STC 1A+1
JMP 8A+5
[PHASE ANGLE VS. TIME
#8C SETi1
2076
SETi2
6077
SETi3
-740
LDAi1
LDAi2
LDA
2006   [XCAL
MULi2
JMP 1B
LDA
2005   [RCAL
STC 7C
JMP 7D
LDAi
2630   [25 DECIMAL TIMES 57.296 DEGREES
MUL
7B+4000
JMP 1B
LDAi1
STC 7C
JMP 7D
LDA
7B
JMP 1Z
JMP 8C+6
JMP 8Z
[ADJUST 24 BIT PRODUCT
#1B STC 7A
ZTA
LZE
COM
ROL 1
STC 7B
ADD 7A
SCRi1
STC 7A
ADD 7B
RORi1
STC 7B
JMP 0
[ADVANCE 1 FRAME
#8D LDA
1V
MULi
740
STC p+3
STC p+3
JMP 4P
000
000
JMP 4Q
JMP 1H
[ADVANCE 1 INCH
#8H LDAi
144
JMP 8D+4
[BACKSPACE 1 FRAME
#8E LDA
1V
COM
JMP 8D+2
[SET X INCREMENT
#8F SETi1
8X+3777
JMP 2M
JMP 2E
JMP 8F
AZEi
JMP 8F
ADAi
-4
APOi
JMP 8F
ADAi
4
STC 1V
JMP 1H
#8X"
X INCR.[1,2,3,4] <'
[SET Y GAIN
#8G SETi1
8Y+3777
JMP 2M
JMP 2E
JMP 8G
ADAi
-3
APOi
JMP 8G
ADAi
3
AZEi
CLR
BSEi
0240
STC 1Z+2
JMP 1H
#8Y"
Y GAIN [0,1,2,3] <'
[OPTION MESSAGES
#2D"
-
-
OPTIONS -
FETCH NEW DATA . . . . . 00
RESISTANCE VS. TIME  . . 01
REACTANCE VS. TIME . . . 02
PHASE ANGLE VS. TIME . . 03
ADVANCE ONE FRAME  . . . 04
BACKSPACE ONE FRAME  . . 05
SET X-AXIS INCREMENT . . 06
SET Y-AXIS GAIN  . . . . 07
ADVANCE ONE INCH . . . . 08
-
<'
#2F "
PLOT  <'
[DPDIV2
[DOUBLE PREC.
[DIVISION SUB-
[ROUTINE.
[ON ENTRY -
[DIVIDEND MSB
[IN 7A, LSB IN
[7B, DIVISOR
[IN 7C.
[ON EXIT -
[QUOTIENT MSB
[IN 7A, LSB IN
[7B, DIVISOR
[UNCHANGED IN
[7C. REMAINDER
[IN ACCUMUL.
[AJH APR.67
#7D LDA
0
STC 7A+10
LDAi
#7C 0
AZEi
JMP 0
APOi
COM
STC 7B-11
STC 7B-13
ADD 7A
STAi
0
APOi
JMP p+6
COM
STC 7A
ADD 7B
COM
STC 7B
LDAi
3777
STC 7B+2
ADD 7B-2
STC 7B+5
CLR
ADD 7B
ROLi1
STC 7B
ADD 7A
ROLi1
STC 7A
ADD 7B-13
ROLi1
STAi
0
ADAi
0
AZEi
COM
APO
JMP p+6
STC 7B-13
LDAi
1
ADMi
#7B 0
SROi
3777
JMP 7B-25
SROi
0001
JMP 7B-25
LDA
7C+11
APOi
JMP p+5
LDA
7B-13
COM
STC 7B-13
LDA
7C
BCO
7C+11
APOi
JMP p+10
LDAi
#7A 0
COM
STC 7A
ADD 7B
COM
STC 7B
LDA
7B-13
JMP 000
[END DP-DIV-2
[  ------
[   ----
[PART OF
[SIMPLOT
[CALL AS FOLLOWS-
[JMP 4P
[   X
[   Y
[NEXT INSTRUCTION
[AJH, JUNE 1967
#4P LDA
0
BCLi
6000
STC 14
LDA 14
STC 4X
LDAi14
STC 4Y
LDAi14
LDA
14
ADD 4P+3
STC p+2
JMP 4Z
JMP 000
[CLOSEOUT PLOT
#4Q SET 17
0
CLR
STC 3X
STC 3Y
JMP 3R+2
[SET PLOTTER WIDE
#3W LDA
0
STC 3U+20
LDAi
OPR 10
STC 4J+6
LDAi
OPR 7
STC 4J+12
LDAi
OPR 12
STA
3U+12
STC 4K+6
LDAi
OPR 11
STA
3U+3
STC 4K+12
JMP 3U
[SET PLOTTER TALL
#3T LDA
0
STC 3U+20
ADD 3W+17
STA
3U+12
STC 4J+6
ADD 3W+12
STA
3U+3
STC 4J+12
ADD 3W+4
STC 4K+6
ADD 3W+7
STC 4K+12
[RESET PEN POSITION BEFORE STARTING.
#3U JMP 4Q
LDAi
-3000
OPR 11
JMP 4L
ADD 4E
APO
JMP p-4
LDAi
-75
OPR 12
JMP 4L
ADD 4E
APO
JMP p-4
JMP 4Q
JMP 0000
[INTERPOL
JMP 000
#4Z LDA
0
STC 4Z-1
STC 15
ADD 3X
COM
ADD 4X
STAi
#4A 0
APO
COM
STC 4B
ADD 3Y
COM
ADD 4Y
STAi
#4C 0
APO
COM
STC 4D
ADD 4D
COM
ADD 4B
APO
CLR
ADD 4D
AZEi
JMP 4Z-1
ROL 1
XSKi15
APOi
JMP p-3
LDAi
240
ADD 15
STC 4H
ADD 15
COM
ADAi
254
STC 4G
ADD 4E
#4G ROL 10
ADD 4E
COM
STC 15
ADD 4B
JMP 4H
STC 4B
ADD 4D
JMP 4H
STC 4D
STC 4M+3
STC 4M+11
#4M CLR
ADD 4B
LAMi
0
LZE
JMP 4J
CLR
ADD 4D
LAMi
0
LZE
JMP 4K
LDAi
#4I 0
APOi
JMP 4L
COM
STC 4I
ADD 4E
ADM
15
AZE
JMP 4M
JMP 4Z-1
#4X 0
#4Y 0
#4B 0
#4D 0
#4H ROL 4
JMP 0
#4J SET 17
0
LDA
4A
APO
JMP p+5
OPR 10
LDAi
#4E 1
JMP p+4
OPR 7
LDAi
#4F -1
ADMi
#3X 0
CLR
STC 4I
JMP 17
#4K SET 17
0
LDA
4C
APO
JMP p+5
OPR 12
LDA
4E
JMP p+4
OPR 11
LDA
4F
ADMi
#3Y 0
CLR
STC 4I
JMP 17
#4L SET 17
0
SETi16
1640
XSKi16
JMP p-1
JMP 17
[LOWER PEN
#3L SET 17
0
LDAi
#4R 7777
APO
JMP 17
OPR 14
CLR
COM
STC 4R
SETi16
0
XSKi16
JMP p-1
SROi
3333
JMP 3L+12
JMP 17
[RAISE PEN
#3R SET 17
0
LDA
4R
APOi
JMP 17
OPR 13
CLR
STC 4R
JMP 3L+12
[PLOTIMP5
[LAST MOD 10 MAR 70