*20
/DIAL-MS EDITOR
/EDITOR
/UPDATE
/15 DEC 69
/UPDATED TO CHAINING 5/14/70
/
/
/	UPDATED FOR MULTIPLE RK08S 8/11/70
/
/
/
/
/
/
/
/
/
	EJECT
	SEGMNT 3
	LMODE
	*20
			/KNOB S.R.
SAM3,	SAM 3		/CURSOR
	ADA I
	-1000
	SCR 2
	STC CURVAL
	JMP 0
SAM7,	SAM 7		/LNS PER FRAME
	SCR 6
	ADD P10
	JMP 0
	NOP
	NOP
	NOP
P10,	10
DSCCUR,	LDA
	0
	STC SCPRTN
	SET 4
	14
	LDH I 4
	SAE I
	LF
	JMP BYMC
	LDA
	14
	SAE
	2
	JMP Y5
			/DISPLAY CURSOR
/
/
BYMC,	SET I	12	/SET CURSOR POINTER TO POINT TO
	CURSOR		/GRID PATRN ADDR
	JMP	JBTMT	/SET STATUS NOW OF FLICKER INDICATOR.
	LDA I		/CURSOR VC IS BELOW
JBM10,	-10		/CURSOR LN
	ADD VCOORD	/VC OF CURSOR LN
	STA
	CURVC		/CURSOR VC
	DSC 12
	DSC I 12
	CLR
	STC CURFLG	/SET FLAG TO 0
	ADD	JBM10	/RESET HC TO INHIB GAP BETWEEN CHARACTERS.
	ADM
POS1,	1
SCPRTN, 0		/RTN
CURVC,	0
CURFLG,	0
CURSOR,	7717		/THESE LOCS DET.
	1777		/CURSOR PATTERN
GAPARG,	0
DOCL,	IOB			/WAIT FOR TTY FREE BEFORE
	PMODE
	TSF			/CLEARING THE WORKING AREA
	LMODE
	JMP	DOCL		/HANG
	LIF	2		/SET UP THE PROPER I.F.
	JMP CLWA
DOPI,	SET I 12	/GET PIP
	E6+1+2000	/NAME SECTOR OF
			/MC PARAM TABLE
	LDA I		/PUT P I P IN TABLE
	2011		/PI
	STA I 12
	LDA I
	2077		/P77 (77 TERMINATES
	STA I	12		/NAME)
	LDA I			/FILL OUT REST OF NAMES WITH 77S
	7777
	STA I	12		/WORD NUMBER 3
	STA I	12		/WORD NUMBER 4
	LDF	7		/PREPARE TO PICK UP UNIT PARAMETER TABLE
	LDA
	DSYS!2000		/GET THE DISK BITS(10 IF THERE,7777 IF NOT)
	LDF	1		/RESET TO E6 SEGMNT
	AZE I			/IF ITS ZERO(7777) MAKE IT 0000
	CLR			/ELSE, LEAVE IT THE WAY IT IS (10)
	STA
	E6+6+2000	/UNIT SECTOR
	JMP DOLO+2	/NOW DO AN
			/LO PIP,0
DOQL,	LDA I		/HERE FOR QUICK LIST
	7777		/THIS VALUE TELLS
			/ASSEMBLER TO QL
	LDF 2
	STA
UNITNO+2000-3		/=7777 FOR QL .NE.
			/7777 FOR LI
			/NO MATTER FOR AS
	LDF 1
	STA
	2000
	LDA I
	5000
	JMP BYAS
DOLI,	CLR
	JMP DOQL+2
DOAS,	LDA I
	5002		/SA FOR AS
BYAS,	STC LIORCV
	JMP W2
	JMP ECON
	JMP CHKMT
	JMP ERRXIT
	LDA I
	DISKS
	LDF 2
	STA
	UNITNO+2000
	LDA I
	0000			/START OF THE WORKING AREA WITH REF TO 110
