*20
/      INTERVAL HISTOGRAM
/          HISTO12
/
/  ROGER A.NACE 
/  ANESTHESIA RESEARCH
/  UNIVERSITY OF WASHINGTON
/  SEATTLE, WASHINGTON 98105
/  MAY 1970
/
KSF=6031		/PDP IOTS
KRB=6036
TSF=6041
TLS=6046
	SEGMNT 0
	*1000
	LDF 3
	0720	/GET INDEX
	4346	/OF TAPE 0
	0700	/PUT IN 6000-7000
	5347
	PDP
	PMODE
/ROUTINE TO FIND FPP2 ON SYSTEMS TAPE
/AND LOAD INTO 5600-7777
STRT,	CLA
	TAD CO6		/6000
	DCA PTR
	TAD M70		/-70
	DCA T2
INC,	TAD PTR		/POINT TO NAME
	TAD CO10	/INC BY 10
	DCA PTR
	TAD PTR
	TAD MI1		/DECREMENT BY 1
	DCA 10		/AUTO INC HOLD
	TAD I 10	/GET FIRST NAME
	TAD IN		/-0620 (FP)
	TAD I 10	/NEXT NAME
	TAD IN+1	/-2062 (P2)
	TAD I 10
	TAD IN+2	/-7777
	TAD I 10
	TAD IN+3	/-7777
	SNA CLA		/IF 0 FPP2 FOUND
	JMP .+4
	ISZ T2		/NOT FOUND
	JMP INC		/DO OVER
	JMP .	/FATAL LOOP IF NO FPP2
	TAD PTR		/POINTS TO FPP2
	TAD C06		/6
	DCA PTR	 /POINTS TO BLOCK NO.
	TAD I PTR	/GET BLOCK NO.
	DCA PTR2	/HOLD
	TAD PTR2
	TAD C3002	/3002,PASS HEAD
	DCA PTR		/AND SET M QTR2
	LINC;	LMODE
	SET I 12
	1777-4		/SET UP COUNT
READIN,	LDA I		/GET INCREMENT
	1001
	ADM		/PUT IN PTR
	PTR
	RDC		/READ BLOCK
PTR,	0		/SECTIONS 2-5
	XSK I 12	/ALL 4?
	JMP READIN	/NO
	LDF 2		/YES, GET SECT 1
	LDA I		/STARTING SECTN
	7002
	ADM		/ADD BLOCK NUMB.
	PTR2
	RDC		/READ SECT 1
PTR2,	0
	PDP; PMODE
	CLA CLL	  /REMOVE + SIGN FROM
	DCA I .+3 /OUTPUT OF FPP2
	JMP I .+1	/JUMP TO TEXT
	3000		/CROSS PAGE JMP
	7327		/ADDR OF + SIGN
MI5,	-5
C3002,	3002
C1001,	1001
CO6,	6000
IN,	-0620
	-2062
	-7777
	-7777
CO10,	10
MI1,	-1
T2,	0
C06,	6
M70,	-70
	LMODE
	SEGMNT 1
	*17
FF,	0
	LDA I	/I/O PRESET
	0020
	ESF
	LDA I	/ENABLE FAST SAMPLE
	0100
	ESF
	SET I 5
	PRSET-1		/POINT TO TEXT
	SET I 4
	1777-5		/INPUT LIMIT
	SET I 3
	CNTLIM-1	/OUTPUT POINTER
	SET I 6		/TEXT COUNT
	1777-11
	CLR		/CLEAR LIMIT BFR
	STC CNTLIM
	STC CNTLIM+1
	STC CNTLIM+2
	STC CNTLIM+3
	IOB
	TLS		/SET FLAG
	LDF 3
