*20
	*11
P1,	1
	*16  /4016
	/LOAD NAME OR NONAME
RSTART,	RCG I E7  /RESTART THE EDITOR
	7\D7
	RDC I E7 /START^2
	1\D7+55  /LOAD RST OF LOADER
START,	JMP L8  /CHK FOR NAME-GET INDEX
	JMP M8  /NONAME RETURN
	LDA I 10
	LDA I 10
	LDA I 10  /HDR TBLK
	BSE I
	2000
	STA
	NN8+4
	ADD P1
	STC QC
	LDA I 10  /1ST BINARY BLK
	APO
	JMP D8
	JMP NN8
S8,	SET I 12
	BUF-1
	SET I 2  /LOAD SEGS 0,1
	-2
	JMP QSET
	JMP FLDER	/0
	JMP FLD
	LDA I 12  /CHK FOR MBLK 4000
	APO I
	JMP NO4000  /MBLK 4000 NOT USED-DONT
	LDA        /NEED BOOT
	QC
	BCL I  /SAVE TBLK FOR
	7000    /FINAL READ
	BSE I
	4000
	STC DUMXIT+5
	JMP UP
NO4CON,	LDF 3
	ADD QC
	BCL I
	7000
	BSE I
	1000
	STC QC
	SET I 1
	-7
MOR,	LDA I 12  /LOAD 4400-7777
	APO
	JMP RDS
	XSK I 1
	JMP MORA
	JMP .+2
	JMP MOR
NOXA,	JMP FLDER  /MB CHECK TO NOEST IF 4K
	JMP FLDER
	JMP FLDER  /FLD+2=LDF 4
	SET I 2
	-4   /ALL 4 SEGS OF 2ND BANK
	JMP QSET
	JMP FLD
	JMP NOEST  /SET UP BOOTSTRAP
NO4000,	LDA I   /DONT NEED BOOTSTRAP
	5374    /JMP AROUND LOAD
	STC DUMXIT+2
	JMP NO4CON
MORA,	LDA I  /ROUTINE BUMPS MBLK
	1000
	ADD QC
	STC QC
	XSK I 0
	JMP 0
M8,	LDF 0  /SET UP TO LOAD FROM TP 1-WA
	RDC I U
	4\A7
	RDC I U
	5\A7+1
	RDC I U
	6\A7+2
	RDC I U
	7\A7+3
	LDF 1
	RCG I U
	3\A7+4
	RCG I U
	2\A7+11
	LDF 3
	RCG U
	3\A7+14
	CLR     /CANT LOAD AND GO
	STC DUMXIT+13
/SET TO JMP NOEST IF ONLY 4K MEM
/ELSE LOAD THE 2ND BANK
EXST,	LDF 4
	RDC I U
	4\A7+20
	RDC I U
	5\A7+21
	RDC I U
	6\A7+22
	RDC I U
	7\A7+23
	LDF 5
	RCG I U
	3\A7+24
	LDF 6
	RDC I U
	4\A7+30
	RDC I U
	5\A7+31
	RDC I U
	6\A7+32
	RDC I U
	7\A7+33
	LDF 7
	RCG U	/SLOW DOWN
	3\A7+34
/THIS RTN RELOCATES BOOTSTRAP TO 7761
/WHICH LOADS MBLK 4000
NOEST,	SET I 3
	DUMXIT-1
	SET I 4
	EXIT+1777
	SET I 2
	-17
	LDF 3
LOOP,	LDA I 3  /SET UP BOOT
	STA I 4
	XSK I 2
	JMP LOOP
	LDA    	/RESTORE 6000
	2000
	LDF 2
	LIF 3
	JMP EXIT  /GOOD BYE
DUMXIT, STC 0
	LDA I  /SET TO JMP .+5 BY NO4000
	0  /MB L8+3
	AXO
	RDC U  /MB L8+7
	4\A7+10  /PRESET FOR NONAME-MB NO4CON
	LDA I 	/IO PRESET-HLT IF NOT L?G
	20
	ESF
	CLR
	LDF 3
	HLT  /SET TO LIF/PDP
	HLT  /SET TO JMP/CIF
	HLT  /SET TO JMP I .+1 IF 8MOD
	HLT  /SET TO ADDR IF 8MOD
UP,	LDA I
	1
	ADD QC
	STC QC
	JMP 0
RDS,	SET 3
	0
	JMP DTEXTR-1
	RDC
QC,	0  /MB R8+10,S8+12,MORA
	LDA I
	1
	ADD QC
	STC QC
	AXO
	JMP 3
	LDA I    /ENTRANCE-SETS UP XOB
DTEXTR,	0
	AXO
	CLR
	JMP 0
/RESET MBLK TO 4 AT THE QC READ
QSET,	ADD QC
	BCL I
	7000
	BSE I
	4000
	STC QC
	JMP 0
/SETS UP FLD SUBROUTINE FOR THE NXT DF
FLDER,	LDA I
	LDF 0
	STC FLD+2
	ADD P1
	ADD FLDER+1
	STC FLDER+1
	JMP 0