RDCASM,	STC BLKST
	LDF 1
	CLR
	SAE
	2000+E6+1
	JMP .+4
	SAE
	2000+E6
	JMP ERRXIT
	LDA
	2000+E6
	LDF 2
	STA
	2000+UNITNO-2
	COM
	LDF 1
	ADA
	2000+E6+1
	LAM
	2000+E6
	LZE
	JMP ERRXIT
	LDF 2
	STA
	2000+UNITNO-1
	PDP
	PMODE
	CIF	10
	JMS I	READ
	JBAS2
	CIF	10
	JMS I	READ
	JBAS1
	LINC
	LMODE
	LDF	2
	LDA
	BLKST
	BSE I
	1000
	STA
	2002
	PDP
	PMODE
	JMP I .+1
	LMODE
LIORCV,	0
BLKST,	WA
W2,	SET 11
	0
	JMP DECODE
	JMP .+4
	LIF 2
	JMP T2
	JMP 11
	LIF 2
	JMP T2
	XSK I 11
	JMP 11
CHKMC3,	LDF 2		/EXECUTE MC COMMAND
	SET 6
	2007
	JMP CLRALL
	LDF 1
	LDH I 6
	JMP NUMCHK	/IS FIRST CHAR 0-7 ?
	JMP M8
	JMP LOCATE	/YES DO LOC REQUEST
			/SEARCH MONITOR
			/COMMAND TABLE
			/CLR NO PAS AND TRAP
CLRALL,	CLR
	JMP 0
M8,	LDH 6
	ROL 6
	STC 0
	LDH I 6
	ADD 0		/COMMAND XX IS IN AC
	SET I 1
	Z6-1+2000	/PTR TO MC TABLE
	SET I 7
	Z6-Y6-3		/LENGTH
	XSK I 7		/TABLE SCANNED ?
	SKP		/NO
	JMP XITERR	/YES DELETE 
			/ILLEGAL COMMAND
N1,	SAE I 1		/FOUND A MATCH ?
	JMP .-4		/NO DO SOME MORE
	LDA I 1		/LOAD A JMP INST
	STC .+1
	0		/TO META
			/LOCATE LN XXXX
LOCATE,	LDA I		/RESET PTR TO
	-HBIT		/START OF
	ADM		/COMMAND
P6,	6		/STRING
	JMP P56		/CONVERT CODES
			/TO LN NUMBERS
	LDF 1
	LIF 2
	JMP LOKATE
			/DIGIT CHK
NUMCHK,	ADA I		/IS CHAR CODE
	-67		/.GT. 67
	APO I		/NO
	JMP 0		/YES  IS NOT A NUM
	ADA I
	10
	APO		/.GT. 57 ?
	JMP 0
	XSK I 0
	JMP 0		/YES IT IS A NUM
			/DECODE MONITOR
			/COMMAND STRING
P56,	SET 16		/SAV RTN JMP
	0
	CLR		/SET NUM TO 0
	STC T4		/STORE RESULT
	LDH I 6
	SHD I
	SP1
	JMP .-3		/IGNORE SPACES
	JMP NUMCHK	/DIGIT ?
	JMP T4-1	/NO EXIT
	LDH 6
	BCL I
	7770		/0-7 TO AC
	ADD T4
	ROL 3
	JMP P56+3	/DO SOME MORE
	LDA I
T4,	0		/NUMBER TO MOVE
	ROR 3
	JMP 16
DOMC,	JMP DECODE
	JMP XITERR
	JMP E2
	LIF 0
AAA4S3,	JMP KDOMC
			/ADD PROGRAM
DOAP,	SET 7
	6
	LDH I 7
	SHD I
	CR1
	JMP XITERR
	JMP DECODE
	JMP .+2		/BY BLOCK NUM
	JMP .+4		/BY NAME
	LDA
	E6+1+2000	/UNIT NUM
	JMP U2+3	/PUT IN UNIT
			/NUM WD OF PARAM TABLE
	PDP
	PMODE
	CIF	10
	JMS I	READ
	JBAP1
	LINC
	LMODE
	LDF	1
	LIF	2
	JMP	1400
