*20
/12K EXTENSION FOR FOCAL-12
/TEXT IS IN FIELD 2;VARIABLES AND PDL,IN FIELD 0
	PMODE
	AXIN=10
	AXOUT=17
	BOTTOM=35
	BUFR=60
	CFRS=133
	CHFLAG=147
	COMBOT=226
	COMBUF=132
	COMEIN=3140
	C200=123
	DGRP1=441
	DOK=2113
	DOONE=463
	END=134
	ENDT=135
	ERG=2227
	ERT=2216
	ERV=2221
	ERVX=2241
	FEND3=2267
	FEXP=4620
	FILSTR=1326
	FINDN=2250
	GET3=2345
	GOTO=603
	GS1=1435
	GTEM=21
	INBUF=34
	INPUTX=271
	ITSAGO=1736
	LASTV=31
	LINE1=111
	LINENO=67
	LLOAD=1203
	LSAVE=1233
	LSBLK=1324
	M100=101
	OP=3115
	O6000=173
	O7=1776
	P=0
	PACX=2530
	PC=22
	PCK1=2535
	PT1=30
	PWAIT=174
	QADD=61
	RECOVR=2740
	RECOVX=2761
	RETRN=1563
	RITEOU=3651
	ROT=2557
	RUB3=3030
	SCONT=1266
	SRETN=261
	START=177
	T=20
	TDUMP=3052
	THISLN=23
	TSTGRP=4563
	WAIT=7657
	WALL=664
	WTEST2=653
	XENDLN=2360
	XGETOUT=1254
	XI33=2666
	XOUTL=2676
	XR1=14
	XR2=15
	XRT=11
FIELD 0
LINE0=100
*PC
	0
*LASTV
	COMEIN
	*BOTTOM
	PWAFAKE-1	/DELETES ABOUT 20 VARIABLES
*BUFR
	LINE1
*COMBUF
	10
*CFRS
	LINE0	/START OF TEXT
*ENDT
	LINE1
	*PWAIT
DTHIS,	THISD	/THISLN
*START+2
	NOP
*COMBOT
	LINE0
*SRETN-5
	JMS I .+1	/DCA I AXIN
	DAXINFAK
*INPUTX+2
	JMS I .+1
	DPCFAKE
*DGRP1-4
        JMS I .+1	     /TAD I XRT IN OTHER D.F.
	DXRTFAKE
*DGRP1+4
	JMS I .+1
	DPCFAKE
	*DOONE-6
       JMS I .+1	/TAD I PT1 IN OTHER DF
	PT1DF1
*DOONE-3
	JMS I .+1
	PT1DF2
*WTEST2-1
	JMS I DTHIS	/TAD I THISLN
*WALL-4
	JMS I .+1	/TAD I PT1
	PT1DF3
*WALL
	JMS I .+1
	PT1DF2
*SCONT-4
	JMS I .+1	/(DCA I AXIN)
	DAXINFAK
*GS1+6
	TAD END
*RETRN
	NOP
*DOK-4
	CDF T
*ERV-1
	CDF T
	DCA I CFRS	/LEAVE THE VARIABLES ALONE
	CDF P
*ERG+4
	JMS I DTHIS	/TAD I THISLN
	TSTGRP
	JMP START
	JMS I DTHIS
*ERVX
	TAD END
*FINDN+4
	JMS I .+1
	DXRTFK
*FEND3-3
	JMS I DTHIS
*GET3
	JMS I .+1
	DXOFAKE
*XENDLN+1
	CDF T
*XENDLN+14
	CDF P
	JMP I XENDLN
*PACX
	CDF P
*PCK1+4
	JMS I .+1	/CLEAR
	FDAXIND
	CLL
	TAD M100	/CMD BF ENDS
	NOP		/FLD,LOC.100
	TAD AXIN	/INPUT PTR
	SZA CLA
/MAKING CODING ROOM
*XI33+1
	JMS I .+1
	PWAFAKE
PWAIT1,	WAIT
*XOUTL+5
	JMS I PWAIT1
*RECOVR+10
	CDF
*RECOVX+6
	JMS I .+1
	DPCFAKE
*RUB3-10
	CDF T
*TDUMP
	TAD END
*TDUMP+10
	JMP I OP+1
*OP
	0003
	TDUMPX
	*RITEOU-3	/SET UP FIELD 2 HDR
	JMP I .+1
	SETFL2
	*4000
SETFL2,	TAD M10
	DCA MOVCTR
	TAD DUMMY
	DCA XR1
	TAD REALOC
	DCA XR2
LOOP1,	CDF P
	TAD I XR1
	CDF T
	DCA I XR2
	ISZ MOVCTR
	JMP LOOP1
	TAD M11
	DCA MOVCTR
	TAD RELOC2
	DCA XR2
