*20
/
/DBLFLT :
/BY MICHAEL MCDONALD
/SEE DEC-L8-SFAA-D
/USES IR. 1-5
	*1000	/MAY BE MOVED
/ADD
A5,	CLR
	ADD 0
	JMP A7
	LDA 1
	COM
	ADA 2
	FLO
	JMP .+4
	SCR 14
	BCO I
	7737
	SCR I 1
	ROL I 1
	LZE I
	COM
	STC M7+1
	JMP I6
	LZE
	JMP H6
	LDA 1
	STA 3
	LDA I 2
	STA I 3
	LDA I 2
	STA I 3
	JMP M7
	JMP H7
	JMP I7-2
	JMP G6
	LDA I 3
	JMP C6+2
	SET 1
	G6+1
	SET I 2
	0
	JMP D6
	JMP Q7
/SUBTRACT
B5,	CLR
	ADD 0
	JMP A7
	JMP I6
	JMP D6-2
	JMP H6
	JMP A5+3
/MULTIPLY
C5,	CLR
	ADD 0
	JMP A7
	LDA 1
	ADA 2
	JMP E6+1
	STC E5
	JMP C6
	JMP I6
	JMP D6
	JMP H6
	JMP D6
	LDA I 2
	LDA I 2
	ROR 1
	STA 2
	JMP H6
	LDA I 1
	MUL I 2
	STA 3
	QAC
	STA I 3
	LDA I 1
	ROR 1
	MUL I 2
	ROL 1
	STA I 3
	JMP H6+2
	LDA I 1
	MUL 2
	JMP F5
D5,	JMP H6
	LDA I 1
	LDA I 1
	ROR 1
	MUL I 2
	JMP F5
	JMP G6
	LDA I 3
	LDA I 3
	ROL I 1
	ROL 1
	BCL I
	7776
	STC P7
	JMP G6
	LDA I 3
	ROL I 1
	STA I 3
	JMP G6
	LDA 3
	STA I 3
	JMP G6
	LDA I
E5,	0
	STA 3
	JMP Q7
F5,	STC X7
	JMP B6
	STC X7+1
	SET I 1
	X7-1
	JMP G6
	JMP H7
	SET I 2
	-0
	JMP I7
	SRO I
	2525
	JMP D5
	JMP D5+6
/DIVIDE
G5,	CLR
	ADD 0
	JMP A7
	ADD K7
	STC J5+1
	LDA I 2
	AZE I
	HLT
	JMP H6
	LDA 2
	COM
	ADA 1
	JMP E6+1
	JMP C6
	JMP H6
	JMP D6
	JMP I6
	JMP D6
	JMP H6
	LDA I 1
	STA I 3
	LDA I 1
	STA I 3
	LDA I 2
	COM
	STC X7+1
	LDA I 2
	COM
	STC X7+2
	STC X7
	STC Y7
	SET I 2
	X7-3
H5,	JMP H6+2
	JMP .+2
I5,	JMP I6+2
	JMP H7
J5,	SRO I
	1
	JMP M5
	SET I 5
	-0
	JMP G6
	LDA I 3
	AZE
	JMP K5-3
	LDA I 3
	AZE I
	JMP K5+2
	CLR
	JMP G6
	LDA I 3
K5,	APO
	JMP L5
	LDA 2
	BSE
	J5+1
	STA 2
	XSK I 5
L5,	SET 1
	G6+1
	JMP G6
	JMP H7
	XSK 5
	JMP H5
	JMP I5
M5,	XSK I 2
	XSK I 2
	XSK I 2
	SRO I
	3333
	JMP J5+3
	JMP G6
	CLR
	ADD X7
	STA I 3
	CLR
	ADD Y7
	STA I 3
	JMP Q7
/MOVE 1 TO 2
A6,	LDA 1
	STA 2
	LDA I 1
	STA I 2
	LDA I 1
	STA I 2
	CLR
	JMP 0
/MQ TO ACCUMULATOR
B6,	QAC
	ROL 1
	QLZ
	ADD K7
	JMP 0
/COM SETUP
C6,	LDA I 1
	BCO I 2
	ROL I 1
	LDA I
	NOP
	LZE
	ADD .+3
	STC S7
	JMP 0
	JMP D6-20
	SET I 2
	-0
/COM/ABS 1
D6,	LDA I 1
	SCR I 1
	ROL I 1
	XSK 2
	LZE
	COM
	STA 1
	LDA I 1
	XSK 2
	LZE
	COM
	STA 1
	JMP 0
/OVF CHECK
E6,	ADA 3
	AZE I
	CLR
	STA 3
	FLO
	JMP 0
	APO
	HLT
/RESULT=0
F6,	JMP G6
	LDA I
	-3777
	STA 3
	CLR
	STA I 3
	STA I 3
	JMP T7