/
/
APRTN,	PDP
	PMODE
	CIF	10
	JMS I	READ
	JBAP2
	LINC
	LMODE
	LDF	1
	LIF 2
	JMP C1		/GO DISPLAY
			/LOAD BINARY
DOLO,	JMP DECODE
	NOP
	JMP E2
	PDP
	PMODE
	CIF	10
	JMS I	READ
	JBLO
	LINC
	LMODE
	LIF	6		/PREPARE TO CALL THE LOADER NOW.
	JMP	20		/START THE LOADER GOING NOW
CURPTR,0
SCOPE,	ROL 1
	STC LNFOR
			/PRESET ONCE
			/PER FRAME
	LDF 2
	LDA
	2000+10
	STA
	FIRSWD
	SET 2
	2000+2
	JMP SCPSTR	/NORMAL CALL
	JMP IWAIT	/TO SCOPE
	JMP .-1		/NOT READY
XIT1,	LDF 1		/READY GET A
	LIF 2		/CHAR
	JMP 17
GETCUR,	LDA		/FIND CURSOR
	0		/CHAR
	STC CURRTN
	LDF 2
	SET I 10
	-3
	JMP SAM3
	JMP CURGO
	STC TEMPB
	STC ENDFLG
	ADD TEMPB
	JMP OUTCUR
CURGO,	LDA
	0
	STC XITCUR
	LDA
	2
	SAE
	14
	SKP
	JMP XITCUR
	XSK CURVAL
	SKP
	JMP XITCUR
CURSET,	ADA I
	-HBIT
	XSK I CURVAL
	SKP
	JMP XITCUR
	SAE
	14
	JMP CURSET
	XSK I 10
	SKP
	JMP XITCUR
	LDA
	ENDFLG
	AZE I
	JMP CNTALL
	SET CURVAL	/KNOB 3 TOO FAR
	TEMPB
	JMP CURGO
	JMP OUTCUR	/FREEZE CURSOR
CNTALL,	LDA
	2
	STA
	ENDFLG
	ROL 1
	COM
	STC TEMPB
	ADD 14
	ROL 1
	ADD TEMPB
	STC TEMPB
	JMP 0
TEMPB,	0
ENDFLG,	0
XITCUR,	0
OUTCUR,	STA
	CURPTR
	ADA I
	HBIT
	STA
	2000+CURPT2
CURRTN,	0
IWAIT,	SET 5
	0
	JMP OUTSCP+1	/GO SCOPE
	LIF 0
	JMP MODKBD	/CHK DUBL BUFR
	XSK I 5		/CHAR READY
	JMP 5		/EMPTY OR MTP
NOPAS,	JMP SCPSTR	/NO PAUSE CALL
	JMP IWAIT	/TO SCOPE
	NOP
	SKP
	JMP NOPAS+1	/LOOP TILL DUN
	LIF 0		/RTN TO
/	JMP TRPRTN	/TRAP SR
/			PREVIOUS INSTRUCTION WAS REMOVED BECAUSE TRAP HANDLER IS NO ONGER PRESENT.
	STC SVACC	/SCP SR EXIT
	ADD 0
	STC DSCRTN
OUTSCP,	0		/RTN JMP TO CALL
	LDA
	0
	STC OUTSCP
	ADD SVACC
DSCRTN,	0		/RTN JMP TO SCP
SVACC,	0
FIRSWD,	0
SCPSTR,	LDA
	0
	STC OUTSCP
	SET 14
	FIRSWD
JGC,	JMP GETCUR
	LDF 1
	ADD EOFRAM
	STC CURFLG
	ADD EOFRAM
	STC CURVC
	STC GAPARG
	LDA I
LNFOR,	0		/LN-1 FOR DISPLAY
	STC K5+1
	LDA I
MAXVC,	0
	STC VCOORD
			/ONCE PER LN
F5,	JMP SAM7	/RTN WITH NUM LNS
			/PER FRAME
	SAE I
OLDSAM,	0		/HAS KNOB 7 MOVED ?
	SKP
	JMP .+3
	LIF 2
	JMP SAMARG
	JMP OUTSCP-3
			/DISPLAY A LN NUM
			/DO NOT DISPLAY
			/LEADING ZEROES