D4,	SAM 14		/DISPLAY INPUT
	DIS 10
	XSK I 10	/1777 SAMPLES
	JMP .-3
	SAM 1		/SAMPLE THRESH.
	APO
	JMP .+4		/IF POSITIVE,
	STA		/HOLD
	FF
	DIS 10		/AND DISPLAY
	XSK I 10	/1777 SAMPLES
	JMP .-7
	XSK 6		/ALL PRINTED?
	SKP		/NO
	JMP LSTN	/YES,CHECK INPUT
	IOB
	TSF		/TTY READY?
	JMP D4		/NO, GO BACK
	LDA I 5		/GET CHARACTER
	IOB
	TLS		/PRINT
	XSK I 6		/BUMP COUNT
	JMP D4		/GO BACK
LSTN,	KST		/KEY STRUCK?
	JMP D4		/NO, GO BACK
	IOB
	KRB		/GET CHAR
	XSK I 4		/5 INPUTS?
	SKP		/NO, ECHO
	JMP FINSH	/YES, GO ON
	PDP		/ECHO WITH TYPE
	4\ TYPE		/JMS TYPE
	KRB		/GET CHAR. AGAIN
	6141		/LINC
	SAE I		/RTN?
	0215	
	SKP
	JMP FINSH	/YES, GO ON
	SAE I		/NO, RUB OUT?
	0377
	SKP
	JMP 20		/YES START AGAIN
	BCL I		/NO, GET DIGIT
	7760
	STA I 3		/HOLD INPUT
	JMP D4		/GO BACK
FINSH,	LDA
	FF
	COM		/NEGATE THRESH.
	STC FF		/PUT AWAY
/CONVERT DECIMAL KBD INPUT TO OCTAL
	STC CNTLIM-1	/0 HOLDING BUFF
	SET I 6
	MULT		/MULTIPLE
	SET I 3
	CNTLIM-1	/INPUT POINTER
	SET I 4
	1777-4		/COUNTER
CNRLOP,	LDA I 3		/GET INPUT
	COM		/MAKE NEG
	ADA I		/CALCULATE INDEX
	1776		/-1 AS PRE COUNT
	STC .+2		/PUT AWAY
	SET I 5		/SET INDEX
	0
	XSK I 5		/BUMP
	SKP		/DONT STOP NOW
	JMP .+3		/ENOUGH OF THIS
	ADA 6		/ADD MULTIPLE
	JMP .-4		/GO BACK
	ADM		/PUT AWAY TOTAL
	CNTLIM-1
	XSK I 6		/MULT POINTER
	XSK I 4		/FINISHED?
	JMP CNRLOP	/NO
	PDP;	PMODE	/YES
	CLA CLL
	TAD C16		/3000
	DCA CO1		/ADDR INTER. BUF
	TAD M13		/-2000
	DCA CO2		/COUNT INTER B.
	DCA I CO1	/ZERO TABLE
	ISZ CO1
	ISZ CO2
	JMP .-3
	DCA MS		/CLEAR MS CTR
	DCA SEC		/CLEAR SEC CTR
	DCA CO7		/CLEAR OFLO CTR
	DCA CO4		/CLEAR IMPLS CTR
	JMP I .+1	/PAGE CROSS
	START-4
/NOTE END OF PDP-8 PAGE
	LMODE		/MODE FOR REFER.
	0
CNTLIM,	0		/HOLD KBD LIMIT
	0		/INPUT
	0
	0
PRSET,	320		/P
	322		/R
	305		/E
	323		/S
	305		/E
	324		/T
	240		/SPACE
	277		/?
	240		/SPACE
MULT,	1750		/PWR OF 1000
	144		/PWR OF 100
	12		/PWR OF 10
	1		/PWR OF 1
	PMODE		/RETURN MODE
	JMS CRLF	/C RTN + L FEED
	TAD CNTLIM-1	/GET LIMIT
	CIA		/FORM NEGATIVE
	DCA LIMIT	/HOLD ON PAGE 0
START,	CLA CLL
	DCA MAXCIA	/CLEAR MAX TEST
	DCA T1		/CLEAR SWITCH
	TAD S2		/NOP
	DCA INCT1	/DONT SET SWITCH
	TAD M1		/-5
	DCA ICO1	/LOOP COUNTER
	DCA ICO2	/CLEAR INT COUNT
	TAD C2		/0100
	CLEN		/CLOCK ENABLE
	CLA CLL
	TAD C1		/2500
	CLLR		/CLOCK CONTROL
