*20
/
/DBLFLT3S
/SAME AS DBLFLT3
/SEE DECUS 12-7 DOCUMENT
/
/MEMORY SEGMENTS
	SEGA=3
	SEGB=1
/
/DBLFLTA STARTS HERE:
/
	SEGMNT SEGA
	*20
/
/DBLFLTA CONTROL PGM
ENTERA,	STC V3
	IOB
	6234
	ROL 2
	SCR 5
	ADA I
	LIF
	STC V4+4
	IOB
	6214
	SCR 1
	ADA I
	LDF
	STA
	V4+3
	STC V3+1
	ADD V4+4
	ADA I
	LDF-LIF
	STC .+1
V1,	0
	STC 12
	SET 17
	2\0
	ADD 17
	STC V1
	LDA
	2\17
	ADA I
	LISTA
	STC .+2
	LDA
V6,	0
	STC V3+3
	STA
	2\17
	SET I 4
	-3
	SET I 5
	V3+3
	ADD V6
	ADA I
	-LISTA-7
	APO I
	JMP V3-6
	LDA 17
	STA I 5
	APO
	JMP V3-3
	LDA I 17
	XSK I 4
	JMP .-5
	JMP V3-1
	LDA I
	XSK I 12
	STA I 5
	XSK I 4
	JMP .-4
	LDA I
V3,	0
	LDF
	NOP
	JMP
	0
	0
	0
	XSK I 12
	STC V3
	ADD DC6+4
	STC V3+2
	ADD 12
	COM
	ADD DC10
V4,	ADD V1
	STC .+4
	ADD V3
	LDF
	LIF
	JMP
/
/COMPARE
COMPRA,	CLR
	ADD 0
	JMP SETUP
	SET 3
	DT7
	LDA I 2
	BCO I 1
	APO I
	JMP .+3
	LDA 2
	JMP COMPR2
	LDA 1
	APO I
	JMP .+4
	LDA I
	COM
	JMP .+3
	LDA I 
	NOP
	SET I 2
	ARG2-1
	SET I 1
	ARG1-1
	JMP COMPR1
	ADD .-6
	JMP COMPR1
	ADD DD5+3
	JMP COMPR1
	JMP 3
COMPR1,	STC COMPR2-1
	LDA I 1
	COM
	ADA I 2
	AZE I
	JMP 0
	FLO I
	COM
	0
COMPR2,	APO I
	XSK I 3
	XSK I 3
	JMP 3
/
/TTY INPUT
TTYINA,	SET 15
	0
	STC TM3
	ADD TTYOUA+5
	STC FIXA+7
	SET I 14
	-0
	ADD TM3
TB3,	SET I 13
	-0
	STC TD3
	STC 16
	JMP TRANSA
	DC0
	-FAC
	JMP TRANSA
	DC10
	-TEM1
	ADD TD3
TC3,	STA I
TD3,	0
	SAE I
	377
	SKP
	JMP TS3
	SAE I
	215
	SKP
	JMP TG3
	JMP TTYP8
	ADD TD3
	SHD I
	5500
	SET I 16
	JMP .+1
	SHD I
	5600
	XSK I 13
	SAE I
	305
	JMP TF3
	XSK I 14
	JMP TRANSA
	-TEM3
	ADD 16
	STC TM3
	JMP TKBDI8
	JMP TB3
TF3,	ADA I
	-271
	APO I
	JMP TE3+4
	ADA I
	12
	APO
	JMP TE3+4
	LDA
	TD3
	BCL I
	7760
	STC TEM2+2
	STC TEM2+1
	JMP FLOATA
	-TEM2
	XSK 13
	JMP TE3+6
TE3,	JMP MULTA
	-DC10
	JMP ADDTA
	-TEM2
	JMP TKBDI8
	JMP TC3
	JMP DIVIDA
	TEM2
	TEM1
	TEM2
	JMP MULTA
	TEM1
	DC10
	TEM1
	JMP TE3+2
TG3,	XSK 14
	JMP TI3
TH3,	CLR
	ADD 16
	APO I
	JMP TI3-2
	SET I 1
	FAC
	JMP COM1A
	XSK I 15
	JMP TS3
TI3,	JMP FIXA
	-FAC
	AZE
	HLT
	ADD FAC+1
	STC TEM2
	ADD 16
	STC L4
TJ3,	JMP TENH4
	JMP MULTA
	TEM3
	-TEM1
	ADD TM3
	JMP TH3+2
