[EXAMOUT
[PROGRAMS TO GENERATE ORDERED LISTS AND GRAPHS FROM EXAM RESULTS LIST 
[EXAM DATA IN LAP-6 WORKING AREA OF TAPE ON UNIT 1, SAVED AS FOLLOWS-
[NO HEADER
[STUDENT SCORE, UP TO 2888 DECIMAL
[STUDENT NUMBER, UP TO 2000 OCTAL
[STUDENT SCORE
[STUDENT NUMBER
[STUDENT SCORE
[ETC. ETC.
[....
[PROGRAMS INCLUDE-
[1. MSS INPUT DATA TAKEN FROM UNIT 1, CONVERTED TO OCTAL AND PLACED IN QUARTER 6
[2. DATA ORDERED FROM MAX SCORE TO MIN SCORE
[3. MAX TO MIN LIST PRINTED OUT
[4. MIN TO MAX LIST GENERATED
[5. HISTOGRAM OUTPUT
[6. MIN TO MAX LIST PRINTED OUT
[NOTE - OPTIONS 4,5,6 ONLY IF SENSE SWITCH 5 IS SET UP
$20
JMP 8A [INPUT
SNSi4
JMP 8B [PRINT
JMP 8C [SORT
JMP 8B [PRINT
SNS 5
HLT
JMP 8D [SORT,MIN - MAX
JMP 8E [GRAPH
JMP 8B [PRINT
HLT
[INPUT
#8A SET 10
0
SETi1
3000
SETi2
7401
RDCu
#1B 7350
CLR
STC 3
STC 17
STC 1N
#1A LDHi2 [PICK UP CHARACTER
SHDi
1400 [SPACE
JMP 1W
SHDi
1200 [EOL
JMP 1W
SHDi
7700 [END OF MS
JMP 1E
SETi17
0
ADAi
-11
APOi
JMP 1C [ILLEGAL CHARACTER - IGNORE
LDH 2 [DIGIT
STC 1T
ADD 1N
MULi
12
ADAi
#1T 0000
STC 1N
#1C LDA
2
SAEi
7777 [WAS THIS LAST CHARACTER IN BLOCK
JMP 1A [NO
LDA
1B
ADAi
1
STC p+2
RDCu
7351
SETi2
7377
JMP 1A
#1W LDA
17
APO
JMP 1C
SETi17
7777
LDAi
#1N 0000
STAi1
CLR
STC 1N
XSKi3
NOP
JMP 1C
#1E LDAi
1
ADD 3
SCR 1
STA
3000
CLR
STAi1
SROi
3333
JMP p-3
JMP 10
1Z=3001
[SORT MAX TO MIN
#8C SET 10
0
#2B SETi1
1Z-1
SETi2
1Z+1
LDA
3000
COM
ADAi
1
STC 3
STC 2F
#2D LDAi1
COM
ADAi2
AZEi
JMP p+3
#2S APOi
JMP 2X [EXCHANGE
LDAi1
LDAi2
#2C XSKi3
JMP 2D
LDAi
#2F 0000
APO
JMP 2B
JMP 10
#2X LDA 1
STC 2T
LDA 2
STA 1
LDAi
#2T 0000
STA 2
LDAi1
STC 2T
LDAi2
STA 1
LDA
2T
STA 2
LDAi
7777
STC 2F
JMP 2C
[SORT MIN TO MAX
#8D SET 11
0
LDAi
APO
STC 2S
JMP 8C
LDAi
APOi
STC 2S
JMP 11
[PRINT
#8B SET 10
0
SETi1
1Z
LDA
3000
COM
STC 2
JOP9T
0012
JOPp+1
#3B JOP9T
0001
JOPp+1
SETi3
-12
#3A JOP9T
0105
0301
0103
0301
0001
JOPp+1
XSKi2
JMP p+2
JMP 10
XSKi3
JMP 3A
JMP 3B
[GRAPH
#8E SET 10
0
LDAi
0060 [DEC 48
STC 4L
SETi1
1Z
LDA
3000
COM
STC 3
JOP9T
0012
JOPp+1
#4A LDAi
1
ADM
4L
SAEi
0145 [IS NEXT BAR NUMBER 101 DEC
JMP p+2
JMP 4C [FINISHED
MULi
12
ADAi
4
COM
STC 4M
JOP9T
0001
JOPp+1
SETi7
4L
JOP9T
0307
0101
JOPp+1
LDAi
311
OPRi2
XSK 3
JMP p+2
JMP 4A
#4B LDA
4M
ADA 1
APOi
JMP 4A
LDAi
330
OPRi2
XSKi3
JMP p+2
JMP 4A
LDAi1
LDAi1
JMP 4B
#4C JOP9T
0012
JOPp+1
JMP 10
#4L 0000
#4M 0000
[END FOR NOW
[OUTPUT-5
[NEW VERSION OF A TELETYPE OUTPUT PACKAGE WHICH OCCUPIES ONLY ONE QUARTER OF MEMORY.
[FORMAT IS AS FOLLOWS -
[JOP9T
[EDITING PHRASE
[EDITING PHRASE
[  ...
[  ...
[EDITING PHRASE
[JMP p+1
[  EACH EDITING PHRASE CONSISTS OF THREE PARTS -
[BITS 11 THRU 9 ARE ALL ZERO,
[BITS 8 THRU 6 FORM A 3 BIT CODE FOR THE OPERATION-SEE BELOW,
[BITS 5 THRU 0 MAY REPRESENT THE NUMBER OF REPETITIONS OF THE OPERATION -FOR CODES 0 AND 1- OR AN INDEX REGISTER, 1 THRU 16, POINTING TO THE ADDRESS OF THE OPERAND. IF THIS INDEX REGISTER IS 0 OR 17 IT IS ASSUMED THE OPERAND IS THE CONTENTS OF THE ACCUMULATOR WHEN THE OUTPUT PACKAGE WAS FIRST ENTERED.
[CODES ARE AS FOLLOWS -
[0  EJECT N LINES
[1  N SPACES
[2  OCTAL 4 DIGIT
[3  SP DECIMAL 4 DIGIT AND SIGN
[4  DP DECIMAL 7 DIGIT AND SIGN
[5  SP FRACTION 4 DIGIT AND DECIMAL POINT
[6  PERCENT 2 DIGIT
[7  SET FRACTION SIGN
[AJH JULY 1967
[            ORIGIN MAY BE INSERTED HERE IF DESIRED
#9T STC 9G-1  [ENTRY
ADD 0
BCLi
4000
STC 9G+11
JMP 9G+11
00  [ACCUMULATOR CONTENTS
#9G LDAi17  [NEXT
LDA
17
STA
10
LDAi
1
ADD p+2
STC p+1
ADD 000
APO
JMP 9B
STAi
#9D 0  [CURRENT EDITING PHRASE
SCR 6
ADAi
JMP+9A+1
STC 9A
ADD 9D
SCR 7
AZE
JMP p+12
ADD 9D  [CODE IS
BCLi    [0 OR 1
7700
AZEi
ADD 9G+6
COM
STC 17
STC 9G+4
JMP 9A
LDA    [CODE IS
9D     [2  - 7
BCLi
7760
SHDi   [IF REG.
1700   [IS 17,
CLR    [SET TO 
STA    [ZERO
9G+4
STC 9A-2
LDAi
9G-1  [ADDRESS OF ACCUM. CONTENTS
STC 0
LDA
10   [0 THRU 16
STC 17
#9A JMP 000
JMP 9C  [EJECT
JMP 9H  [SPACES
JMP 9J  [OCTAL
JMP 9X  [SP DEC
JMP 9W  [DP DEC
JMP 9I  [FRACT
JMP 9E  [PERCENT
JMP 9E+4 [SET FRACTION SIGN
#9B STC p+1
JMP 000  [FINISHED
#9C LDAi  [EJECT
215
OPRi2
LDAi
212
JMP p+3
#9H LDAi  [SPACES
240
OPRi2
XSKi17
JMP p-2
JMP 9G
#9J LDA 17  [OCTAL
ROL 3
STAi
0
BCLi
7770
JMP 9P
LDA
p-5
SROi
3567
JMP p-12
JMP 9G
12  [CONSTANT
#9I LDAi  [FRACTION
256
OPRi2
LDA
9S
ROLi1
LDA 17
RORi1
APO
COM
MUL
4000+9I-1
STAi
0
ZTA
STC p+4
ADD p-3
JMP 9P
LDAi
0
SROi
3567
JMP p-14
JMP 9G
#9E ADD 9E-3 [PERCEN
ROR 2
STC 9E-3
JMP 9I+5
ADD 9D [SET SIGN
ROL 1
STC 9S
JMP 9G+1
[PRINT SUBROUTINE
[DIGITS  0 THRU 11
[SPACE  13
[MINUS  30
[POINT  31
237
33
-12
#9P ADD 9P-1
APO
ADD 9P-2
ADD 9P-3
OPRi2
JMP 0
[INTEGER OCTAL TO DECIMAL
#9X LDAi  [SP ENTRY
0007
JMP 9S+2
STAi
#9R 0   [RIGHT HALF
JMP 9S-2
STC 9L
JMP 9L+4
[SIGN FLAG SET
SCR 13
STAi
#9S 0   [SIGN FLAG
JMP 0
[SUPPRESSED LEAD ZEROES FLAG SET, COUNTERS SET
STA
9O
STC 9K
STC 9F
LDA 17
JMP 0
#9W LDAi   [DP ENTRY
0077
JMP 9S+2
STAi
#9L 0   [LEFT HALF
JMP 9S-2
LDAi17
STC 9R
ADD 9L
APOi
JMP 9Y-3
COM
STC 9L
ADD 9R
COM
STC 9R
LDAi
9V+1
STC 9Z
#9Y ADD 9G+6
STC 9N
STC 9M
#9Q CLR
ADD 9R
ROLi1
STC 9R
ADD 9L
ROLi1
STC 9L
ADD 9M
ROLi1
STAi
#9M 0   [EXTENSION L
ADD 9P-1
AZEi
COM
APO
JMP p+5
STC 9M
ADD 9G+6
ADD 9R
STC 9R
SROi
#9U 3777
JMP 9Q
SROi
#9N 0001
JMP 9Q
LDA
9M
STH
#9Z 9V+1
LDAi
4000
ADD 9Z
STC 9Z
SROi
#9K 0007
JMP 9Y
LDAi  [OUTPUT
3777
ADD 9Z
STA
9Z
STC p+2
LDH
9V+1
STA
9M
AZEi
JMP 9O+10
SROi
#9F 0000
JMP 9F+15
LDA
9S
APO
ADD 9V
ADAi
13
JMP 9P
CLR
COM
STC 9F
ADD 9M
JMP 9P
SROi
#9O 0007
JMP 9K+2
SAEi
240
JMP 9G
CLR
JMP 9P
JMP 9G
ADD 9F
APO
JMP 9F+13
ADD 9F+7
JMP 9F+15
#9V 15
0000
0000
0000
0000
[END OF OUTPUT-5
[EXAMOUT
[20 SEPT 76