TL,	CLSA		/CLEAR INTER
	CLA CLL
	ISZ ICO1	/DIV.BY 5
	JMP D1
	TAD M1		/RESET COUNT
	DCA ICO1
	ISZ MS		/BUMP MS CNTR
	SKP
	ISZ SEC		/BUMP SEC. CTR
	ISZ ICO2	/INTERVAL (MS)
	JMP D1
	TAD C6		/PRINT 1 IF
	JMS TYPE	/> 7777 MS
	JMP START	/START OVER
D1,	TAD C3		/7754
	CLAB		/LOAD PRESET
	LINC;	LMODE
	SAM 14		/SAMPLE INPUT
	ADD FF		/SUBTR. THRESH
	PDP;	PMODE
	SPA		/> THOLD?
	JMP NEG		/NO
INCT1,	0	/YES, COUNT POS IMPULSES
	JMP D7 /IF > 7777 PRINT 3
	CLA CLL
	TAD C9
	JMS TYPE
	JMP START	/START OVER
D7,	DCA HOLD	/HOLD SAMP AMP.
	TAD HOLD
	TAD MAXCIA	/NEW MAX ? 
	SPA CLA
	JMP D2		/NO
	TAD HOLD	/YES, REPLACE
	CIA CLL
	DCA MAXCIA	/NEW MAX COMPL.
	TAD S1		/ISZ T1
	DCA INCT1	/FIX VARIAB INST
	TAD ICO2	/INTERVAL
	DCA CO3		/RECORD INTERV
	JMP D2		/SAMPLE AGAIN
NEG,	CLA CLL	 /HERE IF CONV.< THOLD
	TAD T1		/PREV NEG ?
	SNA		/T1=0 IF PREV -
	JMP D3		/NO
	TAD M2		/YES-HOW MANY
	SPA		/ > 2 ?
	JMP D3		/NO - RESET
	TAD M3		/ < 8 (DEC.)?
	SMA CLA
	JMP D3		/NO - RESET
	TAD CO3		/YES TEST INT
	SMA CLA		/INT > 3777 ?
	JMP D5		/NO, LOG IT
	CLA CLL		/YES, PRINT 2
	TAD C7
	JMS TYPE
	ISZ CO7		/BUMP OFLO CTR
	JMP START	/RESTART
D5,	ISZ CO4		/IMPULSE COUNTER
	JMP .+4		/NO OVERFLOW
	CMA		/FIX TOTAL
	DCA CO4		/IF OVERFLOW
	JMP DIS		/QUIT
	JMS BUMP	/LOG ROUTINE
	ISZ LIMIT	/PRESET COUNTER
	SKP
	JMP DIS		/LIMIT REACHED
	DCA ICO2	/CLEAR MS CNTR
D3,	CLA CLL		/RESET
	DCA T1		/COUNTER
	DCA MAXCIA
D2,	CLSK		/READY SAM ?
	SKP		/NO, TEST KBD
END,	JMP TL		/YES - GO BACK
	KSF		/STAGE TO PLOT?
	JMP .-4		/NO, WAIT
DIS,	KCC		/CLEAR KBD FLAG
	TAD C18		/FULL PLOT
	JMS I MOVEP	/POINTER TO MOVE
	JMP I .+1	/CROSS PAGE JMP
	0200		/NEXT LOCATION
BUMP,	0		/INC SUB
	TAD CO3		/INTERVAL
	RAR CLL		/DIVIDE BY 2
	AND MAS1	/1777
	TAD C16		/3000
	DCA CO2		/BIN POINTER
	ISZ I CO2	/BUMP BIN
	JMP I BUMP	/NO OVERFLOW
	HLT
/THIS HALT SHOULD NEVER BE REACHED.
/A BIN OVERFLOW WILL STOP HERE.
/THE TOTAL COUNT OVERFLOW SHOULD
/SWITCH TO DISPLAY FIRST.
	*2377
GRAPH,	LINC
	LMODE