TS3,	LDA I
	-27
	STC FIXA+7
	JMP 15
/
/TTY OUTPUT
TTYOUA,	SET 15
	0
	JMP TRANSA
	-TEM3
	LDA I
	-13
	STC FIXA+7
	SET I 14
	-7
	SET I 13
	-0
	ADD TEM3+1
	AZE I
	STC TEM3
	CLR
	ADD TEM3
	STA
	FAC+2
	SCR 13
	STC FAC+1
	JMP FLOATA
	-FAC
	JMP MULTA
	-DCLOG2
	JMP FIXA
	-FAC
	ADD FAC+1
	STA I
TM3,	0
	STC L4
	ADD TEM3+1
	ROL I 1
	LDA I
	253
	LZE
	ADD T0002
	JMP TTYP8
	ADD TM3
	APO
	COM
	STC TEM2
	JMP TENH4
	SET I 1
	TEM3
	JMP ABS1A
	SET I 16
	0
TN3,	JMP SUBTA
	TEM3
	TEM1
	TEM2
	ADD TEM2+1
	APO
	JMP TO3
	CLR
	ADD 16
	SHD I
	1100
	JMP TO3
	XSK I 16
	JMP TRANSA
	TEM2
	-TEM3
	JMP TN3
TO3,	CLR
	ADD 16
	AZE
	JMP .+6
	XSK 13
	JMP .+4
	ADD TEM3+1
	AZE
	JMP TQ3-4
	JMP TYPDIG
	XSK 13
	JMP TP3
	LDA I
	256
	JMP TTYP8
	XSK I 13
TP3,	XSK I 14
	JMP TQ3
	SRO I
	5252
	JMP TS3
	LDA I
	305
	JMP TTYP8
	SET I 14
	-3
	ADD TM3
	STA
	TEM3+2
	SCR 13
	STC TEM3+1
	JMP FLOATA
	-TEM3
	LDA I
T0002,	2
	JMP TM3-1
	CLR
	ADD TM3
	ADD DL7
	STC TM3
TQ3,	JMP DIVIDA
	TEM1
	DC10
	TEM1
	JMP TN3-2
/
/10 TO N
TEN2NA,	STA
	L4
	APO
	COM
	STC TEM2
TENH4,	SET 17
	0
	JMP TRANSA
	DC10
	-FAC
	JMP TRANSA
	DC1
	-TEM1
TENI4,	ADD TEM2
	AZE I
	JMP TENM4
	SCR I 1
	STC TEM2
	LZE I
	JMP TENJ4
	JMP MULTA
	TEM1
	FAC
	TEM1
TENJ4,	JMP MULTA
	-FAC
	JMP TENI4
TENM4,	ADD L4
	APO I
	JMP .+5
	JMP DIVIDA
	DC1
	TEM1
	TEM1
	JMP 17
/
/TELETYPE
TKBDI8,	SET 4
	0
	LDA I
	JMP .+7
	JMP .+5
TKBD8,	SET 4
	0
	LDA I
	JMP 4
	STC .+2
	KST
	JMP
	IOB
	6036
	JMP 4
	100
	200
TYPDIG,	ADA I
	60
TTYP6,	STA I
	0
	BCL I
	7737
	AZE I
	ADD .-11
	ADD .-11
	BCL I
	40
	ADD .-10
TTYP8,	SET 4
	0
	IOB
	6046
	IOB
	6041
	JMP .-2
	CLR
	JMP 4
/
/DBLFLT1
/ADD
ADDTA,	CLR
	ADD 0
	JMP SETUP
	LDA 1
	COM
	ADA 2
	FLO
	JMP .+4
	SCR 14
	BCO I
	7737
	SCR I 1
	ROL I 1
	LZE I
	COM
	STC DM7+1
	JMP DI6
	LZE
	JMP DH6
	LDA 1
	STA 3
	LDA I 2
	STA I 3
	LDA I 2
	STA I 3
	JMP DM7
	JMP DH7
	JMP DI7-2
	JMP DG6
	LDA I 3
	JMP DC6+2
	SET 1
	DG6+1
	JMP ABS1A
	JMP EXIT
/SUBTRACT
SUBTA,	CLR
	ADD 0
	JMP SETUP
	JMP DI6+2
	JMP COM1A
	JMP DH6
	JMP ADDTA+3