/SET 3
G6,	SET I 3
	0
	JMP 0
/SET NORMAL
H6,	SET I 2
	Y7+4000
	SET I 1
	X7
	JMP 0
/SET REVERSE
I6,	SET I 2
	X7
	SET I 1
	Y7
	JMP 0
/SETUP
A7,	BCL I
	6000
	STC 4
	ADD 0
	STC E7
	LDA 4
	JMP G7
	JMP F7
	STC C7
	LDA I 4
	JMP G7
	JMP E7+1
	STC D7
	LDA I 4
	JMP G7
	NOP
	STC G6+1
B7,	JMP I6
	SET I 1
C7,	0
	JMP A6
	XSK I 2
	SET I 1
D7,	0
	JMP A6
	XSK I 4
	ADD 4
	ADD A7+1
	STC T7
	STC P7
	JMP G6
	JMP H6
E7,	0	/RTN 
	STC D7
	ADD F7+2
	JMP B7-1
F7,	STC D7
	LDA I
	Z7
	STC C7
	JMP E7+2
/IR+SIGN TEST
G7,	APO I
	XSK I 0
	APO
	COM
	ADA I
	-17
	SCR I 1
	ROL I 1
	ADD G7+3
	LZE I
	JMP 0
	STC 1
	LDA 1
	ADD S7-1
	STA 1
	ADA I
	-3
	JMP 0
/ADD 1 TO 3
H7,	SET 4
	0
	CLR
	JMP G6
	LDA I 1
	STC J7
	LDA I 3
	STC J7+2
	LDA 1
	LAM 3
	LDA I 1
	LAM I 3
	JMP G6
	STC 0
	LAM I 3
	STC 0
	LAM I 3
	JMP 4
	SET I 2
	0
/CHECK FOR ADD OVERFLOW
I7,	SET 1
	0
	JMP G6
	LDA I
J7,	0
	BCO I
	0
	APO
	JMP 1
	LDA I 3
	BCO
	J7
	APO I
	JMP 1
	JMP G6
	LDA I
K7,	1
	JMP E6
	LDA I
L7,	-1
	XSK 2
	JMP M7+2
	ADD P7
	XSK 2
	COM
	STC P7
	JMP G6
	LDA I 3
	BCO I
	4000
	STA 3
	JMP 1
/SCR N 3
M7,	LDA I
	0
	SET 2
	0
	AZE I
	JMP 2
	STC 5
	SET I 4
	-30
O7,	CLR
	JMP G6
	LDA I 3
	SCR I 1
	STA 3
	LDA I 3
	ROR I 1
	STA 3
	XSK I 4
	JMP .+2
	JMP .+3
	XSK I 5
	JMP O7
	JMP G6
	LDA I 3
	ROL I 1
	LZE
	COM
	STC P7
	JMP 2
P7,	0
/NORMALIZE, ROUND, EXIT
Q7,	CLR
	STC 1
	ADD P7
	ROR I 1
	JMP G6
	LDA I 3
	SAE I 3
	JMP .+5
	AZE
	JMP .+3
	LZE I
	JMP F6
	JMP G6
	LDA I 3
	APO
	JMP U7
	ROL 1
	APO I
	JMP T7+1
R7,	JMP G6
	LDA I 3
	LDA I 3
	ROR I 1
	STC 0
	LAM 3
	JMP G6
	STC 0
	LAM I 3
	APO
	JMP V7
	JMP G6
	CLR
	ADD 1
	COM
	JMP E6
	SET 1
	3
S7,	NOP
	CLR
T7,	0	/DBLFLT EXIT 
	LDA I 3
	ROL I 1
	STA 3
	JMP G6
	LDA I 3
	ROL I 1
	STA 3
	XSK I 1
	JMP R7-3
U7,	JMP V7
	JMP R7
V7,	CLR
	ADD 0
	STC W7
	ADD L7
	JMP M7+2
	ADD L7
	ADD 1
	STC 1
	LDA 3
	BCL I
	4000
	STA 3
W7,	0	/RTN 
/ARG 1
X7,	0
	0
	0
/ARG 2
Y7,	0
	0
	0
/FAC
Z7,	0
	0
	0
/TRANSFER
N5,	CLR 
	ADD 0
	JMP A7
	SET 2
	D7
	JMP A6
	JMP T7-1
/FLOAT
O5,	CLR
	ADD 0
	JMP A7
	ADD D7
	STC G6+1
	JMP  G6
	LDA I
	27
	STA 3
	JMP B5-10
/FIX
P5,	CLR
	ADD 0
	JMP A7
	ADD D7
	STC G6+1
	JMP G6
	LDA I
	-27
	JMP E6
	APO I
	JMP T7
	JMP M7+2
	JMP T7-1
	/END DBLFLT
/
/