/DISPLAY ROUTINE WRITTEN BY
/J. BRIAN, N.I.H. AND
/MODIFIED BY R.NACE, U. OF WASHINGTON
/
/X AXIS - 200 LOCATIONS, MARKERS AT 25
/Y AXIX - MARKERS AT 100 COUNTS
/(THIS DATA IN DECIMAL)
	LDF 0		/RESTART ADDR
/Y AXIS
R2,	 SET I 2
	40
	SET I 1
	377
	LDA 00
	1
	SET I 3
	1777-5
	DIS 02
	LDA I 0
	-144
	ADM 00
	1
	XSK I 3
	JMP  .-6
/X AXIS
	SET I 2
	37
	SET I 1
	-363
	SET I 2
	37
	SET I 1
	-363
	SET I 3
	1777-311
	LDA 00
	1
	DIS I 2
	XSK I 2
	XSK I 3
	JMP  .-3
/X CAL MARKS
	SET I 2
	40
	SET I 1
	-377
	SET I 3
	1777-11
T2A,	LDA 00
	1
	DIS 02
	LDA I 0
	62
	ADM 00
	2
	XSK I 3
	JMP  T2A
/PLOT CURVE
	SET I 2
	3377
	SET I 1
	40
	SET I 3
	1777-310
	LDA I 2
	APO 
	CLR 
	ADA I 0
	-363
	JMP V2
	XSK I 1
	XSK I 1
	XSK I 3
	JMP  .-11
	SNS I 5
	HLT
	SNS I 4		/TEST SS 4
	JMP .+5		/UP, TIME BELL
	CLR		/DOWN, PROCEED
	STA I
SWIT,	0		/0 BELL SWITCH
	JMP U2
	PDP		/HERE ON SS 4
	4600 .+3	/JMS I DINGP
	6141		/LINC
	SKP
DINGP,	DING		/POINTER TO SUBR
/KEYBOARD TESTS
U2,	KST		/KEY STRUCK?
	JMP R2		/NO, BACK TO PLT
T3,	IOB		/YES, GET CHAR
	KRB
	SAE I 0		/SKIP IF EQUAL
	203		/^C
	SKP		/NO
	JMP 20		/YES, START OVER
	SAE I 0
	204		/^D
	JMP T4		/NO
	LDF 2		/YES, CALL DIAL
	0720
	4270
	LDF 3
	LIF 2
	JMP 16
T4,	SAE I 0
	325		/U
	SKP		/NO
	JMP U3		/YES, ADD 50
	SAE I 0
	261		/1
	SKP		/NO
	JMP NEWG	/NEW PLOT
	SAE I 0
	262		/2
	SKP		/NO
	JMP NEWG	/NEW PLOT
	SAE I 0
	260		/0
	SKP		/NO
	JMP NEWG	/NEW PLOT
	SAE I 0
	263		/3
	JMP .+4		/NO
	LDA I		/RPLC 3 WITH 4
	0004
	JMP NEWG	/NEW PLOT
	SAE I 0
	315		/M (MULTIPLY)
	JMP .+10	/NO
	LDA I		/GET INSTRUCTION
	ADM 16
	STC MF1		/PUT IN MF1
	LDA I		/GET NOP
	NOP
	STC MF2		/PUT IN MF2
	JMP MU1		/GO TO MULTIPLY
	SAE I 0
	306		/F (DIVIDE)
	JMP .+10	/NO
	LDA I		/SAME AS MULT
	SCR 1		/SEQUENCE
	STC MF1
	LDA I
	STA 16
	STC MF2
	JMP MU1
	SAE I 0
	304		/D
	JMP R2		/NO, ILLEGAL KEY
	LDA I 0		/SUBTRACT 50
	-62
	STC  W3
V3,	 SET I 17
	1777-310
	SET I 16
	3377
	LDA I 0
W3,	-62
	ADM I 16
	XSK I 17
	JMP  .-4
	JMP R2
U3,	LDA I 0
	62
	STC  W3
	JMP V3