H5,	SET I 1
	LNHC
			/NUM
	LDA I
	2
	ADD K5+1
	STC K5+1
	JMP K5		/GET GRID PTR FOR
			/DIGIT IN LN NUM
	AZE		/IS IT A LEADING 0 ?
	JMP J5		/NO DISPLAY FIRST NON
			/ZERO DIGIT
	ADA I		/YES INCREASE H COORD
	12
	ADD 1
	STC 1
	JMP K5-3	/AND GET NEXT DIGIT
	JMP .-7		/CHK FOR LEADING ZERO
J5,	ADA I
	140
	JMP DSCCHR+1	/DISPLAY A DIGIT
	JMP K5-3	/GET PTR NEXT DIGIT
AAA7S3,	JMP J5
			/COME HERE TO
			/DISPLAY THE LN
DISTXT,	SET I 1
	TXTHC		/INIT H COORD FOR
			/FIRST CHAR OF A LN
	JMP EOFRAM	/CHK FOR END
			/OF FRAME
	LDH I 14
	SHD I
	TB1		/TAB ?
	JMP FLDSET
	SHD I
	LF1
	JMP Y5
P5,	JMP DSCCHR
	JMP EOFRAM
	LDH I 14
	SHD I
	TB1
	JMP FLDSET
	SAE I
	CR
	JMP P5
	LDA I
	TXTHC
	SAE
	1
	JMP W5
	JMP F5
Y5,	LDA I		/SET FOR MC
	MCVC
	STC VCOORD
	SET I 1
	MCHC
	LDA I
	LF
	JMP 0
FLDSET,	SET I 10	/SET FOR TAB
	FLDTAB-1
GOTAB,	LDA I 10
	SAE
	ENDTB
	JMP ENDSKP
	LDA I
	-COMTB
	ADD 1
	STC CARTB
	JMP W5
	LDA I
CARTB,	0
	ADM
	1
	JMP P5+1
ENDSKP,	COM
	ADD 1
	APO I
	JMP GOTAB
	AZE I
	JMP GOTAB
	LDA 10
	STC 1
	JMP P5+1
FLDTAB,	TAGTB
	INSTB1
	INSTB2
	COMTB
ENDTB,	0
TABSET=120
TXTHC=1157
TAGTB=TXTHC+TABSET
INSTB1=TAGTB+TABSET
INSTB2=INSTB1+TABSET
COMTB=INSTB2+TABSET
			/DSC 1 CHAR ACCORDING
			/TO C(AC) AND RTN
DSCCHR, ROL 1
	ADA I
M5,	A6-1+2000
	STC 12
	ADA I
VCOORD, 0
	ADD GAPARG
	DSC I 12
	DSC I 12
	XSK I 1
	XSK I 1
	JMP 0
W5,	CLR		/SET VC
	SET 12		/FOR NXT SCP LN
	0
	SAE
	CURFLG
	JMP .+4
	LDA I
	-10
	STC GAPARG
	LDA I
	-17
	LAM
	VCOORD
	BCL I
	7020
	SET I 1
	TXTHC
	JMP OUTSCP-3
	SAE I
	360
	JMP 12
			/MOVE DISPLAY TO
			/TOP OF SCOPE
	STC MAXVC
	JMP 12
			/CHK END OF FRAME
EOFRAM, LDA
	0
	STC RTNEOF
	LDA
	14
	SAE
	CURPTR
	SKP
	JMP DSCCUR
	LDA
	2		/PTR TO LAST CHAR 
			/IN BUFFER
	SAE
	14		/PTR TO LST 
			/DISPLAYED CHAR
RTNEOF,	0
	CLR
	SET I 1
	MKHC
	JMP DSCCHR+1	/DISPLAY MARKER
	JMP SCPSTR+3
XITERR,	IOB
	6244
	JMP DELMC
/
ERRXIT,	PDP
	PMODE
	JMP I	.+1
	EANDZB
	LMODE
