[SOLID-01
[AJH JULY 1970
$20
JMP 3W
HLT
[SET UP ADDRESSES
LDAi
#2D 0001   [FIRST POINT TO BE PLOTTED
ADAi
3377
STAi
#2E 0000   [ADDRESS OF FIRST POINT, LESS ONE, IN Q 7
ADAi
-400
STAi
#2F 0000   [ADDRESS OF FIRST MASK POINT, LESS ONE, IN Q 6
[NUMBER OF POINTS
LDAi
#2G 0376   [LAST POINT TO BE PLOTTED
ADAi
1
COM
ADD 2D
STAi
#2H 0000   [COMPLEMENT OF NUMBER OF POINTS TO BE PLOTTED
SETi5
-1    [TIMEMARKER
[CLEAR Q6 AND Q7
SETi2
2777
CLR
STAi2
XSK 2
JMP p-2
#2S LSW
ADAi
-1
STC 2B
RSW
STC 2C
JMP 2L+4
[REPETITION BEGINS HERE
[SUBTRACT Y OFFSET FROM MASK|DATA IN Q 7
[TRANSFER MASK TO Q 6 WITH X OFFSET TO LEFT
[FILL REMAINDER OF MASK WITH ZEROES
[MOVE PEN RIGHT AND UP TO NEW STARTING POSITION AND CLOSEOUT
#2N JMP 3R
JMP 4P
#2X 0020   [X OFFSET
#2Y 0004   [Y OFFSET
JMP 4Q
LDAi
3377
ADD 2X
STC 1
SETi2
2777
ADD 2Y
COM
STAi
#2A 0000   [MINUS  Y OFFSET
LDAi1
ADD 2A
STAi2
XSK 1
JMP p-4
#2L CLR
STAi2
XSK 2
JMP p-2
[READ IN DATA, Q 7
LDA
2B
BCLi
7000
SAEi
#2C 0777   [FINAL BLOCK
JMP p+2
JMP 2P
LDAi
1
ADD 2B
AZEi
CLR
BSEi
7000
STC 2B
RDCu
#2B 7000
[SCALE DATA
SETi1
3377
LDAi1
SCR 2
STA 1
XSK 1
JMP p-4
[FILL LEFT END WITH ZEROES UP TO PLOTABLE DATA
SET 3
2H      [NUMBER OF POINTS TO BE PLOTTED
SETi1
3377
LDA
2E
SAE
1
JMP p+2
JMP p+4
CLR
STAi1
JMP p-10
[SKIP THROUGH PLOTABLE DATA
LDAi1
XSKi3
JMP p-2
[FILL RIGHT END WITH ZEROES
CLR
XSK 1
JMP p+2
JMP p+3
STAi1
JMP p-4
[READY TO PLOT
SET 1
2E      [DATA ADDRESS
SET 2
2F      [MASK ADDRESS
SET 3
2H      [NUMBER OF POINTS
SETi4
0     [X AXIS
#2K LDAi1
COM
ADAi2
AZE
APO
JMP 2J  [GO PLOT
JMP 3R
LDA 2
STA 1
#2R XSKi4
NOP
XSKi3
JMP 2K
LDA
4
STC p+3
STC p+3
JMP 4P
0000
0000
JMP 3L
XSKi5
JMP 2N
SETi5
-74
LDA
4
STC p+2
JMP 4P
0000
-40
[DONE WITH THIS BLOCK
JMP 2N  [NEXT BLOCK
#2P HLT
JMP 2S
[PLOTTING NUCLEUS
#2J LDA 1
STC 2Q+1
ADD 4
#2M NOP
STC 2Q
JMP 4P
#2Q 0000   [X
0000   [Y
JMP 3L  [LOWER PEN
JMP 2R
[SIMPLOT
#4P LDA
0
BCLi
6000
STC 14
LDA 14
STC 4X
LDAi14
STC 4Y
LDAi14
LDA
14
ADD 4P+3
STC p+3
JMP 4V
JMP 4Z
JMP 000
[MODIFY AXES
[XP = X
[YP = 0.5X - 2Y
#4V SET 17
0
LDA
4X
SCR 1
COM
STC p+4
ADD 4Y
ROL 1
ADAi
0000
STC 4Y
JMP 17
[CLOSEOUT PLOT
#4Q SET 17
0
CLR
STC 3X
STC 3Y
JMP 3R+2
[SET PLOTTER WIDE
#3W LDA
0
STC 3U+20
LDAi
OPR 10
STC 4J+6
LDAi
OPR 7
STC 4J+12
LDAi
OPR 12
STA
3U+12
STC 4K+6
LDAi
OPR 11
STA
3U+3
STC 4K+12
JMP 3U
[SET PLOTTER TALL
#3T LDA
0
STC 3U+20
ADD 3W+17
STA
3U+12
STC 4J+6
ADD 3W+12
STA
3U+3
STC 4J+12
ADD 3W+4
STC 4K+6
ADD 3W+7
STC 4K+12
[RESET PEN POSITION BEFORE STARTING.
#3U JMP 4Q
LDAi
-3000
OPR 11
JMP 4L
ADD 4E
APO
JMP p-4
LDAi
-62
OPR 12
JMP 4L
ADD 4E
APO
JMP p-4
JMP 4Q
JMP 0000
[INTERPOL
JMP 000
#4Z LDA
0
STC 4Z-1
STC 15
ADD 3X
COM
ADD 4X
STAi
#4A 0
APO
COM
STC 4B
ADD 3Y
COM
ADD 4Y
STAi
#4C 0
APO
COM
STC 4D
ADD 4D
COM
ADD 4B
APO
CLR
ADD 4D
AZEi
JMP 4Z-1
ROL 1
XSKi15
APOi
JMP p-3
LDAi
240
ADD 15
STC 4H
ADD 15
COM
ADAi
254
STC 4G
ADD 4E
#4G ROL 10
ADD 4E
COM
STC 15
ADD 4B
JMP 4H
STC 4B
ADD 4D
JMP 4H
STC 4D
STC 4M+3
STC 4M+11
#4M CLR
ADD 4B
LAMi
0
LZE
JMP 4J
CLR
ADD 4D
LAMi
0
LZE
JMP 4K
LDAi
#4I 0
APOi
JMP 4L
COM
STC 4I
ADD 4E
ADM
15
AZE
JMP 4M
JMP 4Z-1
#4X 0
#4Y 0
#4B 0
#4D 0
#4H ROL 4
JMP 0
#4J SET 17
0
LDA
4A
APO
JMP p+5
OPR 10
LDAi
#4E 1
JMP p+4
OPR 7
LDAi
#4F -1
ADMi
#3X 0
CLR
STC 4I
JMP 17
#4K SET 17
0
LDA
4C
APO
JMP p+5
OPR 12
LDA
4E
JMP p+4
OPR 11
LDA
4F
ADMi
#3Y 0
CLR
STC 4I
JMP 17
#4L SET 17
0
SETi16
1640
XSKi16
JMP p-1
JMP 17
[LOWER PEN
#3L SET 17
0
LDAi
#4R 7777
APO
JMP 17
OPR 14
CLR
COM
STC 4R
SETi16
0
XSKi16
JMP p-1
SROi
3333
JMP 3L+12
JMP 17
[RAISE PEN
#3R SET 17
0
LDA
4R
APOi
JMP 17
OPR 13
CLR
STC 4R
JMP 3L+12
[END OF INTERPOL
[END OF SIMPLOT.
[END SOLID-01
[20 JULY 1970