/MULTIPLY
MULTA,	CLR
	ADD 0
	JMP SETUP
	LDA 1
	ADA 2
	JMP DE6+1
	STC DE5
	JMP DC6
	JMP DI6+2
	JMP ABS1A
	JMP DH6
	JMP DD6
	LDA I 2
	LDA I 2
	ROR 1
	STA 2
	JMP DH6
	LDA I 1
	MUL I 2
	STA 3
	QAC
	STA I 3
	LDA I 1
	ROR 1
	MUL I 2
	ROL 1
	STA I 3
	JMP DH6+2
	LDA I 1
	MUL 2
	JMP DF5
DD5,	JMP DH6
	LDA I 1
	LDA I 1
	ROR 1
	MUL I 2
	JMP DF5
	JMP DG6
	LDA I 3
	LDA I 3
	ROL I 1
	ROL 1
	BCL I
	7776
	STC DP7
	JMP DG6
	LDA I 3
	ROL I 1
	STA I 3
	JMP DG6
	LDA 3
	STA I 3
	JMP DG6
	LDA I
DE5,	0
	STA 3
	JMP EXIT
DF5,	STC ARG1
	JMP QAC12
	STC ARG1+1
	SET I 1
	ARG1-1
	JMP DG6
	JMP DH7
	SET I 2
	-0
	JMP DI7
	SRO I
	2525
	JMP DD5
	JMP DD5+6
/DIVIDE
DIVIDA,	CLR
	ADD 0
	JMP SETUP
	ADD DK7
	STC DJ5+1
	LDA I 2
	AZE I
	HLT
	JMP DH6
	LDA 2
	COM
	ADA 1
	JMP DE6+1
	JMP DC6
	JMP DH6+2 
	JMP ABS1A
	JMP DI6+2
	JMP ABS1A
	JMP DH6
	LDA I 1
	STA I 3
	LDA I 1
	STA I 3
	LDA I 2
	COM
	STC ARG1+1
	LDA I 2
	COM
	STC ARG1+2
	STC ARG1
	STC ARG2
	SET I 2
	ARG1-3
DH5,	JMP DH6+2
	JMP .+2
DI5,	JMP DI6+2
	JMP DH7
DJ5,	SRO I
	1
	JMP DM5
	SET I 5
	-0
	JMP DG6
	LDA I 3
	AZE
	JMP DK5-3
	LDA I 3
	AZE I
	JMP DK5+2
	CLR
	JMP DG6
	LDA I 3
DK5,	APO
	JMP DL5
	LDA 2
	BSE
	DJ5+1
	STA 2
	XSK I 5
DL5,	SET 1
	DG6+1
	JMP DG6
	JMP DH7
	XSK 5
	JMP DH5
	JMP DI5
DM5,	XSK I 2
	XSK I 2
	XSK I 2
	SRO I
	3333
	JMP DJ5+3
	JMP DG6
	CLR
	ADD ARG1
	STA I 3
	CLR
	ADD ARG2
	STA I 3
	JMP EXIT
/MOVE12
MOVE12,	LDA 1
	STA 2
	LDA I 1
	STA I 2
	LDA I 1
	STA I 2
	LDA I 1
	LDA I 2
	CLR
	JMP 0
/MQ TO ACC.
QAC12,	QAC
	ROL 1
	QLZ
	ADD DK7
	JMP 0
/COM SETUP
DC6,	LDA I 1
	BCO I 2
	ROL I 1
	LDA I
	NOP
	LZE
	ADD .+3
	STC DS7
	JMP 0
	JMP COM1A-NOP
/COMPLEMENT
COM1A,	SET I 2
	-0
/ABSOLUTE VALUE
	SKP
ABS1A,	SET I 2
	NOP
DD6,	LDA I 1
	SCR I 1
	ROL I 1
	XSK 2
	LZE
	COM
	STA 1
	LDA I 1
	XSK 2
	LZE
	COM
	STA 1
	LDA I 1
	CLR
	JMP 0
/OVERFLOW CHECK
DE6,	ADA 3
	AZE I
	CLR
	STA 3
	FLO
	JMP 0
	APO
	HLT
/SET RESULT=0
DF6,	JMP DG6
	LDA I
	-3777
	STA 3
	CLR
	STA I 3
	STA I 3
	JMP DT7
/SET IR.3
DG6,	SET I 3
	0
	JMP 0