/
			/COUNT DIGITS
	SRO I
	4210
	JMP DISTXT	/EXEC THIS WHEN
			/LN NUM
			/HAS BEEN DISPLAYED
K5,	LDA I
	0		/LN FOR DISPLAY
	ROL 3
	STA
	K5+1
	BCL I
	7761
	JMP 0
KSAM7,	LDA
	0
	STC EGGSIT
	JMP SAM7
	IOB
	6244
EGGSIT,	0
			/MONITOR COMMAND
			/STRING DECODE
			/LN,NAME,UNIT
DECODE,	CLR
	SET I 12
	E6+2000		/PTR TO MON
			/PARAMETER TABLE
			/CLEAR THE TABLE
	STA 12		/LN NUM
	STA I 12	/LN NUM
	COM
	STA I 12	/N
	STA I 12	/A
	STA I 12	/M
	STA I 12	/E
	CLR
	STA I 12	/UNIT NUM
	SET 1		/SAV RTN JMP
	0
			/LN NUM
	SET I 12
	E6-1+2000
	SET I 17
	-2		/COMMA CTR
	SET 14
	6
F2,	JMP P56		/AND RTN WITH A
			/NUM IN AC
	STA I 12	/STORE A LN NUM
	LDH 6
	SHD I
	CR1
	JMP 1		/END OF COMMAND
	SAE I
	COMA
	JMP .+4		/NO
	XSK I 17	/FIRST COMMA ?
	JMP F2-2	/YES CHK FOR 2ND LN NUM
	JMP .+5
	CLR		/NO COMMA RESET
	STA 12		/NUM TO 0
	SET 6		/RESET COMMAND
	14		/STRING PTR
			/NAME
N2,	SET I 12
	E6+4001+2000	/NAME SECTOR
	SET I 16
	-11		/NAME LENGTH CTR
	XSK I 1		/SET RTN TO P+2
	LDH I 6
	SHD I
	SP1
	JMP .-3
REDO,	SHD I
	CR1
	JMP XITERR
	SHD I
	KOM1
	JMP XITERR
	SHD I
	QMARK1
	JMP XITERR
	SHD I
	COMA1
	JMP U2		/GET UNIT NUM
	STH I 12
	LDH I 6
	XSK I 16
	JMP REDO
	JMP XITERR	/NAME TOO LONG
			/UNIT
U2,	JMP P56
	SET 0
	1
	STA
	E6+6+2000
	ADA I		/TEST FOR UNIT TOO LARGE.
	-47		/LARGEST UNIT
	APO		/IF POSITIVE THEN ITS WAY TOO LARGE (ABOVE 47)
	JMP 0		/GOOD UNIT.
	JMP XITERR	/ILLEGAL UNIT
			/SB,SR
DOSB,	JMP DECODE
	JMP XITERR	/NO NAME
	LDH 6
	SHD I
	CR1
	JMP DUNSB
	SAE I
	COMA
	JMP XITERR
	LDH I 6
	SHD I
	PCODE
	JMP STPDP
	SHD I
	LCODE
	JMP STLINC
	JMP XITERR
STPDP,	LDA I
	0200
	STA
	2000+E6+1
	LDA I
	4000+400+0
	JMP GETSA
STLINC,	LDA I
	4020
	STA
	2000+E6+1
	LDA I
	0+400+0
GETSA,	STA
	2000+E6
	LDH I 6
	SHD I
	CR1
	JMP DUNSB
	JMP NUMCHK
	JMP XITERR
	LDH 6
	BCL I
	7770
	ADM
	2000+E6
	JMP P56
	STA
	2000+E6+1
DUNSB,	JMP E2
	PDP
	PMODE
	CIF	10
	JMS I	READ
	JBSB
	LINC
	LMODE
	LDF	1
	LIF	2
	JMP	FCSA		/DO THE SAVE BINARY
/
/
/
			/AS,SP
			/CHK FOR EMPTY WA
CHKMT,	LDF 2
	LDA
	2000+MAXLN
	LDF 1
	SAE I
	1
	XSK I 0
	JMP 0
			/EXIT LOAD BINARY SR