/LOADS THE NXT FIELD
FLD,	SET 5
	0
	LDF 0
FOUR,	SET I 1
	-4
UPS,	LDA I 12  /CHK MAP - THIS BLK USED ?
	APO
	JMP RDS  /YES-READ IT IN
	CLR
	XSK I 1  /THRU THIS SEG ?
	JMP MORA  /NO-BMP MBLK AT QC
	JMP .+2
	JMP UPS  /NXT MBLK
	XSK I 2  /LAST SEG ?
	JMP .+2  /NO
	JMP 5    /YES-XIT
	JMP QSET  /NO-NXT SEG
	JMP FLDER
	JMP FLD+2
*BUF=.
0
*BUF+37
	0        /NB THIS MUST BE MBLK 0
/SETS UP AC ? LINK FOR TAPE UNIT
SETS,	CLR
	LDA
	E6+6  /TAPE NO
	ROR I 1  /UNIT TO LINK
	BCL I  /EXT TAPE UNIT BITS
	7774
	JMP 0
/CHK FOR NAME-THEN GET INDEX ? LOCATE
L8,	SET 7
	0
	JMP CHECK  /CHK FOR 4 OR 8K
	LDH
	E6+2
	SHD I
	7700
	JMP 7  /NONAME-LOAD FROM WA 0N 1
	XSK I 7  /BMP XIT TO SHOW NAME FOUND
	JMP SETS
	STA    /STORE EXTENDED TAPE UNIT BITS
	DUMXIT+2
	STC DTEXTR
	ROL I 4  /RETRIEVE THE UNIT BIT
	BSE I
	RDC
	STA
	DUMXIT+4  /RDC ORDER
	STA
	A8
	STA
	QC-1
	STC NN8+3
	JMP A8-3  /RDS THE INDEX BLKS
	LDA I 10
	SAE I
	5757
	JMP D8  /NO INDEX-DISPLAY NO
	JMP B8  /SEARCH 1ST BLK
	JMP 7  /FOUND IN 1ST BLK
	JMP A8-3
	JMP B8
	JMP 7  /FOUND IT IN 2ND BLK
	JMP D8	/NO
/THIS RTN RELOADS THE EDITOR ? STARTS IT AT 4020
AZ,	SET I RSTART-1
	LDF 3
	JMP RSTART-1
/THIS RTN DISPLAYS NO-THEN GOES TO AZ
D8,	CLR
	SET I 1
	340
	SET I 12
	A6+34
	DSC 12
	DSC I 12
	SET I 1
	352
	DSC I 12
	DSC I 12
	KST
	JMP D8+1
K8,	JMP AZ
/THIS RTN READS IN THE HDR BLK ? SETS BUFF
NN8,	SET 3
	0
	JMP DTEXTR-1  /SET UP FOR EXTENDED UNITS
	RDC   /HDR BLK TO 5000
	0
	CLR
	AXO
	SET I 1
	-40
	SET I 17
	BUF-1
	SET I 12
	USEDNO
	LDA I 12
	STA I 17
	XSK I 1
	JMP .-3
	LDA  /SET START UP FOR BOOTSTRAP
/SB HAS SET UP 1ST 4 WDS FOR START MODE
	STARTR
	STC DUMXIT+13
	LDA
	STARTR+1
	STC DUMXIT+14
	LDA
	STARTR+2
	STC DUMXIT+15
	LDA
	STARTR+3
	STC DUMXIT+16
	JMP 3
/READ IN THE INDEX FROM THE NAMED UNIT
	SET 1
	0
	JMP DTEXTR-1
A8,	RDC
	2\G7
	SET I 10
	4777
	ADD P1
	ADD A8+1
	STC A8+1
	AXO
	JMP 1
/SEARCH THE GIVEN INDEX BLK FOR NAME
B8,	SET 1
	0
	SET I 12
	-4
	SET I 13
	E6+1
	LDA 
	10
	BSE I
	7
	SAE I
	5377
	JMP .+3
	XSK I 1
	JMP 1
	STC 10
	LDA I 10
	SAE I 13
	JMP B8+2
	XSK I 12
	JMP .-4
	JMP 1	/MATCH
/THIS RTN CHKS FOR 4OR8K
UPPY,	0
CHECK,	SET 3
	0
	PDP
	PMODE
	CDF 10
	CLA IAC
	DCA I UPPY  /ST 1 IN UPPER MEM
	CDF 0
	DCA I UPPY  /CLR LOWER MEM
	CDF 10
	TAD I UPPY  /AC TO 0 IF UPPER MEM
	LINC
	LMODE
	AZE  	/SKIP IF ONLY  4K
	JMP OUT  /AT LEAST 8K
	LDA I
	JMP NOEST
	STC EXST  /ONLY 4K FROM WA IF NONAME
	LDA I
	JMP NOEST
	STC NOXA  /ONLY 4K
OUT,	LDF 1
	JMP 3
D7=300
A7=370
J7=430
B7=0
E7=0
C7=470
E6=2371
G7=346
F7=270
A6=2001
KBDOPR=6400
USEDNO=1337
EXIT=1761
STARTR=1000