[MUSIC G C JOHNS MAY 5,1967
[INPUT ON SAME UNIT AS CALLED FROM
$1
ZZZ i
JMP 1A
LDA i
RDC i u
STC 2B
LDA i
WRC i 
STC 5U
LDA i
RCG u
STC 3C
LDA i
RDC u
STC 2D
LDA i
MTB u
STC 2E
LDA i
MTB
STC 2H
LDA i
MTB u
STC 2E
LDA i
WRC 
STC 2G
#1A CLR
COM
STC 1G
JMP 1C
JMP 2A
SET i 9I
3777
LDA i
2065
SAE i 9I
JMP 3B
COM
SAE i 9I
JMP 3B
SET i 9I
6001
#4B SET 9S
9I
LDH i 9S
SHD i
"R'
JMP 1X
CLR
SRO i
#1G 0
STC 4C
STC 4D
#1B LDH i 9I
SHD i
1200
JMP 3E
SHD i 
7700
JMP 3D
SHD i
"$'
JMP 3F
SHD i
"<'
JMP 1H
SHD i 
"['
JMP 4X
SHD i 
"P'
JMP 4T
SHD i 
"S'
JMP 4U
SHD i
"T'
JMP 4V
SHD i 
"C'
JMP 4E
SHD i
"D'
JMP 4F
SHD i 
"E'
JMP 4G
SHD i 
"F'
JMP 4H
SHD i 
"G'
JMP 4I
SHD i
"A'
JMP 4J
SHD i 
"B'
JMP 4K
SHD i 
"N'
JMP 4L
SHD i
"#'
JMP 4M
SHD i
"|'
JMP 4N
ADA i
#1Q -6
APO i
JMP 1B
JMP 1R
JMP 1B
#1R ADA i
246
STC p+2
ADD 3A
ROL
ADM i
#4C [DURATION OF NOTE
JMP 0
[C
#4E JMP 3G
ADD 3A
JMP 4P
[D
#4F JMP 3G
LDA i
#1U 2
JMP 4P
[E
#4G JMP 3G
ADD 5C+1
JMP 4P
[F
#4H JMP 3G
LDA i
#1T 4
JMP 4P
[G
#4I JMP 3G
ADD 5D+1
JMP 4P
[A
#4J JMP 3G
ADD 4O
JMP 4P
[B
#4K JMP 3G
LDA i
7
#4P ADD 5J
STC 9U
LDA 9U
#4Q ADM i
#4D [PITCH
JMP 1B
[NATURAL
#4L LDA i
#5M [NATURAL PITCH CORRECTION
JMP 4Q
[SHARP
#4M LDA i
1
JMP 4Q
[FLAT
#4N LDA i
-1
JMP 4Q
[REPEAT ONE NOTE
#1X LDH i 9I
SAE i
12
JMP 1X
[END OF LINE
#3E LDA
3J
MUL i
14
ADD 4D
JMP 4R
JMP 2F
LDA
4C
JMP 4R
AZE i
ADD 3A
JMP 2F
#5R LDA
9I
BCL i
4000
ADA i
-2377
APO
JMP 4B [NEW LINE
LDA i
-400
ADM
9I
JMP 2A
JMP 4B
[CLEAN UP AND GET OUT
#3D JMP 4W
JMP 4W
CLR
JMP 2I
[RETURN TO LAP
#3B SET i 15
#3C RCG
SET i 16
7300
JMP 15
[OUT OF RANGE?]
#4R STA i
#4S 
BCL i
77
AZE
STC 4S
ADD 4S
JMP 0
[REST
#4T STC 3J
JMP 1B
[STOP
#4U JMP 4W
[COMMENT
#4X LDH i 9I
SHD i 
7700
JMP 3D
SAE i
12
JMP 4X
JMP 5R
[TEMPO
#4V CLR
STC 1D
JMP 2F
#1E LDH i 9I
SHD i
1200
JMP 1F
ADA i
-7
APO i
JMP 1E
LDH 9I
ADD 1D
ROL 3
STC 1D
JMP 1E
#1F LDA i
#1D 
ROR 3
JMP 2F
JMP 5R
#4W SET 9S
0
CLR
JMP 2F
CLR
JMP 2F
JMP 9S
[KEY SIGNATURE
#3F LDA i
-1
STC 5M
#5I LDH i 9I
SHD i
"C'
JMP 5B
SHD i
"D'
JMP 5C
SHD i
"E'
JMP 5D
SHD i
"F'
JMP 5E
SHD i
"G'
JMP 5F
SHD i
"A'
JMP 5G
SHD i 
"B'
JMP 5H
CLR
#5A AZE
STC 5J
LDH 9I
SHD i
1200
JMP 5N
SHD i
"#'
JMP 5K
SHD i
"|'
JMP 5L
SHD i
7700
JMP 3B
JMP 5I
#5K LDA i
-1
STC 5M
ADD 3A
ADM i
#5J
JMP 5I
#5L LDA i
1
STC 5M
ADD 5K+1
JMP 5J-1
#5N LDA
5J
SHD i
1500
JMP 5Q
AZE i
JMP 6B
ADD 5K+1
#6C MUL i
7
ADA i
6A-1
STC 5J
JMP 5R
#6B LDA i
13
JMP 6C
#5Q CLR
JMP 6C
#5B CLR
STC 5M
ADD 3A
JMP 5A
#5C LDA i
#1V 3
JMP 5A
#5D LDA i
#1S 5
JMP 5A
#5E LDA i
1
STC 5M
LDA i
#4O 6
JMP 5A
#5F LDA i
10
JMP 5A
#5G LDA i
12
JMP 5A
#5H LDA i
14
JMP 5A
[OCTAVE NUMBER
#3G SET 9S
0
CLR
STC 3J
SET 9U
9I
#3H LDH i 9U
ADA i
-11
APO i
JMP 3I
LDH i 9I
ADD 3J
ROL 3
STC 3J
JMP 3H
#3I LDA i
#3J 
ROR 3
AZE
ADD 4Y
STC 3J
JMP 9S
#4Y -2
[OUTPUT TAPE ROUTINE
#2F STH i 9O
LDA
9O
AZE
JMP 0
#2I ADD 3A
ADM
p+2
#5U WRC i u
6427
ADD p-1
ADD 5T
STC p+2
#2G WRC u
0
ADD 3A
ADM
5U+1
#2H MTB u
0
#1C SET i 9O
6777
JMP 0
[INPUT TAPE ROUTINE
#2A LDA i
#3A 1
ADM
2C
#2B RDC i
#2C 4347
ADD p-1
ADA i
#5T 1001
STC p+2
#2D RDC
0
#2E MTB
0
CLR
JMP 0
#1H SHD i
"W'
JMP 1I
SHD i 
"H'
JMP 1J
SHD i
"Q'
JMP 1K
SHD i
"E'
JMP 1L
SHD i
"S'
JMP 1M
SHD i
"T'
JMP 1N
SHD i
"N'
JMP 1O
SHD i
1200
JMP 5R
LDH i9I
JMP 1H
#1I JMP 1P
ADD 1S
JMP 1W
#1J JMP 1P
ADD 1T
JMP 1W
#1K JMP 1P
ADD 1V
JMP 1W
#1L JMP 1P
ADD 1U
JMP 1W
#1M JMP 1P
ADD 3A
JMP 1W
#1N JMP 1P
#1W JMP 1R
JMP 4X
#1O CLR
COM
STC 1G
JMP 4X
#1P CLR
STC 1G
STC 4C
ADD 1Q
JMP 0
[KEY SIGNATURE TABLES
[C
#6A 1
3
5
6
10
12
14
[C#
2
4
6
7
11
13
15
[D
2
3
5
7
10
12
14
[D#
1
3
4
6
10
11
13
[E
2
4
5
7
11
12
14
[F
1
3
5
6
10
12
13
[F#
2
4
6
7
11
13
14
[G
1
3
5
7
10
12
14
[G#
1
2
4
6
10
11
13
[A
2
3
5
7
11
12
14
[A#
1
3
4
6
10
12
13
[B
2
4
5
7
11
13
14
9O=1
9I=2
9R=3
9S=4
9U=5