E2,	LDF 2
	CLR
	STA
	2000+X2+5
	IOB
	6244
	JMP T2
	JMP 0
			/SAVE PROG
DOSP,	JMP CHKMT
	JMP XITERR
	JMP DECODE
	JMP XITERR	/NO NAME
	JMP E2
	LDF	2		/SET THE D.F. TO 2 TO PICK UP THE  OF BLOCKS.
	LDA			/GET THE LAST BLOCK IN THE AC.
	SPTBLK!2000		/LAST BLOCK NUMBER
	STC	DOSPTP		/SAVE IN A TEMPORARY UNTIL PAST READ.
	PDP
	PMODE
	CIF	10
	JMS I	READ
	JBSP
	LINC
	LMODE
	LIF	2
	LDA I			/RECALL THE LAST BLOCK NUMBER NOW
DOSPTP,	0			/TEMPORARY FOR THE LAST BLOCK NUMBER
	JMP FCSA+3
			/PRINT MS
DOPS,	JMP W2
	JMP .+3
	JMP CHKMT
	JMP ERRXIT
	PDP
	PMODE
	CIF	10
	JMS I	READ
	JBSP
	LINC
	LMODE
	LDF	1
	LIF	2
	JMP FCSA+5
	/PX
DOPX,	JMP Z2
	PDP
	PMODE
	CIF	10
	JMS I	READ
	JBPXDX
	LINC
	LMODE
	LDF	1
	LIF	2
	JMP 20
/
/
/
/
/
DOAB,	JMP	DECODE		/DECODE THE COMMAND
	JMP	XITERR		/AN ERROR. REDO EDITOR
	JMP	E2		/FORCE THE EXIT NOW.
	PDP
	PMODE			/GET OVER INTO THE WONDERFULL MODE
	CIF	10		/PREPARE TO CALL THE ROUTINES
	JMS I	READ		/CALL THEM IN NOW.
	JBFC2			/THEYRE BING CALLED IN NOW.
	LINC			/BACK TO THE CALLING SIDE
	LMODE
	LIF	2		/SET UP THE CORRECT INSTRUCTION FIELD
	JMP	FCSA+1		/DO IT,BUBBY
/
/
/
/
/
/
/
/
	EJECT
/
/
/
/
/
/
/
/
/
/
	*7377
/
/
/
/
/				THIS LOCATION IS A RETURN FROM FIELCOMS
/				SO THAT "LI,AS, AND QL" WILL GO INTO
/				THE EDITOR AND START THE ASSEMBLER GOING
/				DO NOT REMOVE. ITS A NO-NO.
/
/
/
/
/
/
	JMP	RDCASM		/ASSEMBLER READ IN LOCATION.
/
/
/
/
/
/
/
/
/
/
/
	EJECT
/KBD INPUT CONVERSION ROUTINES
/TABLE CONTAINS ASCII CODES OF ALL
/SPECIAL  AND ILLEGAL CHARS
/HIGH ORDER 4 BITS HOLDS A MICRO ADDR
/RELATIVE TO LOC KLEGAL
*1400
KBDOPR,	LDA
	0
	STC RTNJMP
	IOB		/GET THE CHAR
	PMODE
	KRB			/READ IN THE CHAR NOW
	LMODE
	BCL I
	7600
	STA
	CHAR
	STC ENDTAB	/LAST CHAR IN TABLE
			/WILL GENERATE A MATCH
			/IN SCAN ROUTINE
			/UNLESS A SPECIAL
			/OR ILLEGAL CHAR
			/WAS STRUCK
	SET I 1
	TABLE-1
SPYTAB,	LDA I 1		/NEXT CHAR
	BCL I		/LOOK AT
	7600		/EVEN ASCII ONLY
	SAE		/FOUND A 
	CHAR		/MATCH ?
	JMP SPYTAB	/NO DO SOME MORE
	LDH 1		/MICRO ADDR TO
	SCR 2		/LOW ORDER FOUR BITS
	ADA I		/MAKE A JMP INST
	JMP+KLEGAL	/RELATIVE TO KLEGAL
	STC AJMP
	XSK I 1		/DIAL CODE OF INPUT
	LDH I 1		/CHAR IS LOW ORDER
			/6 BITS OF LOC
			/FOLLOWING MATCH
	STC ENDTAB