MU1,	SET I 17  /MULT-DIV ROUTINE
	1777-310	/SET CNTR
	SET I 16	/AND POINTER
	3377
	LDA I 16	/GET BIN
	SAE I 0		/SKIP 6466 (0)
	6466
MF1,	0  /ADM 16 (MULT), SCR 1 (DIV)
MF2,	0  /NOP (MULT), STA 16 (DIV)
	XSK I 17
	JMP .-6		/NOT FINISHED
	JMP R2		/BACK TO DISPLAY
/PLOT POINT
/SUBROUTINE
	0 /SCRATCH
Q2,	0 /SCALING EXP
V2,	SET 4
	0
	SNS I 0
	JMP  .+3
	DIS 01
	JMP 4
	STA 00
	V2-1
	DIS 01
	LDA I 0
	-1
	ADM 00
	V2-1
	SAE I 0
	-364
	JMP  .-7
	JMP  4
E3,	0
	0
	0 	/SCRATCH
M5,	7400
NEWG,	PDP	/NEW GRAPH
	PMODE	/ENTER WITH SIZE IN AC
	AND MAS2	/0007
	JMS MOVE	/MOVE BUFFER
	JMP I .+1
	GRAPH		/GO TO GRAPH
MOVE,	0		/C(AC)=SEGMENT
	CIA		/FORM NEG
	DCA HOLD	/- SEG IN HOLD
	TAD C4		/1400
	DCA CO1		/DEST
	TAD M11		/-400
	DCA CO2		/COUNT
	TAD M12		/6466
	DCA I CO1	/PUT IN ALL
	ISZ CO1		/OF TABLE
	ISZ CO2
	JMP .-4		/NOT FINISHED
	TAD HOLD
	SZA		/WAS HOLD 0?
	JMP .+11	/NO
	TAD D9-1	/ISZ CO1
	DCA D9		/BUMP DEST TWICE
	CMA		/-1
	DCA HOLD	/FIX HOLD
	TAD M11		/-400
	CLL CML RAR	/-200
	DCA CO2		/NEW COUNT
	JMP .+5
	TAD S2		/NOP
	DCA D9		/DONT BUMP TWICE
	TAD M11		/-400
	DCA CO2		/COUNTER
	TAD C4		/1400
	DCA CO1		/DESTINATION
	TAD C16		/3000
	DCA CO3		/ORIGIN
D8,	TAD HOLD
	DCA CO5		/COUNTER
	TAD I CO3	/GET DATA
	ISZ CO3		/BUMP POINTER
	ISZ CO5
	JMP .-3		/NOT FINISHED
	SZA		/IF ZERO SKIP
	DCA I CO1	/LEAVE AT 6466
	ISZ CO1		/BUMP DEST POINT
D9,	0		/NOP OR ISZ CO1
	ISZ CO2		/DONE?
	JMP D8		/NO
	JMP I MOVE	/YES
/ROUTINE TO TYPE AN INSTRUCTION TEXT.
/THE INTERVAL BUFFER OVERLAYS THIS AFTER
/PRINTING INSTRUCTION TEXT
	*3000
	CLA
	TLS		/SET FLAG
	TAD SP		/START OF TEXT-1
	DCA 10		/POINTER
	TAD I 10	/GET WORD
	JMS UNPAK	/UNPACK 6 BIT
	KSF		/KEY STRUCK
	JMP .-3		/NO, GO BACK
	KCC		/YES, CLEAR FLAG
	TAD .+2		/GET ADDR COLM
	JMP .-7		/FINISH OUTPUT
	HEAD		/TITLE ADDRESS
MA1,	7700
MA2,	0077
H,	0
H1,	0
M43,	-43
M33,	-33
ONHD,	100
THD,	200
TST,	0
UNPAK,	0 /ROUTINE TO TYPE 6 BIT PACKING
	DCA H1		/PACKED WORD
	IAC		/1
	CMA		/-2
	DCA TST		/SET SWITCH
	TAD H1		/GET WORD
	AND MA1		/7700
	CLL		/MOVE 6 RIGHT
	RTR
	RTR
	RTR
	DCA H		/HOLD WORD
