/
/	COPYRIGHT 1968, DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/	UTILITY SUBROUTINE PACKAGE
/		VERSION UTILTY.V07 (JANUARY 7, 1969)
/
/*****	PATCHED 8/3/71. (PATCH # LIB8 (PS/8) 2, MARCH 1971.)
/
/
	ENTRY	OPEN	     /INITIALIZING AND FLAG SETTING ROUTINE
	ENTRY	GENIO
	DUMMY	MEMOR
	ENTRY	MEMOR
	ENTRY	EXIT		/EXIT TO DISK MONITOR SYSTEM
	ENTRY	ERROR
	ENTRY	CKIO	/USELESS ROUTINE
	OPDEF	KRS	6034
	OPDEF	KCC	6032
	OPDEF TADI 1400
	OPDEF DCAI 3400
	OPDEF	JMSI	4400
	OPDEF JMPI 5400
/LINE PRINTER IOT'S
	OPDEF	LLB	6666
	OPDEF	LSF	6661

	LAP

U17,	17		/*** MUST BE FIRST LOC IN PAGE ***

IOER,	1117
	0522		/"IOER" ERROR
GENIO,	BLOCK 2		/GENERAL INPUT/OUTPUT ROUTINE
	DCA	7	/SAVE ENTRY AC
GENLP,	TAD	7
	RTL
	RTL
	RAL
U200,	AND	U17
	TAD	JMPITB
	DCA	DSPACH	/INDEX JUMP TABLE BY DEVICE NUMBER
	TAD	U200
	KRS
	TAD	UM203
	SNA CLA
	KSF		/CHECK FOR ^C ON TELETYPE
DSPACH,	NOP		/NO ^C - DISPATCH TO I/O ROUTINE
	CALL	0,EXIT

JMPITB,	JMPI	DEVTAB
DEVTAB,	TTYOUT
	HSPOUT
	LPTOUT
	GENOUT
	TTYIN
	HSRIN
	IOERR	/OLD CARD READER
	GENIN
	TTYFUJ		/FUDGE - SEE TELETYPE INPUT ROUTINE
	IOERR
	IOERR
	IOERR
	IOERR
	IOERR
	IOERR
	IOERR


TTYIN,	KSF
	JMP	GENLP
	7332/2000B	/****DEPENDS ON NUMBER OF DEVICES ****
	JMP	GENLP	/TEST FOR ^C ONE LAST TIME

HSRIN,	RSF
	JMP	GENLP
	RRB RFC
	JMP	GENRTN#

UM203,	-203

/ CALL 1,MEMOR
/ ARG ARRAY

	DUMMY DMY
MEMOR,	BLOCK	2
	TAD I	MEMOR	/DMY=ARG1
	INC	MEMOR#
	DCA	DMY
	TAD I	MEMOR
	INC	MEMOR#
	DCA	DMY#
	DCA	CHO	/ZERO CHR BUFFER
	RETRN	MEMOR
CHO,	0
DMY,	BLOCK 2

CH,	0
HSPOUT,	TAD	7
	AND	(377	/DELETE UNIT NUMBER
	TAD	(-212	/*LF*
	SNA		/=0?
	JMP	GENRTN	/YES
	TAD	(-3	/*CR*
	SNA CLA		/=0?
	JMP	GENRTN	/YES
	TAD	7
	AND	(77
	DCA	CH	/=CHARACTER.A.77
	TAD	CHO
	SNA		/CHO=0?
	JMP	HSP1	/YES
	TAD	(-1
	TAD	CH
	DCA I	DMY	/=CHO+CH-1
	INC	DMY#
	DCA	CHO	/=0
	JMP	GENRTN
HSP1,	TAD	CH
	RTL;RTL;RTL;IAC
	DCA	CHO	/=CH*100+1
GENRTN,	CLA
	RETRN	GENIO

	PAGE
U377,	377		/MUST BE FIRST LOC IN THIS PAGE
GENIN,	6201
	TADI	IHNDLR
	SNA CLA		/OPEN INPUT FILE?
	JMP	IOERR	/NO
	6202
	JMS I	FICHAR	/GET A CHAR
	JMP	IOERR	/INPUT ERROR
UU200,	AND	U377
GRTN2,	RETRN	GENIO

GENOUT,	6201
	TADI	OHNDLR
	SNA CLA		/OPEN OUTPUT FILE?
	JMP	IOERR	/NO
	6202
	TAD	7	/GET CHAR TO BE OUTPUT
	AND	U377
	JMS I	FOCHAR	/PUT A CHARACTER
	JMP	IOERR	/OUTPUT ERROR
	JMP	GRTN2

IHNDLR,	122		/***ALL THESE LOCATIONS ARE VERY VOLATILE!! ***
FICHAR,	606		/*******
OHNDLR,	121		/*******
FOCHAR,	651		/******************

/
/	INITIALIZING SUBROUTINE CALLED BY FORTRAN
/	CLEARS FLOATING AC AND SETS FLAGS
/
OPEN,	BLOCK	2
	CLA
	TLS	/INITIALIZE TTY
	LLB	/INITIALIZE LPT
	KCC	/CLEAR KEYBOARD FLAG (AND AC)
	PLS
	RFC
	CALL	0,CLEAR
	6201
	DCAI	IHNDLR
	DCAI	OHNDLR		/ZERO DEVICE-INDEPENDENT IO FLAGS
	RETRN	OPEN


LPTOUT,	LSF
	JMP	GENLP
	TAD	7
	ISZ	PFSTCH
	JMP	NOFST
	TAD	(-1262	/LOOK FOR CONTROL CHARS IN PRINT POSITION 1
	CLL IAC
	IAC
	SNL
	JMP	DCACH
	CLL RAL
	TAD	(212
NOFST,	LLB
	TAD	(-1212
DCACH,	SNA CLA		/IF LINE FEED
	CMA		/SET "FIRST CHAR" SWITCH ON
	DCA	PFSTCH
	JMP	GRTN2
PFSTCH,	-1

TTYFUJ,	TAD	UU200
	KRS
	DCA	7	/SAVE KEYBOARD CHAR
	KCC		/CLEAR FLAG
	TAD	7
	TAD	(-212
	SZA CLA
	JMS	TYPE
	TAD	7
	TAD	(-215
	SZA CLA
	JMP	TYRTN
	CLA CLL CMA RTL
	JMS	TYPE
TYRTN,	TAD	7
	JMP	GRTN2	/RETURN WITH CHAR IN AC

TYPE,	0
	TAD	7
TYPELP,	TSF
	JMP	TYPELP
	TLS
	CLA
	JMPI	TYPE

TTYOUT,	JMS	TYPE
	JMP	GRTN2

IOERR,	CALL	1,ERROR
	ARG	IOER

	PAGE

PMESG,	MESG
MESG,	7777
	7777
	4005
	2222
	1722
	4001
	2440
	1417
	0340
LIT7,	0007

ERROR,	BLOCK 2		/ERROR PROCESSOR
U7600,	7600
	TAD	ERROR
	DCA	TEM1
TEM1,	NOP		/SET DATA FIELD OF "CALL ERROR"
	TADI	ERROR#
	DCA	TEM3
	INC	ERROR#
E60,	CLA CMA CML	/CML IS WINDOW DRESSING
	TADI	ERROR#
	DCA	10
	INC	ERROR#
TEM3,	NOP		/DATA FIELD OF MESSAGE&ENTRY POINT
	DCA	CKIO	/ZERO "FATAL ERROR" FLAG
	TADI	10
	RAL
	SZL		/NON-FATAL BIT ON?
	ISZ	CKIO	/YES - SET "FATAL FLAG" TO NON-FATAL
	CLL RAR		/STRIP NON-FATAL BIT FROM MESSAGE
	DCA	MESG
	TADI	10	/SECOND WORD OF MESSAGE
	DCA	MESG#
	TADI	10
	DCA	TEM1
	TADI	10
	DCA	TEM3	/CALLING ADDRESS
	TAD	PMESG
	DCA	TEM2

ERLP,	TAD I	TEM2
	RTR
	RTR
	RTR
	JMS	PR6BIT
	TAD I	TEM2
	JMS	PR6BIT
	INC	TEM2
	JMP	ERLP

PRLOC,	TAD	TEM1
	RTR
	RTR
	JMS	ERTTY	/PRINT CALLING FIELD
	TAD	(-4
	DCA	TEM2
NUMLP,	TAD	TEM3
	RTL
	RAL
	DCA	TEM3
	TAD	TEM3
	JMS	ERTTY
	ISZ	TEM2
	JMP	NUMLP
	TAD	(215
	DCA	7
	JMS	TYPE
	CLA CLL CMA RTL
	JMS	TYPE
	TAD	CKIO	/GET THE FATAL ERROR FLAG
	SNA CLA		/WHADDOWEDO??
	JMP	EXITX
	RETRN	ERROR	/HE SAYS ITS NON-FATAL - LET HIM HANDLE IT

ERTTY,	0	/DIGIT PRINTING ROUTINE
	RAL
	AND	LIT7
	TAD	E60
	JMS	PR6BIT
	JMP I	ERTTY

PR6BIT,	0		/6BIT TO 8BIT CONVERTOR
	AND	(77
	SNA
	JMP	PRLOC	/MESSAGE OVER
	TAD	(7740
	SPA
	TAD	(100
	TAD	(240
	CALL	0,GENIO	/LOOK FOR ^C WHILE TYPING
	JMP I	PR6BIT

/
/EXIT TO DISK MONITOR SYSTEM
/
EXIT,	BLOCK	2
EXITX,	CALL	0,CKIO
	6203
	JMPI	U7600	/RETURN TO MONITOR

CKIO,	0
TEM2,	0	/DUMMY SUBROUTINE TO WAIT FOR I/O COMPLETE
CKWAIT,	6041
	JMP	CKWAIT
	RETRN	CKIO

	END