AJMP,	0		/GO TO S.R.
KLEGAL,	JMP LEGAL	/HERE FOR LEGAL CODE
	JMP ILEGAL
	JMP TAB
	JMP KCR
	JMP RUBOUT
	JMP LNFEED
	JMP ALTM
/FOR ADDITIONAL SPECIAL CHARS
	JMP ALTZ
LEGAL,	ADD CHAR
	ADA I
	-140
	APO
	JMP .+5
	ADA I
	-32
	APO
	JMP .+5
	LDA
	CHAR
	JMP TYPE
	JMP EXIT
	LDA
	CHAR
	BCL I
	40
	JMP TYPE
	ADD ENDTAB
	BCL I
	40
	JMP EXIT+1
TAB,	LDA I
	240			/TYPE OUT A SPACE FOR A TAB
	JMP	TYPE
	JMP	EXIT		/AND THEN RETURN
KCR,	JMP TYCAR
	JMP EXIT
RUBOUT,	LDA I
	334
	JMP TYPE
	ADD ENDTAB
ALTM1,	BSE I
	4000
	JMP EXIT+1
LNFEED,	JMP EXIT
ALTM,	ADD ENDTAB
	BCL I
	0041
	JMP ALTM1
ALTZ,	LDA I
	4036
	JMP EXIT+1
ILEGAL,	STC ENDTAB
EXIT,	ADD ENDTAB
	IOB
	6244
	DJR
RTNJMP,	0
TYCAR,	LDA
	0
	STC RTN
	ADD CRCODE
	JMP TYPE
	ADD LFCODE
	JMP TYPE
RTN,	0
TYPE,	PDP		/TYPE AC
			/AND RTN
	PMODE
	TSF
	JMP .-1
	TLS
	CLA
	LINC
	LMODE
	JMP 0
/TABLE FORMAT IS :
/XX00+0YYY
/AAZZ WHERE:
/XX= UNROTATED MICRO ADDRESS E.G.
/1400 ROR 10=0003
/AND C(KLEGAL+3) = JMP TAB
/YYY= ASCII CODE
/ZZ= DIAL CODE FOR YYY IF YYY IS A 
/SPECIAL CHAR
 
 
 
TABLE,	1000+211	/TAB
	0400+247	/APOSTROPHE
LFCODE,	2400+212
	0400+337	/LEFT ARROW
CRCODE,	1400+215
	0400+243	/NUMBER SIGN
	3000+375	/ALT
	3000+376	/ALT
	2000+377	/RUBOUT
	0400+337	/LEFT ARROW
	3400+233	/ALT ESCAPE
	0400+300	/AT SIGN
ENDTAB,	0		/C(CHAR)
CHAR,	0		/LOC FOR INPUT CHAR
			/ABOVE 2 TAGS NOT
			/TO BE MOVED
/
/
/
/
DOEX,	JMP E2		/EXIT
	HLT
	LIF 2
	JMP 20
DODX,	JMP Z2
	PDP			/GET OVER INTO 8 MODE TOREAD IN DX
	PMODE
	CIF	10
	JMS I	READ
	JBPXDX
	LINC
	LMODE
	JMP XIT1
Z2,	LDA
	0
	STC P2T
	JMP DECODE
	JMP .+2
	JMP XITERR
	LDA
	E6+1+2000
	JMP U2+3
	JMP E2
P2T,	0
ECON,	PDP
	PMODE
	CIF	10
	JMS I	READ
	JBFC2
	LINC
	LMODE
	LDF	2
	LIF	2
	JMP FCSA+4