/SET IR.1?2 NORMAL
DH6,	SET I 2
	4\ARG2	
	SET I 1
	ARG1	
	JMP 0
/SET IR.1?2 REVERSE
DI6,	SET I 2
	ARG1	
	SET I 1
	ARG2	
	JMP 0
/STANDARD SETUP
SETUP,	BCL I
	6000
	STC 4
	ADD 0
	STC DE7
	LDA 4
	JMP DG7
	JMP DF7
	STC DC7
	LDA I 4
	JMP DG7
	JMP DE7+1
	STC DD7
	LDA I 4
	JMP DG7
	NOP
	STC DG6+1
DB7,	JMP DI6
	SET I 1
DC7,	0
	JMP MOVE12
	SET I 1
DD7,	0
	JMP MOVE12
	XSK I 4
	ADD 4
	ADD SETUP+1
	STC DT7
	STC DP7
	JMP DG6
	JMP DH6
DE7,	JMP
	STC DD7
	ADD DF7+2
	JMP DB7-1
DF7,	STC DD7
	LDA I
	FAC
	STC DC7
	JMP DE7+2
/TEST ARGS.
DG7,	APO I
	XSK I 0
	APO
	COM
	ADA I
	-17
	SCR I 1
	ROL I 1
	ADD DG7+3
	LZE I
	JMP 0
	STC 1
	LDA 1
	ADD DS7-1
	STA 1
	ADA I
	-3
	JMP 0
/ADD 1 TO 3
DH7,	SET 4
	0
	CLR
	JMP DG6
	LDA I 1
	STC DJ7
	LDA I 3
	STC DJ7+2
	LDA 1
	LAM 3
	LDA I 1
	LAM I 3
	JMP DG6
	STC 0
	LAM I 3
	STC 0
	LAM I 3
	JMP 4
	SET I 2
	0
/ADD OVERFLOW CHECK
DI7,	SET 1
	0
	JMP DG6
	LDA I
DJ7,	0
	BCO I
	0
	APO
	JMP 1
	LDA I 3
	BCO
	DJ7
	APO I
	JMP 1
	JMP DG6
	LDA I
DK7,	1
	JMP DE6
	LDA I
DL7,	-1
	XSK 2
	JMP DM7+2
	ADD DP7
	XSK 2
	COM
	STC DP7
	JMP DG6
	LDA I 3
	BCO I
	4000
	STA 3
	JMP 1
/SCR N 3
DM7,	LDA I
	0
	SET 2
	0
	AZE I
	JMP 2
	STC 5
	SET I 4
	-30
DO7,	CLR
	JMP DG6
	LDA I 3
	SCR I 1
	STA 3
	LDA I 3
	ROR I 1
	STA 3
	XSK I 4
	JMP .+2
	JMP .+3
	XSK I 5
	JMP DO7
	JMP DG6
	LDA I 3
	ROL I 1
	LZE
	COM
	STC DP7
	JMP 2
DP7,	0
/NORMALIZE,ROUND ? EXIT
EXIT,	CLR
	STC 1
	ADD DP7
	ROR I 1
	JMP DG6
	LDA I 3
	SAE I 3
	JMP .+5
	AZE
	JMP .+3
	LZE I
	JMP DF6
	JMP DG6
	LDA I 3
	APO
	JMP DU7
	ROL 1
	APO I
	JMP DT7+1
DR7,	JMP DG6
	LDA I 3
	LDA I 3
	ROR I 1
	STC 0
	LAM 3
	JMP DG6
	STC 0
	LAM I 3
	APO
	JMP DV7
	JMP DG6
	CLR
	ADD 1
	COM
	JMP DE6
	SET 1
	3
DS7,	NOP	
	CLR
DT7,	JMP	/EXIT 
	LDA I 3
	ROL I 1
	STA 3
	JMP DG6
	LDA I 3
	ROL I 1
	STA 3
	XSK I 1
	JMP DR7-3
DU7,	JMP DV7
	JMP DR7
DV7,	CLR
	ADD 0
	STC DW7
	ADD DL7
	JMP DM7+2
	ADD DL7
	ADD 1
	STC 1
	LDA 3
	BCL I
	4000
	STA 3
DW7,	0
/TRANSFER
TRANSA,	CLR 
	ADD 0
	JMP SETUP
	SET 2
	DD7
	JMP MOVE12
	JMP DT7-1
