*20
/FX FOR ADDITIONAL FUNCTIONS
/PRELIMINARY VERSION PER
/DAVE COPE.
/IMPLEMENTS FUNCTIONS AS
/DESCRIBED ON PAGE 61
/LAB. COMPUTER HANDBOOK.
/15 JAN 1971.
/
	PMODE
	BOTTOM=35
	FEXP=4620
	FLAC=44
	EFUN3I=136
	PFZ=412
	PFX=PFZ-1
	PFNEW=PFZ-2
	INTEGE=53
/
/
	*BOTTOM
	FX-1
	*PFX
	FX
	*FEXP-151
FX,	JMS I INTEGE	/GET INTEGER ARG
	IOF		/FOR LMODE CODE
	LINC
	LMODE
	STA I
ARG,	0		/HOLD ARG
	CLR
	ADD 0
	STC ZERO
	ADD ARG
	ADD M5
	APO I		/SENSE SWITCHES?
	JMP NOTSNS	/NO
	LDA		/YES
	ARG
	ADD ISNSI	/FORM SNS I N
	STC .+1
	0		/SNS I N
	ADD ONE		/SW=1
EXIT,	PDP		/SW=0
	PMODE
	DCA FLAC+2	/STORE ANSWER
	DCA FLAC+1
	TAD O27
	DCA FLAC
	LINC
	LMODE
	ADD ZERO	/RESTORE LOC 0
	STC 0
	PDP
	PMODE
	ION
	JMP I EFUN3I	/BACK TO FOCAL.
	LMODE
M5,	-5
ISNSI,	SNS I
ONE,	1
O27,	27
/
/
NOTSNS,	ADD M2		/HERE WITH ARG-5
	APO I		/LSW OR RSW?
	JMP STATUS	/NEITHER
	COM		/AC=-1 FOR LSW,    OR -0 FOR RSW
	ADD ISW		/FORM LSW OR RSW
	STC .+1
	0
	JMP EXIT
M2,	-2
ISW,	RSW
/
/
STATUS,	ADD M28		/HERE WITH ARG-7
	APO I		/RELAYS?
	JMP XSENS	/NO, SENSE LINES
	STC ARG		/YES
	RTA		/GET RELAY STATUS
	STC RELAYS
	ADD ARG
	ADD P6
	APO		/CLOSE RELAYS?
	JMP OPEN	/NO
	JMP GETBIT	/SET AC BIT
	BSE
	RELAYS		/OR WITH RELAYS
	ATR
	JMP EXIT
P6,	6
M28,	-34
/
/
OPEN,	ADD P10
	APO		/OPEN RELAYS?
	JMP READ	/NO, READ STATUS
	JMP GETBIT	/YES
	COM
	PDP
	PMODE
	AND RELAYS
	LINC
	LMODE
	JMP OPEN-4
P10,	12
/
/
READ,	ADD P10
	JMP GETBIT
	PDP
	PMODE
	AND RELAYS
	LINC
	LMODE
	AZE I		/RELAY CLOSED?
	JMP EXIT	/NO
	CLR		/YES
	ADD ONE
	JMP EXIT
RELAYS,	0
/
/
XSENS,	ADD M20
	APO		/SENSE LINES?
	JMP .+3		/YES
	CLR		/NO, INVALID ARG
	JMP EXIT
	ADD P15
	ADA I
	SXL I
	STC .+1
	0		/SXL I N
	ADD ONE
	JMP EXIT
M20,	-24
P15,	17
/
/
GETBIT,	COM
	ADD P6		/WE MUST FORM A
	ADA I		/BIT IN THE AC
	ROL		/CORRESPONDING
	STC .+2		/TO THE
	ADD ONE		/REQUIRED RELAY.
	0
	JMP 0
/
ZERO,	0
/
	LISTAP -7