LOO,	TAD H		/GET WORD
	SNA		/ZERO?
	JMP FIN		/FINISHED
	TAD M43		/-43
	SZA CLA		/=43?
	JMP .+3		/NO
	JMS CRLF	/YES, CR+LF
	JMP LOP		/SKIP REST
	TAD H		/GET WORD
	TAD M33		/-33
	SMA CLA		/<33?
	JMP .+4		/NO
	TAD H		/YES
	TAD ONHD	/100
	DCA H		/HOLD
	TAD H
	TAD THD		/200
	JMS TYPE	/OUTPUT RESULT
LOP,	TAD H1		/ORIG WORD
	AND MA2		/0077
	DCA H		/HOLD IT
	ISZ TST		/TEST SWITCH
	JMP LOO		/NOT FINISHED
	JMP I UNPAK	/FINISHED, EXIT
FIN,	LINC;	LMODE	/ALL DONE
	LIF 1		/GO TO NEXT SECT
	JMP 20
	PMODE
/FOLLOWING IS THE TEXT OF INSTRUCTIONS
/
/     INTERVAL HISTOGRAM 
/  
/STOP INSTRUCTION TEXT BY TYPING ANY KEY.
/ 
/SET THRESHOLD WITH KNOB 1. 
/ 
/TYPE LIMIT TO SPIKE COUNT (IF ANY).
/LEADING 0S ARE REQUIRED!
/     DEFAULT AND-OR MAXIMUM IS 4095.
/ 
/BUILD GRAPH BY TYPING RETURN.
/ 
/TELETYPE DIAGNOSTICS:
/     1; NO IMPULSES FOR 4.096 SECONDS
/     2; IMPULSES MORE THAN 2.048 SECONDS APART
/     3; BASE LINE SHIFT
/         (LONGER THAN 500 MS. CONVERSION)
/ 
/ 
/TO STOP SAMPLING AND DISPLAY TYPE SPACE BAR.
/ 
/DURING DISPLAY:
/     SENSE SWITCH 0 PRODUCES A HISTOGRAM.
/     SENSE SWITCH 4 RINGS THE TTY BELL 
/       EVERY 15 SECONDS.
/     SENSE SWITCH 5 HALTS THE PLOT,
/       PRESS CONTINUE FOR SINGLE SWEEP.
/ 
/  TELETYPE INTERVENTION:
/      U - SCALE UP, ADD 50
/      D - SCALE DOWN, SUBTRACT 50
/      M - MULTIPLY BY 2
/      F - DIVIDE BY 2
/      0 - DISPLAY 0-200 MS.
/      1 - DISPLAY 0-400 MS.
/      2 - DISPLAY 0-800 MS.
/      3 - DISPLAY 0-1600 MS.
/      CTRL C - RESTART
/      CTRL D - CALL MONITOR
/ 
/ 
/IF COMPUTER JUMPS TO DISPLAY, AN 
/OVERFLOW HAS OCCURED FOR THE PRESET
/LIMIT OR THE TOTAL COUNT.
/ 
/ 
/SWITCH RESTARTS (LINC MODE):
/     2020; SAMPLE
/     2400; DISPLAY
/ 
/ 
/ 
/     TOTAL  FREQUENCY       TIME    MISSED.
/
SP,	.	/START OF TEXT POINTER
/START OF TEXT
	NOLIST
INST,	TEXT Z
     INTERVAL HISTOGRAM
  
STOP INSTRUCTION TEXT BY TYPING ANY KEY.
 
SET THRESHOLD WITH KNOB 1.
 
TYPE LIMIT TO SPIKE COUNT (IF ANY).
LEADING 0S ARE REQUIRED!
     DEFAULT AND-OR MAXIMUM IS 4095.
 
BUILD GRAPH BY TYPING RETURN.
 
TELETYPE DIAGNOSTICS:
     1; NO IMPULSES FOR 4.096 SECONDS
     2; IMPULSES MORE THAN 2.048 SECONDS APART
     3; BASE LINE SHIFT
         (LONGER THAN 500 MS. CONVERSION)
 
 