/FLOAT
FLOATA,	CLR
	ADD 0
	JMP SETUP
	ADD DD7
	STC DG6+1
	JMP DG6
	LDA I
	27
	STA 3
	JMP ADDTA+35
/FIX
FIXA,	CLR
	ADD 0
	JMP SETUP
	ADD DD7
	STC DG6+1
	JMP DG6
	LDA I
	-27
	JMP DE6
	APO I
	JMP DT7
	JMP DM7+2
	JMP DT7-1
/CONSTANTS
DC90,	0007
	2640
	0000
DC3,	0002
	3000
DCLN2,	0000
	2613
	4410
DCLOG2,	7776
	2321
	0116
DC10,	0004
	2400
	0000
DC0,	-3777
	0000
	0000
DC1,	0001
	2000
	0000
DC4,	0003
	2000
	0000
DCRT2,	0001
	2650
	1174
DC2,	0002
	2000
DCPID4,	0000
	3110
	3756
DCPI,	0002
	3110
	3756
DCPID2,	0001
	3110
	3756
/ENTRY JMP LIST
LISTA,	JMP ADDTA
	JMP SUBTA
	JMP MULTA
	JMP DIVIDA
	JMP TRANSA
	JMP FIXA
	JMP FLOATA
	JMP COMPRA
	JMP TTYP8	
	JMP ABS1A
	JMP COM1A
	JMP TTYINA
	JMP TTYOUA
	JMP TEN2NA
	JMP TTYP6
	JMP TKBDI8
	JMP TKBD8
/UNUSED
	0
/STORAGE LOCATIONS
DS1,	0
	0
	0
DS2,	0
	0
	0
DS3,	0
	0
	0
DS4,	0
	0
	0
DS5,	0
	0
	0
/FOR DISC DATA BREAK
	*1750
	0
	0
/STORAGE
DS6,	0
	0
	0
ARG1,	0
	0
	0
ARG2,	0
	0
	0
FAC,	0
	0
	0
TEM1,	0
	0
	0
TEM2,	0
	0
	0
TEM3,	0
	0
	0
L4,	0
/END DBLFLTA
/
/
/DBLFLTB STARTS HERE:
/
	SEGMNT SEGB
/
/DBLFLTB CONTROL PROGRAM
	*17
	0
ENTERB,	STC V4B
	IOB
	6234
	ROL 2
	SCR 5
	ADA I
	LIF
	STC V7B
	IOB
	6214
	SCR 1
	ADA I
	LDF
	STC V7B-1
	ADD V7B
	ADA I
	LDF-LIF
	STC .+1
V3B,	LDF
	LDA
	2\0
	STC 12
	LDA
	2\17
	ADA I
	LISTB
	STC .+2
	LDA
	0
	STC V4B+1
	STA
	2\17
	STC 17
	LDF SEGA
	LDA I
V4B,	0
	JMP
	JMP .+4
	SKP
	XSK I 12
	XSK I 12
	SET 0
	12
	LDF
V7B,	LIF
	JMP
/
/FLOT12
FLOT1B,	SET 1
	0
	STA
	2\FAC+2
	SCR 13
	STA
	2\FAC+1
	JMP FLOATB
	-FAC
	JMP 1
/
/FIX12
FIX12B,	SET 1
	0
	LDA I
	-13
	STA
	2\FIXA+7
	JMP FIXB
	-FAC
	STC .+6
	LDA I
	-27
	STA
	2\FIXA+7
	LDA I
	0
	AZE
	JMP 1
	LDA I 1
	LDA
	2\FAC+1
	SAE I
	3777
	SKP
	JMP 1
	SAE I
	4000
	SKP
	JMP 1
	SCR 17
	SCR 10
	LDA
	2\FAC+2
	ROL I 1
	STC 0
	QLZ
	COM
	LAM
	2\FAC+1
	JMP 1
/
/IRLOAD
IRLOAB,	LDA
	0
	STC .+23
	ADD V3B
	STC .+3
	SET I 17
	2000
	LDF
	LDA I 17
	LDF SEGA
	STA 17
	LDF SEGB
	STA 17
	LDA
	17
	SHD I
	1100
	XSK I 17
	SAE I
	2016
	JMP IRLOAB+7
	JMP
/
/SIGN TEST:
SIGNB,	LDA
	2\FAC+1
	AZE I
	JMP 0
	XSK I 0
	APO I
	JMP 0
	XSK I 0
	JMP 0
