*20
/
/	SNSDIS
/
/	EDWARD RAPOPORT
/	1/20/72
/
/DISPLAYS STATE OF EXTERNAL SENSE LINES
/ON SCOPE. H=+3V,L=GROUNDED.
/
/	STARTS AT LINC MODE 20.
/
/	(SEE LINE 160 FOR ANOTHER TEST)
BEGIN,	LDA I
	20		/INIT. X COORD
	STC X
	STC CHAN
	SET I 3
	-14		/CHANNEL COUNTER
NEWCH,	LDA
	CHAN
	SCR 3		/HI ORD DIGIT
	ROL 1		/*2
	ADD NUMAR
	STC 4		/ADDR OF PATTERN
	ADD X
	STC 1		/W SET
	ADD YNUM	/Y SET
	DSC 4
	DSC I 4
	LDA
	CHAN
	BCL I
	7770		/LO ORD DIGIT
	ROL 1
	ADD NUMAR
	STC 4
	DSC 4
	DSC I 4
	LDA
	CHAN
	ADA I
	SXL
	STC SENSE
SENSE,	0		/SXL
	ADD LOP		/LO
	ADD HIP		/HI
	STC 4
	ADD M20
	ADD 1
	STC 1		/ALIGN X
	LDA
	YCHAN
	DSC 4
	DSC I 4
	XSK I 3		/DONE?
	JMP .+2		/NO
	JMP RETCHK	/YES
	LDA I
	50
	ADM		/NEW X POS.
	X
	LDA I
	1
	ADM
	CHAN		/NEW CHANNEL
	JMP NEWCH
RETCHK,	SNS 0		/CALL DIAL?
	JMP BEGIN
	RCG		/LOAD DIAL
	6301
	LDF 2
	LIF 0
	JMP DIALR
HIP,	H
LOP,	L-H
X,	0
M20,	-20
CHAN,	0
NUMAR,	NUM
YNUM,	0
YCHAN,	40
H,	1077
	7710
L,	0177
	0301
NUM,	4136
	3641
	2101
	0177
	4523
	2151
	4122
	2651
	2414
	0477
	5172
	0651
	1506
	4225
	4443
	6050
	SEGMNT 0
	*20
DIALR,	RDC
	4300
	LDF 3
	LIF 2
	JMP 20
/END SNSDIS
/
/
/TEST OF SENSE LINES
/STARTS AT 400 (LINC MODE)
/COUNTS NUMBER OF TIMES EX-
/TERNAL SENSE LINE CHANGES STATE.
/LINE NUMBER IS IN RIGHT SWITCHES.
/NUMBER OF CHANGES IS DISPLAYED IN MQ
/WHEN SENSE SWITCH 1 IS PRESSED.
/RESTART AT 400.
	SEGMNT 2
	*4400
	RSW		/LINE NO. IN RSW
	BSE I
	SXL I 0		/NOT EXECUTED
	STC SENS2	/INITIAL INST.
	STC 4
	STC 5
SENS2,	0
	JMP SENS1
	LDA
	SENS2
	BCO I		/REVERSE SENSE
	20
	STC SENS2
	XSK I 4
	JMP SENS1
	XSK I 5
SENS1,	SNS 1
	JMP SENS2
	LDA
	4
	SCR 12		/COUNTER TO MQ
	LDA 5
	SCR 2		/MQ LOW ORDER
	HLT		/AC HIGH ORDER