TO STOP SAMPLING AND DISPLAY TYPE SPACE BAR.
 
DURING DISPLAY:
     SENSE SWITCH 0 PRODUCES A HISTOGRAM.
     SENSE SWITCH 4 RINGS THE TTY BELL
       EVERY 15 SECONDS.
     SENSE SWITCH 5 HALTS THE PLOT,
       PRESS CONTINUE FOR SINGLE SWEEP.
 
  TELETYPE INTERVENTION:
      U - SCALE UP, ADD 50
      D - SCALE DOWN, SUBTRACT 50
      M - MULTIPLY BY 2
      F - DIVIDE BY 2
      0 - DISPLAY 0-200 MS.
      1 - DISPLAY 0-400 MS.
      2 - DISPLAY 0-800 MS.
      3 - DISPLAY 0-1600 MS.
      CTRL C - RESTART
      CTRL D - CALL MONITOR
 
 
IF COMPUTER JUMPS TO DISPLAY, AN
OVERFLOW HAS OCCURED FOR THE PRESET
LIMIT OR THE TOTAL COUNT.
 
 
SWITCH RESTARTS (LINC MODE):
     2020; SAMPLE
     2400; DISPLAY
 Z
HEAD,	TEXT Z
  
     TOTAL  FREQUENCY       TIME    MISSED
 
Z
	LIST
/END OF TEXT
	0000		/TERMINAL
	.
	*200
/FLOATING POINT OPERATE INSTRUCTIONS
FNOR=7000
FMPY=3000
FEXT=0000
FADD=1000
FDIV=4000
FGET=5000
FPUT=6000
	CLA
	TLS		/SET FLAG
	JMS CRLF
	TAD CO4		/GET TOTAL COUNT
	JMS FLOAT	/FLOAT IT
	JMS I 6		/OUTPUT TOTAL
	TAD SEC		/(4.096/INC)
	JMS FLOAT	/PUT IN FAC
	JMS I 7		/ENTER INTERPRET
	FMPY FP4096	/X 4096
	FPUT SEC	/HOLD
	FEXT
	TAD MS		/GET MS.
	JMS FLOAT	/FLOAT MS
	JMS I 7		/INTERP
	FADD SEC	/ADD SECONDS
	FDIV FP1000	/CONVERT TO SEC.
	FPUT SEC	/HOLD
	FEXT
	TAD CO4		/TOTAL AGAIN
	JMS FLOAT	/FLOAT IT
	JMS I 7		/INTERP
	FDIV SEC	/AVERAGE
	FEXT
	TAD C17		/DECIMAL PLACES
	JMS I 6		/OUTPUT AVERAGE
	JMS I 7		/INTERP
	FGET SEC	/GET SEC
	FEXT
	TAD C17		/DEC
	JMS I 6		/OUTPUT SECONDS
/NOW CHECK FOR COUNT > 1.6 MS.
	TAD M14		/-337
	DCA CO1		/COUNT
	TAD C19		/4440
	DCA CO2		/ORIGIN
	DCA CO4		/OFLO CNTR
	TAD CO7		/GET "2" COUNT
	CLL
	TAD I CO2	/TALLY MISSED
	ISZ CO2		/COUNTS
	SZL		/OVERFLOW?
	ISZ CO4		/YES
	ISZ CO1		/NO
	JMP .-6		/NOT DONE
	JMS FLOAT	/FLOAT TOTAL
	JMS I 7		/INTERP
	FPUT SEC	/HOLD IT
	FEXT
	TAD CO4		/4096 OFLOW
	JMS FLOAT	/FLOAT OVERFLOW
	JMS I 7		/INTERP
	FMPY FP4096	/CORRECT
	FADD SEC	/FINAL TOTAL
	FEXT
	JMS I 6		/OUTPUT MISSED
	JMS CRLF
	JMP I .+1	/CROSS PAGE JUMP
	GRAPH