/
/MAGNITUDE TEST
MAGTSB,	SET 1
	0
	SET I 2
	2\FAC
	LDA 2
	APO
	JMP .+16
	AZE I
	JMP .+14
	ADD K7776
	AZE
	JMP 1
	LDA I 2
	APO
	COM
	SAE I
	2000
	JMP 1
	LDA I 2
	AZE I
	XSK I 1
	JMP 1
/
/NEGFAC
NEGFAB,	SET I 1
	2\FAC
	LDA I 1
	COM
	STA 1
	LDA I 1
	COM
	STA 1
	JMP 0
/
/POWER SERIES
POWSEB,	SET 3
	0
	STA
	2\16
	JMP TRANSB
	16
	-FAC
	JMP MULTB
	-TEM2
	JMP ADDTB
	-16
	XSK I 4
	JMP .-5
	JMP 3
/
/SINE ? COSINE
COSDEB,	SET 6
	0
	JMP DIVB
	-DC90
	JMP COSPIB+2
COSRAB,	SET 6
	0
	JMP DIVB
	-DCPID2
	JMP COSPIB+2
COSPIB,	SET 6
	0
	JMP ADDTB
	-DC1
	JMP SINPIB+2
SINDEB,	SET 6
	0
	JMP DIVB
	-DC90
	JMP SINPIB+2
SINRAB,	SET 6
	0
	JMP DIVB
	-DCPID2
	JMP SINPIB+2
SINPIB,	SET 6
	0
	SET I 7
	5252
	JMP MAGTSB
	JMP SIN1
	JMP TRANSB
	-TEM1
	JMP MULTB
	TEM1
	TEM1
	TEM2
	SET I 4
	-3
	LDA I
	2\SINC
	JMP POWSEB
	JMP MULTB
	-TEM1
	SRO
	7
	JMP NEGFAB
	JMP 6
SIN1,	SRO
	7
	NOP
	LDA
	2\FAC
	APO I
	JMP .+5
	SRO
	7
	NOP
	JMP NEGFAB
	JMP SUBTB
	-DC2
	JMP SINPIB+4
/SINE CONSTANTS:
SINC,	7770
	5610
	3161
	7774
	2426
	2466
	0000
	5325
	1165
	0001
	3110
	3750
/
/SQUARE ROOT
	XSK I 3
	JMP 3
SQROOB,	SET 3
	0
	JMP SIGNB
	JMP SQROOB-2
	JMP SQRT1-1
	JMP NEGFAB
	SKP
	XSK I 3
SQRT1,	JMP TRANSB
	-TEM2
	SET I 4
	-13
	LDA
	2\FAC
	SCR 1
SQRT2,	AZE I
	CLR
	STA
	2\FAC
	XSK I 4
	JMP .+2
	JMP 3
	JMP DIVB
	TEM2
	FAC
	TEM3
	JMP ADDTB
	-TEM3
	LDA
	2\FAC
	ADD K7776
	JMP SQRT2
/
/ARCSIN
ARCSIB,	SET 6
	0
	SET I 7
	-0
	JMP MAGTSB
	JMP 6
	XSK I 6
	JMP SIGNB
	JMP 6
	JMP .+4
	JMP NEGFAB
	SET I 7
	+0
	JMP TRANSB
	-TEM2
	SET I 4
	-5
	LDA I
	2\ASINC
	JMP POWSEB
	JMP TRANSB
	-TEM1
	JMP SUBTB
	DC1
	-TEM2
	JMP SQROOB
	HLT
	JMP MULTB
	-TEM1
	JMP SUBTB
	DCPID2
	-FAC
	XSK 7
	JMP NEGFAB
	JMP 6
/CONSTANTS
ASINC,	7770
	5616
	7023
	7772
	2364
	0742
	7773
	5076
	6227
	7774
	2637
	6100
	7775
	4442
	5555
	0001
	3110
	3750
/
/ARCTAN
ARCTAB,	SET 6
	0
	SET I 7
	-0
	JMP SIGNB
	JMP 6
	JMP ATAN1
	JMP NEGFAB
	SET I 7
	+0
ATAN1,	JMP ADDTB
	FAC
	DC1
	TEM1
	JMP SUBTB
	-DC1
	JMP DIVB
	FAC
	TEM1
	TEM1
	JMP MULTB
	TEM1
	TEM1
	TEM2
	SET I 4
	-4
	LDA I
	2\ATANC
	JMP POWSEB
	JMP MULTB
	-TEM1
	JMP ADDTB
	-DCPID4
	XSK 7
	JMP NEGFAB
	JMP 6
