*20
	*20	
/FOCAL-12 OVERLAY TO READ THE RELAYS
/WRITTEN BY STEVE POMFRET
/DIGITAL EQUIPMENT CORP.
/
/USE THE COMMAND "SET A=FX(N)"
/WHERE N=0 TO 5 TO SET THAT RELAY;
/"SET A=FX(7)" CLEARS ALL RELAYS
/ERROR MESSAGES:
/?18.83 - NUMBER >7 TYPED
/?18.:1 - 6 IS ILLEGAL VALUE
/
	PMODE
	BOTTOM=35
	FEXP=4620
	FLAC=44
	EFUN31=136
	PFZ=412
	PFX=PFZ-1
	INTEGER=53
	ERROR2=4566
	ERROR3=4566
/
	*BOTTOM
	FX-1
	*PFX
	FX
	*FEXP-82	/SO SAME PAGE
FX,	JMS I INTEGER	/GET ARG
	DCA TRY
	TAD TRY
	AND C7770	/SAVE 1ST 9 BITS
	SZA		/IS N>7?
	ERROR2		/YES
	TAD TRY		/NO. TEST FOR N
	AND C7		/STRIP ALL BUT
			/LAST 3 BITS
	DCA TEMP
	TAD TEMP	/GET NEW ARG
	IAC
	AND C7
	SZA		/WAS ARG=7
	JMP TEST1	/NO. TRY AGAIN
	IOF		/YES.CLEAR RELAY
	LINC
	LMODE
	ATR
	PDP
	PMODE
	JMP TION	/RETN TO FOCAL
TEST1,	IAC
	AND C7
	SZA CLA		/TEST FOR 6
	JMP TEST2	/N=0 TO 5
	ERROR3		/ILLEGAL VALUE
TEST2,	TAD P40
	DCA SR
	TAD TEMP
	SNA		/IS IT 0?
	JMP SET		/N=0
	CIA		/N=1 TO 5
	DCA TEMP	/SAVE COUNTER
	TAD SR
LOOP,	CLL RAR
	ISZ TEMP
	JMP LOOP
	DCA SR
SET,	IOF
	LINC 
	LMODE
	RTA
	BSE I
SR,	0000		/PUT VALUE IN AC
LOAD,	ATR
	PDP
	PMODE
TION,	ION
	JMP I EFUN31	/RETN TO FOCAL
TEMP,	0000
C7,	0007
P40,	40
C7770,	7770
TRY,	0000
	LISTAP-7