LOOP2,	CDF P
	TAD I XR1
	CDF T
	DCA I XR2
	ISZ MOVCTR
	JMP LOOP2
	CDF P
	ION
	JMP I .+1
	ERT
M10,	-10
M11,	-11
DUMMY,	TABLE-1
REALOC,	-1
RELOC2,	77
MOVCTR,	0
TABLE,	0		/ZERO PC
	0
	0		/TDUMP DATA
	0
	0
	5051
	BUFR
	LINE1
/10-77:COMMAND INPUT BUFFER
/*LINE0-START OF TEXT
	0
	0
	TEXT ZC-12K FOCL12Z
	7715
/*ST12K; START 12K USER FILE AT THIS ADDRESS,111. (LINE1=111)
	*FEXP-172
PWAFAKE,	0
	ISZ PWAFAKE
	ISZ PWAFAKE
	TAD INBUF
	SNA
	JMS I WAIT1
	JMP I PWAFAKE
WAIT1,	WAIT
DAXINFAK,	0
	TAD LINENO
	CDF T
	DCA I AXIN
	CDF P
	ISZ DAXINFAK
	JMP I DAXINFAK
FDAXIND,	0
	CDF T
	DCA I AXIN
	CDF P
	DCA QADD
	ISZ FDAXIND
	JMP I FDAXIND
DXRTFAK,	0
	DCA XRT
	CDF T
	TAD I XRT
	CDF P
	ISZ DXRTFAK
	JMP I DXRTFAK
DXRTFK,	0
	CLL CMA IAC
	CDF T
	TAD I XRT
	CDF P
	ISZ DXRTFK
	JMP I DXRTFK
PT1DF1,	0
	ISZ PT1DF1
	CDF T
	TAD I PT1
	CDF P
	TSTGRP
	JMP I PT1DF1
	ISZ PT1DF1
	JMP I PT1DF1
PT1DF2,	0
	CDF T
	TAD I PT1
	CDF P
	DCA LINENO
	ISZ PT1DF2
	JMP I PT1DF2
PT1DF3,	0
	ISZ PT1DF3
	SPA CLA
	JMP I PT1DF3
	CDF T
	TAD I PT1
	CDF P
	JMP I PT1DF3
DPCFAKE,	0
	ISZ DPCFAKE
	CDF T
	TAD I PC
	CDF P
	SZA
	ISZ DPCFAKE
	JMP I DPCFAKE
DXOFAKE,	 0
	CDF T
	TAD I AXOUT
	CDF P
	DCA GTEM
	ISZ DXOFAKE
	JMP I DXOFAKE
TDUMPX,	CDF T
	DCA I .+3
	CDF P
	JMP I .+2
	4
	TDUMP+11
THISD,	0
	CDF T
	TAD I THISLN
	CDF P
	JMP I THISD
/
/THIS RTN SAVES OR LOADS FIELD 2 TEXT
/
DIALIO,	0		/TEMP
PREAD,	7774
PFILSTRT,	FILSTRT
PLSBLK,	LSBLK
PTR,	0		/UNIT
	40		/FIELD 2
	0		/STARTING TBLK
	20		/ALL OF FIELD 2
WRITE,	IAC		/7775 FOR WRITE
READ,	TAD PREAD	/7774 FOR READ
	DCA DIALIO
	CDF 10
	TAD I PLSBLK	/UNIT
	DCA PTR
	CLA CLL IAC RTL	/4
	TAD I PFILSTRT	/STARTING TBLK
	CDF 0
	DCA PTR+2
	CIF 10
	JMS I DIALIO	/READ OR WRITE
	PTR
	ION
	CLA IAC
	CDF 10
	ISZ I PCHFLAG
	CLA
	CDF CIF 0
	SZA CLA
	JMP I PGOTO
	JMP I .+1
	START
PGOTO,	GOTO
PCHFLAG,	CHFLAG
/
/FIELD 1 CHANGES FOR SAVING AND LOADING PROGRAMS
/
	FIELD 1
	*O6000
MLENGTH,	7754	/COMP OF ID
XLENGTH,	24	/24 TBLKS;ALSO NEW ID
	*LLOAD+6
	TAD XLENGTH	/NEW LENGTH IS 24 TBLKS
	*LSAVE-6
	TAD MLENGTH	/1ST WD MUST BE 24
	*LSAVE-1
	JMP XGETOUT+3
	*LSAVE+3
	TAD XLENGTH	/24 TBLKS
	*XGETOUT-5
	TAD XLENGTH	/ID IS 24
	*XGETOUT
	CDF CIF
	JMP I .+1
	WRITE
	CDF CIF
	JMP I .+1
	READ
	*ITSAGO+3
	TAD X6000	/MAKING CODING ROOM
	*O7+1
X6000,	6000
	LISTAPE -7