/CONSTANTS
ATANC,	-005
	2525
	3460
	7774
	5215
	1343
	7775
	2703
	5562
	7776
	5267
	0577
	0000
	3777
	5634
/
/LOGS
LOG2B,	SET 3
	0
	JMP SIGNB
	JMP 3
	JMP .+2
	JMP 3
	XSK I 3
	LDA
	2\FAC
	STA
	2\TEM1+2
	SCR 13
	STA
	2\TEM1+1
	JMP LOGS1
	STA
	2\TEM2+2
	SCR 13
	STA
	2\TEM2+1
	JMP LOGS1
	STA
	2\TEM3+2
	SCR 13
	STA
	2\TEM3+1
	JMP FLOATB
	-TEM1
	JMP FLOATB
	-TEM2
	JMP FLOATB
	-TEM3
	LDA I 
	-13
	ADM
	2\TEM2
	FLO
	JMP .+4
	JMP TRANSB
	DC0
	-TEM2
	LDA I
	-26
	ADM
	2\TEM3
	FLO
	JMP LOGS1-6
	JMP TRANSB
	DC0
	-TEM3
	JMP ADDTB
	TEM1
	-TEM2
	JMP ADDTB
	-TEM3
	JMP 3
LOGS1,	LDA
	0
	STC .+13
	STA
	2\FAC
	SET I 4
	-13
	JMP MULTB
	-FAC
	XSK I 4
	JMP .-3
	LDA
	2\FAC
	JMP
LOG10B,	SET 5
	0
	JMP LOG2B
	JMP 5
	XSK I 5
	JMP MULTB
	-DCLOG2
	JMP 5
LOGNB,	SET 5
	0
	JMP LOG2B
	JMP 5
	XSK I 5
	JMP MULTB
	-DCLN2
	JMP 5
/
/EXPON
	JMP TRANSB
	DC1
	-FAC
	JMP 3
EXPONB,	SET 3
	0
	SET I 4
	0
	JMP SIGNB
	JMP EXPONB-4
	JMP EXPON1
	JMP NEGFAB
	SET I 4
	-0
EXPON1,	JMP TRANSB
	-TEM1
	JMP TRANSB
	-TEM2
	JMP TRANSB
	DC1
	-FAC
	JMP TRANSB
	-TEM3
EXPON2,	JMP ADDTB
	-TEM2
	LDA
	2\FAC
	COM
	ADA
	2\TEM2
	ADA I
	27
	APO
	JMP EXPON3
	JMP ADDTB
	TEM3
	DC1
	TEM3
	JMP DIVB
	TEM2
	TEM3
	TEM2
	JMP MULTB
	TEM2
	TEM1
	TEM2
	JMP EXPON2
EXPON3,	XSK 4
	JMP 3
	JMP DIVB
	DC1
	-FAC
	JMP 3
/
/LF ? CR
TLFCR,	SET 1
	0
	LDA I
	215
	JMP TYP8B
	JMP TYP8B
	LDA I
	212
	JMP TYP8B
	JMP 1
/
/DBL3GO (MODIFIED)
TYP8B,	XSK I 17
COMPRB,	XSK I 17
FLOATB,	XSK I 17
FIXB,	XSK I 17
TRANSB,	XSK I 17
DIVB,	XSK I 17
MULTB,	XSK I 17
SUBTB,	XSK I 17
ADDTB,	STC .+6
	LDA I
	LDF SEGB
	STA
	2\V3+2
	LDA I
	0
	LIF SEGA
	JMP ENTERA
K7776,	-1
/
/ENTRY JMP LIST
LISTB,	JMP FLOT1B
	JMP FIX12B
	JMP IRLOAB
	JMP TLFCR
	JMP SQROOB
	JMP COSDEB
	JMP SINDEB
	JMP COSRAB
	JMP SINRAB
	JMP LOG10B
	JMP LOGNB
	JMP SIGNB
	JMP MAGTSB
	JMP EXPONB
	JMP POWSEB
	JMP ARCTAB
	JMP ARCSIB
	JMP LOG2B
	JMP COSPIB
	JMP SINPIB
	JMP NEGFAB
	/END DBLFLT3S
/
/
/