AATTY3,	0
GOODY,	LDF	2
	STC	12
	LDA	12
	ROR	2
	BCL I
	-1
	ADA I
	PMODE
	JMS I	READ
	LMODE
	STC	GCLOC?1777
	LDA I	12
	BCL I
	-777
	STC	GTOUT
	LDA	12
	ROL	3
	BCL I
	-3
	BSE I
	4
	STC	GCORE
	LDA	12
	COM
	BCL I
	-4000
	ROL	3
	ADD	GCORE
	STC	GCORE
	XSK I	12
	PDP
	PMODE
	TAD	WATAG		/GET WORKING AREA POINTER.
	TAD	GTOUT
	DCA	GTOUT
	CIF	10
GCLOC,	JMS I	READ
	GCTWO
	LINC
	LMODE
	LDA I
	DISKS
	STC	GCTWO?1777
	LDA I
	-WA+1
	STC	WATAG?1777
	LDF	1
	LIF	2
	ADD	12
	STC	.+3
	COM
	DJR
	0
/
/
	PMODE
WATAG,	-WA
	LMODE
/
GCTWO,	DISKS
GCORE,	0
GTOUT,	0
	1
/
/
/
/
/
/
/
/
/
/
/
/
/
ZERO,	JMP	E2		/THIS IS THE ZERO BINARY ROUTINE. DO AN EX.
	PDP			/GET OVER INTO 8 MODE
	PMODE			/TEL ASSY WERE IN 8 MODE
	CLA CMA			/PREPARE TO ZERO UPPER CORE
	DCA	10		/0-1
	TAD	ZM7000		/ZERO OUT 7000 WORDS OF UPPER CORE
	DCA	11		/SAVE IN A COUNTER
	CDF	10		/SET THE DATA FIELD TO POINT T UPPER CORE
	DCA I	10		/ZERO A WORD OF CORE
	ISZ	11		/DONE?
	JMP	.-2		/NOPE. LOOP
/
	CDF	0		/RESET THE DATA POINTER TO FIELD 0 FOR THE WRITE CALL
	CIF	10		/SET THE INSTRUCTION FIELD TO 1
	JMS I	WRITE		/WRITE AND ZEROTHE OUTPUT AREA
	ZP1
	CIF	10
	JMS I	WRITE
	ZP2
	CIF	10
	JMS I	WRITE
	ZP3			/BINARY AREA SHOULD NOW BE ZERO
	CIF	10		/SET I.F. TO UPPER CORE FOR ONE MORE CALL
	JMS I	WRITE		/NOW ZERO OUT THE BIT MAP.
	ZP4			/POINTS TO THE BIT MAP
EANDZB,	CIF	10		/NOW REBOOTSTRAP DIAL
	JMP I	.+1
	7777
/
/
/
/
ZP1,	111
	20
	0
	16
/
/
/
/
ZP2,	111
	20
	16
	16
/
/
	*7752
/
ZP3,	111
	20
	16+16
	40-16-16
/
/
/
ZP4,	111
	20
	57			/POINTS TO THE BIT MAP.
	1			/ONE BLOCK FOR THE BIT MAP
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
	LMODE			/TELL ASSY WERE IN LMODE
/
/
/
/
/
/
JBTMT,	LDA
	JBTMTS			/GET THE SWITCH IN THE AC.
	BCO I			/COMPLEMENT THE SKP BIT NOW.
	20
	SRO I			/TEST FOR 12 TIMES THROUGH
	4444			/ONE IN SIX COUNTER
	STC	JBTMTS		/SAVE AWAY NEW ONE
JBTMTS,	SKP			/SKIPS SOMETIMES
	JMP	0		/RETURN SOMETIMES
	SET I	12		/SET CURSOR TO DISPLAY BLANKS.
	JBNULO
	JMP	0
/
/
/
JBNULO,	0
	0
/
/
/
/
/
/
/
/
/
	PMODE
/
/
/
/
/
/
	ZM7000=JBTMT		/LDA IS A 1000 WHCIH IS -7000
/
/
/
/
	*7750
/
/
/
	.-1
	.
/
	LMODE
/
/
/
/
/
	EJECT
/
/
/
/
/
/
	CHAIN	"EDITOR2"
/
/
/
/
/
/
	EJECT