*20
/RD-WRI
/
/KEITH WHITTLE
/FEB,1972
/
/READ IN AND WRITE OUT THE SAME 
/DATA FILE USING THE PARAMETERS
/LEFT BY L F,NAME,UNIT
/
/
/****DEFINE STARTING LOCATION.****
/
/SUBROUTINE USES INDEX REGISTER 10
/OF FLD0, IN READIN PORTION.
/
/
	PMODE
	*100
READIN,	0
	CLA CLL
	DCA 10		/ZERO POINTER
/RETREIVE INFO. FROM FLD1.
	6211
	TAD I 10
	DCA UNIT1
	TAD I 10
	DCA TBLK1
	TAD I 10
	DCA NBLK1
	6201
/
/
/
	TAD MBLK2	/P20
	CIA
	TAD MBLK1
	SMA		/JUST FLD1?
	JMP READ1	/YES.
	TAD NBLK1	/NO.
	SPA SNA		/JUST FLD0?
	JMP READ1	/YES
	DCA NBLK2	/NO,BOTH FLDS.
	TAD NBLK2
	CIA
	TAD NBLK1
	DCA NBLK1	/BLKS IN FLD0.
	CLL
	TAD NBLK1
	TAD TBLK1
	DCA TBLK2	/1ST TBLK IN F1
	TAD UNIT1
	DCA UNIT2	/SAME AS UNIT1
	6212
	JMS I PREAD
	PTR2
READ1,	CLA CLL
	6212
	JMS I PREAD
	PTR1
	JMP I READIN	/EXIT
/
/
/
/
/
/
/
/
/WRITE PORTION OF SUBROUTINE.
/
WRIOUT,	0		/ENTRY.
	TAD NBLK2	/CHECK FLDS.
	SPA 		/ONLY ONE FLD?
	JMP WRITE1	/YES
	6212		/BOTH
	JMS I PWRITE
	PTR2
WRITE1,	6212
	JMS I PWRITE
	PTR1
	JMP I WRIOUT	/EXIT
/
/**************************************
/
	PTR1=.
UNIT1,	0
/MBLK1 SET BY USER TO STARTING MBLK OF
/DATA FILE.
MBLK1,	14
TBLK1,  0
NBLK1,	0
	PTR2=.
UNIT2,	0
MBLK2,	20		/ALWAYS THIS.
TBLK2,	0
NBLK2,	0
PREAD,	7774
PWRITE,	7775
	RDWRI=100
	PMODE
	*4400
START,	JMS RDWRI	/GET DATA
	LINC
	LMODE
	AXO
	SET I 1		/INITIAL PTR
	2001
BEGIN,	LDA I 1		/GET STIMULUS
	SAE I		/CHECK FOR STOP
	0007		/CODE.
	SKP		/CONTINUE.
	JMP RETURN	/BACK TO FOCAL.
	ATR		/CLOSE RELAY.
	LDA
	2000		/ON TIME
	JMP CLCK	/CLOCK ROUTINE
	ATR		/CLEAR RELAY
	LDA
	2001		/DELAY TIME
	JMP CLCK	/CLOCK ROUTINE
	JMP BEGIN	/LOOP.
RETURN,	0702		/GET FOCLDR
	0232
	CLR
	JMP 20
CLCK,	PDP		/CLOCK SUB-
	PMODE		/ROUTINE.
	CIA
	CLAB
	CLA
	CLLR
	CLEN
	TAD CKCON1
	CLLR
	CLSA
	CLA
	TAD CKENU
	CLEN
	CLA
	TAD CKCON2
	CLLR
	CLA
	CLSK
	JMP .-1
	LINC
	LMODE
	JMP 0
CKCON1,	0100
CKENU,	0300
CKCON2,	5100