FLOAT=. /ROUTINE TO FLOAT AC INTO FAC
	0
	SPA		/>2048?
	ISZ FPFL	/YES, SET SWITCH
	AND MAS3	/3777
	DCA 45	   /PUT IN HIGH FAC
	DCA 46	   /0 TO LOW FAC
	TAD FLC13  /11 INTO EXPONENT
	DCA 44		/EXP
	JMS I 7	/CALL INTERPRETER
	FNOR	/NORMALIZE
	FEXT
	TAD FPFL	/CHECK SWITCH
	SNA		/SET?
	JMP I FLOAT	/NO, EXIT
	JMS I 7		/YES, ADD 2048
	FADD FP2048
	FEXT
	DCA FPFL	/CLEAR SWITCH
	JMP I FLOAT	/EXIT
FPFL,	0
FLC13,	0013
FP2048,	0014
	2000
	0000
FP1000,	0012
	3750
	0
	*400
DING=. /ROUTINE TO RING TTY BELL 15 SEC.
	0
	CLA
	TAD I SWITP	/TEST SWITCH
	SZA		/FIRST TIME?
	JMP BEL		/NOT FIRST TIME
	TAD BELT	/FIRST TIME
	CLAB		/15 SEC.
	CLSA		/CLEAR OVERFLOW
	CLA IAC		/1
	DCA I SWITP	/SET SWITCH
	TAD C2		/0100
	CLEN		/CLOCK INTERUPT
	CLA
	TAD BELT+1	/1100
	CLLR		/FAST CLOCK
	CLSK		/QUICK SET
	JMP .-1
	CLA
	TAD BELT+2	/5100
	CLLR		/SLOW CLOCK
	CLSA		/CLEAR OFLOW
BEL,	CLSK		/CHECK OVERFLOW
	JMP I DING	/NOT YET
	CLA		/YES
	TAD C13
	TLS		/DING!
	CLA
	DCA I SWITP	/RESET SWITCH
	JMP I DING
BELT,	-2715		/CORRECTED -1500
	1100
	5100
SWITP,  SWIT
/PAGE 0 REFERENCES, WATCH FPP2 LOCATIONS
	*5
	7400		/FLOATING
	7200		/POINT
	5600		/ENTRIES
	*20
T1,	0
TYPE=. /ROUTINE TO OUTPUT AC ON TTY
	0
	TSF		/READY
	JMP .-1		/NO
	TLS		/OUTPUT
	CLA		/EXIT AC CLEAR
	JMP I TYPE	/EXIT
C1,	2500		/CLOCK CONTROL
C2,	0100
C3,	7754
C4,	1400
C6,	0261
C7,	0262
C9,	0263
C11,	0215
C12,	0212
	*40
/SPACE 40-54 FOR FPP2 - LEAVE ALONE!
	*55		/FLAGS FOR
	7777		/FLOATING
	7777		/POINT
	0		/OPERATING
	0		/SYSTEM
	0		/
	0012		/
C13,	0207
C15,	0400
CO1,	0
CO2,	0
CO3,	0
CO4,	0
ICO1,	0
ICO2,	0
S1,	ISZ T1		/FOR INCT1
S2,	NOP		/FOR INCT1
HOLD,	0
MAXCIA,	0
LIMIT,	0
M4,	-5000
/M5 IN LINC FIELD
M6,	-1000
MAS1,	1777
MAS2,	0007
MAS3,	3777
M11,	-400
M12,	6466		/ZERO FOR PLOT
M13,	-2000
M14,	-337
MS,	0
SEC,	0		/SPACE TO FLOAT
	0
	0
C16,	3000
C17,	0003
C18,	0004
C19,	4440
CO5,	0
CO7,	0
FP4096,	0015
	2000
	0000
MOVEP,	MOVE
CRLF=./SUBROUTINE TO TYPE C RTN + L FEED
	0
	TAD C11		/215 (RTN)
	JMS TYPE
	TAD C12		/212 (LF)
	JMS TYPE
	JMP I CRLF
	DECIMAL
M1,	-5
M2,	-2
M3,	-8